[gentoo-commits] proj/gnome:master commit in: app-crypt/gcr/

[Gilles Dartiguelongue]

commit:     ccb73d438df478f1edb17cd183b21da5c0a6180e
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 20 22:30:43 2013 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Wed Nov 20 22:31:25 2013 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=ccb73d43

app-crypt/gcr: 3.8.2 → 3.10.1

---
 app-crypt/gcr/gcr-3.10.1.ebuild | 70 +++++++++++++++++++++++++++++++++++++++++
 app-crypt/gcr/gcr-9999.ebuild   | 51 ++++++++++++++++--------------
 2 files changed, 97 insertions(+), 24 deletions(-)

diff --git a/app-crypt/gcr/gcr-3.10.1.ebuild b/app-crypt/gcr/gcr-3.10.1.ebuild
new file mode 100644
index 0000000..f6d7f96
--- /dev/null
+++ b/app-crypt/gcr/gcr-3.10.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+GCONF_DEBUG="no"
+VALA_MIN_API_VERSION="0.18"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala virtualx
+
+DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
+HOMEPAGE="https://developer.gnome.org/gcr/"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/1" # subslot = suffix of libgcr-3
+IUSE="debug gtk +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+COMMON_DEPEND="
+	>=app-crypt/gnupg-2
+	>=app-crypt/p11-kit-0.19
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/libgcrypt-1.2.2:=
+	>=dev-libs/libtasn1-1:=
+	>=sys-apps/dbus-1
+	gtk? ( >=x11-libs/gtk+-3:3 )
+	introspection? ( >=dev-libs/gobject-introspection-1.34 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<gnome-base/gnome-keyring-3.3
+"
+# gcr was part of gnome-keyring until 3.3
+DEPEND="${COMMON_DEPEND}
+	dev-libs/gobject-introspection-common
+	dev-util/gdbus-codegen
+	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+# eautoreconf needs:
+#	dev-libs/gobject-introspection-common
+
+src_prepare() {
+	# Disable stupid flag changes
+	sed -e 's/CFLAGS="$CFLAGS -g"//' \
+		-e 's/CFLAGS="$CFLAGS -O0"//' \
+		-i configure.ac configure || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+	gnome2_src_configure \
+		$(use_with gtk) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		$(usex debug --enable-debug=yes --enable-debug=default) \
+		--disable-update-icon-cache \
+		--disable-update-mime
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	Xemake check
+}

diff --git a/app-crypt/gcr/gcr-9999.ebuild b/app-crypt/gcr/gcr-9999.ebuild
index d1afa69..0067941 100644
--- a/app-crypt/gcr/gcr-9999.ebuild
+++ b/app-crypt/gcr/gcr-9999.ebuild
@@ -1,22 +1,24 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Header: $
 
-EAPI="4"
+EAPI="5"
 GCONF_DEBUG="no"
-GNOME2_LA_PUNT="yes"
+VALA_MIN_API_VERSION="0.18"
+VALA_USE_DEPEND="vapigen"
 
-inherit gnome2 virtualx
+inherit gnome2 vala virtualx
 if [[ ${PV} = 9999 ]]; then
 	inherit gnome2-live
 fi
 
 DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
-HOMEPAGE="http://www.gnome.org/"
+HOMEPAGE="https://developer.gnome.org/gcr/"
 
 LICENSE="GPL-2+ LGPL-2+"
-SLOT="0"
-IUSE="debug +introspection"
+SLOT="0/1" # subslot = suffix of libgcr-3
+IUSE="debug gtk +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
 if [[ ${PV} = 9999 ]]; then
 	IUSE="${IUSE} doc"
 	KEYWORDS=""
@@ -26,13 +28,13 @@ fi
 
 COMMON_DEPEND="
 	>=app-crypt/gnupg-2
-	>=app-crypt/p11-kit-0.6
+	>=app-crypt/p11-kit-0.19
 	>=dev-libs/glib-2.32:2
-	>=dev-libs/libgcrypt-1.2.2
-	>=dev-libs/libtasn1-1
-	>=sys-apps/dbus-1.0
-	>=x11-libs/gtk+-3.0:3
-	introspection? ( >=dev-libs/gobject-introspection-1.29 )
+	>=dev-libs/libgcrypt-1.2.2:=
+	>=dev-libs/libtasn1-1:=
+	>=sys-apps/dbus-1
+	gtk? ( >=x11-libs/gtk+-3:3 )
+	introspection? ( >=dev-libs/gobject-introspection-1.34 )
 "
 RDEPEND="${COMMON_DEPEND}
 	!<gnome-base/gnome-keyring-3.3
@@ -45,6 +47,7 @@ DEPEND="${COMMON_DEPEND}
 	>=dev-util/intltool-0.35
 	sys-devel/gettext
 	virtual/pkgconfig
+	vala? ( $(vala_depend) )
 "
 # eautoreconf needs:
 #	dev-libs/gobject-introspection-common
@@ -55,17 +58,6 @@ if [[ ${PV} = 9999 ]]; then
 fi
 
 src_prepare() {
-	DOCS="AUTHORS ChangeLog HACKING NEWS README"
-	G2CONF="${G2CONF}
-		$(use_enable introspection)
-		--enable-debug=default
-		--disable-update-icon-cache
-		--disable-update-mime"
-
-	if use debug; then
-		G2CONF="${G2CONF} --enable-debug=yes"
-	fi
-
 	# Disable stupid flag changes
 	sed -e 's/CFLAGS="$CFLAGS -g"//' \
 		-e 's/CFLAGS="$CFLAGS -O0"//' \
@@ -74,6 +66,17 @@ src_prepare() {
 	gnome2_src_prepare
 }
 
+src_configure() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+	gnome2_src_configure \
+		$(use_with gtk) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		$(usex debug --enable-debug=yes --enable-debug=default) \
+		--disable-update-icon-cache \
+		--disable-update-mime
+}
+
 src_test() {
 	unset DBUS_SESSION_BUS_ADDRESS
 	Xemake check