[gentoo-commits] gentoo-x86 commit in net-im/gajim: gajim-0.15.2-r4.ebuild ChangeLog gajim-0.15.2-r3.ebuild gajim-0.15.2-r2.ebuild

[Justin Lecher (jlec)]

jlec        13/02/23 10:32:18

  Modified:             ChangeLog gajim-0.15.2-r3.ebuild
  Added:                gajim-0.15.2-r4.ebuild
  Removed:              gajim-0.15.2-r2.ebuild
  Log:
  net-im/gajim: Drop parts of upstream which should fix CVE-2012-5524 but added more code which is incompatible with current implementation
  
  (Portage version: 2.2.0_alpha163/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key 8009D6F070EB7916)

Revision  Changes    Path
1.172                net-im/gajim/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/ChangeLog?rev=1.172&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/ChangeLog?rev=1.172&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/ChangeLog?r1=1.171&r2=1.172

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/gajim/ChangeLog,v
retrieving revision 1.171
retrieving revision 1.172
diff -u -r1.171 -r1.172
--- ChangeLog	20 Feb 2013 14:29:15 -0000	1.171
+++ ChangeLog	23 Feb 2013 10:32:18 -0000	1.172
@@ -1,6 +1,14 @@
 # ChangeLog for net-im/gajim
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/ChangeLog,v 1.171 2013/02/20 14:29:15 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/ChangeLog,v 1.172 2013/02/23 10:32:18 jlec Exp $
+
+*gajim-0.15.2-r4 (23 Feb 2013)
+
+  23 Feb 2013; Justin Lecher <jlec@g.o> -gajim-0.15.2-r2.ebuild,
+  gajim-0.15.2-r3.ebuild, +gajim-0.15.2-r4.ebuild,
+  files/gajim-0.15.2-CVE-2012-5524.patch:
+  Drop parts of upstream which should fix CVE-2012-5524 but added more code
+  which is incompatible with current implementation
 
   20 Feb 2013; Justin Lecher <jlec@g.o> -gajim-0.15.1.ebuild:
   Drop vulnerable versions for CVE-2012-5524, #442860



1.2                  net-im/gajim/gajim-0.15.2-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/gajim-0.15.2-r3.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/gajim-0.15.2-r3.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/gajim-0.15.2-r3.ebuild?r1=1.1&r2=1.2

Index: gajim-0.15.2-r3.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/gajim/gajim-0.15.2-r3.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- gajim-0.15.2-r3.ebuild	20 Feb 2013 10:46:25 -0000	1.1
+++ gajim-0.15.2-r3.ebuild	23 Feb 2013 10:32:18 -0000	1.2
@@ -1,49 +1,45 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/gajim-0.15.2-r3.ebuild,v 1.1 2013/02/20 10:46:25 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/gajim-0.15.2-r3.ebuild,v 1.2 2013/02/23 10:32:18 jlec Exp $
 
-EAPI=5
+EAPI=4
 
-PYTHON_COMPAT=( python{2_6,2_7} )
-PYTHON_REQ_USE="sqlite xml"
+PYTHON_DEPEND="2"
+PYTHON_USE_WITH="sqlite xml"
 
-AUTOTOOLS_AUTORECONF=true
-
-inherit autotools-utils python-r1 versionator
+inherit autotools eutils python versionator
 
 DESCRIPTION="Jabber client written in PyGTK"
 HOMEPAGE="http://www.gajim.org/"
