[gentoo-commits] gentoo-x86 commit in media-sound/esound: ChangeLog esound-0.2.41.ebuild

[Gilles Dartiguelongue (eva)]

eva         08/11/23 22:23:41

  Modified:             ChangeLog
  Added:                esound-0.2.41.ebuild
  Log:
  Bump to 0.2.41.
  (Portage version: 2.2_rc15/cvs/Linux 2.6.24-gentoo-r8-mactel x86_64)

Revision  Changes    Path
1.120                media-sound/esound/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/esound/ChangeLog?rev=1.120&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/esound/ChangeLog?rev=1.120&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/esound/ChangeLog?r1=1.119&r2=1.120

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/esound/ChangeLog,v
retrieving revision 1.119
retrieving revision 1.120
diff -u -r1.119 -r1.120
--- ChangeLog	17 Nov 2008 21:49:05 -0000	1.119
+++ ChangeLog	23 Nov 2008 22:23:41 -0000	1.120
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/esound
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/esound/ChangeLog,v 1.119 2008/11/17 21:49:05 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/esound/ChangeLog,v 1.120 2008/11/23 22:23:41 eva Exp $
+
+*esound-0.2.41 (23 Nov 2008)
+
+  23 Nov 2008; Gilles Dartiguelongue <eva@g.o> +esound-0.2.41.ebuild:
+  Bump to 0.2.41.
 
   17 Nov 2008; Diego E. Pettenò <flameeyes@g.o>
   files/esound-0.2.32-amd64.patch:



1.1                  media-sound/esound/esound-0.2.41.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/esound/esound-0.2.41.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/esound/esound-0.2.41.ebuild?rev=1.1&content-type=text/plain

Index: esound-0.2.41.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/esound/esound-0.2.41.ebuild,v 1.1 2008/11/23 22:23:41 eva Exp $

inherit libtool gnome.org eutils flag-o-matic

DESCRIPTION="The Enlightened Sound Daemon"
HOMEPAGE="http://www.tux.org/~ricdude/EsounD.html"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="alsa debug doc ipv6 tcpd"

# esound comes with arts support, but it hasn't been tested yet, feel free to
# submit patches/improvements
COMMON_DEPEND=">=media-libs/audiofile-0.2.3
	alsa? ( >=media-libs/alsa-lib-0.5.10b )
	doc?  ( app-text/docbook-sgml-utils )
	tcpd? ( >=sys-apps/tcp-wrappers-7.6-r2 )"
#	arts? ( kde-base/arts )

DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig"

RDEPEND="${COMMON_DEPEND}
	app-admin/eselect-esd"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}/${PN}-0.2.39-fix-errno.patch"
}

src_compile() {
	# Strict aliasing problem
	append-flags -fno-strict-aliasing

	econf \
		--sysconfdir=/etc/esd \
		--htmldir=/usr/share/doc/${PF}/html \
		$(use_enable ipv6) \
		$(use_enable debug debugging) \
		$(use_enable alsa) \
		$(use_with tcpd libwrap) \
		--disable-dependency-tracking

	emake || die "Make failed"
}

src_install() {
	emake -j1 DESTDIR="${D}" install  || die "Installation failed"
	mv "${D}/usr/bin/"{esd,esound-esd}

	dodoc AUTHORS ChangeLog MAINTAINERS NEWS README TIPS TODO

	newconfd "${FILESDIR}/esound.conf.d" esound

	extradepend=""
	use tcpd && extradepend=" portmap"
	use alsa && extradepend="$extradepend alsasound"
	sed -e "s/@extradepend@/$extradepend/" "${FILESDIR}/esound.init.d.2" >"${T}/esound"
	doinitd "${T}/esound"
}

pkg_postinst() {
	eselect esd update --if-unset \
		|| die "eselect failed, try removing /usr/bin/esd and re-emerging."
}