[gentoo-commits] repo/gentoo:master commit in: dev-libs/libcec/

[Patrice Clement]

commit:     012e9e12edca0a75c2defefac6e444e2b4ebc665
Author:     Anthony Ryan <anthonyryan1 <AT> gmail <DOT> com>
AuthorDate: Sat Oct 22 22:26:09 2016 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Wed Oct 26 21:11:12 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=012e9e12

dev-libs/libcec: various fixes.

This commit:
* bumps to EAPI=6.
* fixes improper linux-info check.
* cleans up cmake configure blocks.
* adds post-install note about uutp.
* adds missing version dependency on libplatform >= 2.

Gentoo-Bug: https://bugs.gentoo.org/588926
Gentoo-Bug: https://bugs.gentoo.org/597834

Closes: https://github.com/gentoo/gentoo/pull/2641

Signed-off-by: Patrice Clement <monsieurp <AT> gentoo.org>

 dev-libs/libcec/libcec-3.1.0-r1.ebuild | 79 ++++++++++++++++++++++++++++++++++
 1 file changed, 79 insertions(+)

diff --git a/dev-libs/libcec/libcec-3.1.0-r1.ebuild b/dev-libs/libcec/libcec-3.1.0-r1.ebuild
new file mode 100644
index 00000000..dee8065
--- /dev/null
+++ b/dev-libs/libcec/libcec-3.1.0-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit cmake-utils linux-info python-single-r1 toolchain-funcs
+
+DESCRIPTION="Library for communicating with the Pulse-Eight USB HDMI-CEC Adaptor"
+HOMEPAGE="http://libcec.pulse-eight.com"
+SRC_URI="https://github.com/Pulse-Eight/${PN}/archive/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="cubox exynos python raspberry-pi +xrandr"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="virtual/udev
+	>=dev-libs/libplatform-2.0.0
+	raspberry-pi? ( >=media-libs/raspberrypi-userland-0_pre20160305-r1 )
+	xrandr? ( x11-libs/libXrandr )
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+	python? ( dev-lang/swig )
+	virtual/pkgconfig"
+
+CONFIG_CHECK="~USB_ACM"
+
+S="${WORKDIR}/${PN}-${P}"
+
+pkg_pretend() {
+	linux-info_pkg_setup
+}
+
+pkg_setup() {
+	linux-info_pkg_setup
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# Do not hardcode the python libpath #577612
+	sed -i \
+		-e '/DESTINATION/s:lib/python${PYTHON_VERSION}/dist-packages:${PYTHON_SITEDIR}:' \
+		src/libcec/cmake/CheckPlatformSupport.cmake || die
+
+	use python || cmake_comment_add_subdirectory "src/pyCecClient"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSKIP_PYTHON_WRAPPER=$(usex python)
+		-DHAVE_EXYNOS_API=$(usex exynos)
+		-DHAVE_TDA955X_API=$(usex cubox)
+		-DHAVE_RPI_API=$(usex raspberry-pi)
+	)
+	use python && mycmakeargs+=(
+		-DPYTHON_SITEDIR="$(python_get_sitedir)"
+	)
+
+	# raspberrypi-userland itself does not provide .pc file so using
+	# bcm_host.pc instead
+	use raspberry-pi && mycmakeargs+=(
+		-DRPI_INCLUDE_DIR=$( $(tc-getPKG_CONFIG) --variable=includedir bcm_host) \
+		-DRPI_LIB_DIR=$( $(tc-getPKG_CONFIG) --variable=libdir bcm_host)
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	elog "You will need to ensure the user running your CEC client has"
+	elog "read/write access to the device. You can ensure this by adding"
+	elog "them to the uucp group"
+}