-SRC_URI="
-	http://www.gajim.org/downloads/$(get_version_component_range 1-2)/${P}.tar.bz2
-	test? ( http://dev.gentoo.org/~jlec/distfiles/${PN}-tests-${PV}.tar.xz )"
+SRC_URI="http://www.gajim.org/downloads/$(get_version_component_range 1-2)/${P}.tar.bz2"
 
 LICENSE="GPL-3"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
-IUSE="avahi crypt dbus gnome kde idle jingle libnotify networkmanager nls spell +srv test X xhtml"
+KEYWORDS="alpha amd64 ~arm ~hppa ia64 ppc ppc64 sparc x86 ~x86-fbsd"
+IUSE="avahi crypt dbus gnome kde idle jingle libnotify networkmanager nls spell +srv X xhtml"
 
 REQUIRED_USE="
 	libnotify? ( dbus )
 	avahi? ( dbus )"
 
 COMMON_DEPEND="
-	dev-python/pygtk:2[${PYTHON_USEDEP}]
+	dev-python/pygtk:2
 	x11-libs/gtk+:2"
 DEPEND="${COMMON_DEPEND}
 	>=dev-util/intltool-0.40.1
 	virtual/pkgconfig
 	>=sys-devel/gettext-0.17-r1"
 RDEPEND="${COMMON_DEPEND}
-	dev-python/pyasn1[${PYTHON_USEDEP}]
-	dev-python/pyopenssl[${PYTHON_USEDEP}]
+	dev-python/pyasn1
+	dev-python/pyopenssl
 	crypt? (
 		app-crypt/gnupg
-		dev-python/pycrypto[${PYTHON_USEDEP}]
+		dev-python/pycrypto
 		)
 	dbus? (
-		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/dbus-python
 		dev-libs/dbus-glib
-		libnotify? ( dev-python/notify-python[${PYTHON_USEDEP}] )
+		libnotify? ( dev-python/notify-python )
 		avahi? ( net-dns/avahi[dbus,gtk,python] )
 		)
 	gnome? (
@@ -55,7 +51,7 @@
 	jingle? ( net-libs/farstream:0.1[python] )
 	kde? ( kde-base/kwallet )
 	networkmanager? (
-			dev-python/dbus-python[${PYTHON_USEDEP}]
+			dev-python/dbus-python
 			net-misc/networkmanager
 		)
 	spell? ( app-text/gtkspell:2 )
@@ -66,54 +62,41 @@
 		)
 	xhtml? ( dev-python/docutils )"
 
-RESTRICT="test"
-
-PATCHES=(
-		"${FILESDIR}"/${P}-CVE-2012-5524.patch
-	)
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
 
 src_prepare() {
 	echo "src/command_system/mapping.py" >> po/POTFILES.in
+	epatch \
+		"${FILESDIR}"/0.14-python-version.patch \
+		"${FILESDIR}"/0.14.1-testing.patch \
+		"${FILESDIR}"/${P}-CVE-2012-5524.patch
 	echo '#!/bin/sh' > config/py-compile
-	autotools-utils_src_prepare
-	python_copy_sources
+	eautoreconf
 }
 
 src_configure() {
-	configuration() {
-		local myeconfargs=(
-			$(use_enable nls)
-			$(use_with X x)
-			--docdir="/usr/share/doc/${PF}"
-			--libdir="$(python_get_sitedir)"
-			--enable-site-packages
-		)
-		run_in_build_dir autotools-utils_src_configure
-	}
-	python_foreach_impl configuration
-}
-
-src_compile() {
-	compilation() {
-		run_in_build_dir autotools-utils_src_compile
-	}
-	python_foreach_impl compilation
-}
-
-src_test() {
-	testing() {
-		run_in_build_dir ${PYTHON} test/runtests.py --verbose 3 || die
-	}
-	python_foreach_impl testing
+	econf \
+		$(use_enable nls) \
+		$(use_with X x) \
+		--docdir="/usr/share/doc/${PF}" \
+		--libdir="$(python_get_sitedir)" \
+		--enable-site-packages
 }
 
 src_install() {
-	installation() {
-		run_in_build_dir autotools-utils_src_install
-		python_optimize "${ED}"/$(python_get_sitedir)
-	}
-	python_foreach_impl installation
+	default
 
 	rm "${D}/usr/share/doc/${PF}/README.html" || die
 	dohtml README.html
 }
+
+pkg_postinst() {
+	python_mod_optimize ${PN}
+}
+
+pkg_postrm() {
+	python_mod_cleanup ${PN}
+}



1.1                  net-im/gajim/gajim-0.15.2-r4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/gajim-0.15.2-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/gajim/gajim-0.15.2-r4.ebuild?rev=1.1&content-type=text/plain

Index: gajim-0.15.2-r4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/gajim/gajim-0.15.2-r4.ebuild,v 1.1 2013/02/23 10:32:18 jlec Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE="sqlite xml"

AUTOTOOLS_AUTORECONF=true

inherit autotools-utils python-r1 versionator

DESCRIPTION="Jabber client written in PyGTK"
HOMEPAGE="http://www.gajim.org/"
SRC_URI="
	http://www.gajim.org/downloads/$(get_version_component_range 1-2)/${P}.tar.bz2
	test? ( http://dev.gentoo.org/~jlec/distfiles/${PN}-tests-${PV}.tar.xz )"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="avahi crypt dbus gnome kde idle jingle libnotify networkmanager nls spell +srv test X xhtml"

REQUIRED_USE="
	libnotify? ( dbus )
	avahi? ( dbus )"

COMMON_DEPEND="
	dev-python/pygtk:2[${PYTHON_USEDEP}]
	x11-libs/gtk+:2"
DEPEND="${COMMON_DEPEND}
	>=dev-util/intltool-0.40.1
	virtual/pkgconfig
	>=sys-devel/gettext-0.17-r1"
RDEPEND="${COMMON_DEPEND}
	dev-python/pyasn1[${PYTHON_USEDEP}]
	dev-python/pyopenssl[${PYTHON_USEDEP}]
	crypt? (
		app-crypt/gnupg
		dev-python/pycrypto[${PYTHON_USEDEP}]
		)
	dbus? (
		dev-python/dbus-python[${PYTHON_USEDEP}]
		dev-libs/dbus-glib
		libnotify? ( dev-python/notify-python[${PYTHON_USEDEP}] )
		avahi? ( net-dns/avahi[dbus,gtk,python] )
		)
	gnome? (
		dev-python/libgnome-python
		dev-python/gnome-keyring-python
		dev-python/egg-python
		)
	idle? ( x11-libs/libXScrnSaver )
	jingle? ( net-libs/farstream:0.1[python] )
	kde? ( kde-base/kwallet )
	networkmanager? (
			dev-python/dbus-python[${PYTHON_USEDEP}]
			net-misc/networkmanager
		)
	spell? ( app-text/gtkspell:2 )
	srv? (
		|| (
			dev-python/libasyncns-python
			net-dns/bind-tools )
		)
	xhtml? ( dev-python/docutils )"

RESTRICT="test"

PATCHES=(
		"${FILESDIR}"/${P}-CVE-2012-5524.patch
	)

src_prepare() {
	echo "src/command_system/mapping.py" >> po/POTFILES.in
	echo '#!/bin/sh' > config/py-compile
	autotools-utils_src_prepare
	python_copy_sources
}

src_configure() {
	configuration() {
		local myeconfargs=(
			$(use_enable nls)
			$(use_with X x)
			--docdir="/usr/share/doc/${PF}"
			--libdir="$(python_get_sitedir)"
			--enable-site-packages
		)
		run_in_build_dir autotools-utils_src_configure
	}
	python_foreach_impl configuration
}

src_compile() {
	compilation() {
		run_in_build_dir autotools-utils_src_compile
	}
	python_foreach_impl compilation
}

src_test() {
	testing() {
		run_in_build_dir ${PYTHON} test/runtests.py --verbose 3 || die
	}
	python_foreach_impl testing
}

src_install() {
	installation() {
		run_in_build_dir autotools-utils_src_install
		python_optimize "${ED}"/$(python_get_sitedir)
	}
	python_foreach_impl installation

	rm "${D}/usr/share/doc/${PF}/README.html" || die
	dohtml README.html
}