[gentoo-commits] gentoo-x86 commit in net-p2p/qbittorrent: qbittorrent-2.9.3.ebuild ChangeLog

[Markos Chandras (hwoarang)]

hwoarang    11/12/30 10:53:31

  Modified:             ChangeLog
  Added:                qbittorrent-2.9.3.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha82/cvs/Linux x86_64)

Revision  Changes    Path
1.176                net-p2p/qbittorrent/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/qbittorrent/ChangeLog?rev=1.176&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/qbittorrent/ChangeLog?rev=1.176&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/qbittorrent/ChangeLog?r1=1.175&r2=1.176

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/ChangeLog,v
retrieving revision 1.175
retrieving revision 1.176
diff -u -r1.175 -r1.176
--- ChangeLog	29 Oct 2011 16:50:52 -0000	1.175
+++ ChangeLog	30 Dec 2011 10:53:31 -0000	1.176
@@ -1,6 +1,11 @@
 # ChangeLog for net-p2p/qbittorrent
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/ChangeLog,v 1.175 2011/10/29 16:50:52 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/ChangeLog,v 1.176 2011/12/30 10:53:31 hwoarang Exp $
+
+*qbittorrent-2.9.3 (30 Dec 2011)
+
+  30 Dec 2011; Markos Chandras <hwoarang@g.o> +qbittorrent-2.9.3.ebuild:
+  version bump
 
 *qbittorrent-2.9.2 (29 Oct 2011)
 



1.1                  net-p2p/qbittorrent/qbittorrent-2.9.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/qbittorrent/qbittorrent-2.9.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/qbittorrent/qbittorrent-2.9.3.ebuild?rev=1.1&content-type=text/plain

Index: qbittorrent-2.9.3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/qbittorrent-2.9.3.ebuild,v 1.1 2011/12/30 10:53:31 hwoarang Exp $

EAPI="2"
PYTHON_DEPEND="2"

inherit python qt4-r2 versionator

MY_P="${P/_/}"
DESCRIPTION="BitTorrent client in C++ and Qt"
HOMEPAGE="http://www.qbittorrent.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dbus +X geoip"

QT_MIN="4.6.1"
# boost version so that we always have thread support
CDEPEND="net-libs/rb_libtorrent
	>=x11-libs/qt-core-${QT_MIN}:4
	X? ( >=x11-libs/qt-gui-${QT_MIN}:4 )
	dbus? ( >=x11-libs/qt-dbus-${QT_MIN}:4 )
	dev-libs/boost"
DEPEND="${CDEPEND}
	dev-util/pkgconfig"
RDEPEND="${CDEPEND}
	geoip? ( dev-libs/geoip )"

DOCS="AUTHORS Changelog NEWS README TODO"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	# Respect LDFLAGS
	sed -i -e 's/-Wl,--as-needed/$(LDFLAGS)/g' src/src.pro
	qt4-r2_src_prepare
}

src_configure() {
	local myconf
	use X         || myconf+=" --disable-gui"
	use geoip     || myconf+=" --disable-geoip-database"
	use dbus 	  || myconf+=" --disable-qt-dbus"

	# slotted boost detection, bug #309415
	BOOST_PKG="$(best_version ">=dev-libs/boost-1.34.1")"
	BOOST_VER="$(get_version_component_range 1-2 "${BOOST_PKG/*boost-/}")"
	BOOST_VER="$(replace_all_version_separators _ "${BOOST_VER}")"
	myconf+=" --with-libboost-inc=/usr/include/boost-${BOOST_VER}"

	# econf fails, since this uses qconf
	./configure --prefix=/usr --qtdir=/usr ${myconf} || die "configure failed"
	eqmake4
}