[gentoo-commits] proj/kde:master commit in: kde-frameworks/kservice/

[Andreas Sturmlechner]

commit:     1c6ec5b07d10d39756419989c68cb637cdb4ab1e
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Feb  6 13:59:32 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Feb  6 21:38:01 2021 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=1c6ec5b0

kde-frameworks/kservice: 5.79.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-frameworks/kservice/kservice-5.79.0.ebuild | 51 ++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/kde-frameworks/kservice/kservice-5.79.0.ebuild b/kde-frameworks/kservice/kservice-5.79.0.ebuild
new file mode 100644
index 0000000000..b70e6261a0
--- /dev/null
+++ b/kde-frameworks/kservice/kservice-5.79.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Advanced plugin and service introspection"
+
+LICENSE="LGPL-2 LGPL-2.1+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="+man"
+
+# requires running kde environment
+RESTRICT+=" test"
+
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+	man? ( >=kde-frameworks/kdoctools-${PVCUT}:5 )
+"
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	=kde-frameworks/kconfig-${PVCUT}*:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/kcrash-${PVCUT}*:5
+	=kde-frameworks/kdbusaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+"
+DEPEND="${RDEPEND}
+	test? ( >=dev-qt/qtconcurrent-${QTMIN}:5 )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DAPPLICATIONS_MENU_NAME=kf5-applications.menu
+		$(cmake_use_find_package man KF5DocTools)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# bug 596316
+	dosym kf5-applications.menu /etc/xdg/menus/applications.menu
+}