[gentoo-commits] gentoo-x86 commit in net-misc/chrony: ChangeLog chrony-1.26_pre1.ebuild

[Jeroen Roovers (jer)]

jer         11/07/05 15:40:48

  Modified:             ChangeLog
  Added:                chrony-1.26_pre1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha43/cvs/Linux x86_64)

Revision  Changes    Path
1.78                 net-misc/chrony/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/ChangeLog?rev=1.78&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/ChangeLog?rev=1.78&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/ChangeLog?r1=1.77&r2=1.78

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v
retrieving revision 1.77
retrieving revision 1.78
diff -u -r1.77 -r1.78
--- ChangeLog	25 Jun 2011 18:56:43 -0000	1.77
+++ ChangeLog	5 Jul 2011 15:40:48 -0000	1.78
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/chrony
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v 1.77 2011/06/25 18:56:43 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/ChangeLog,v 1.78 2011/07/05 15:40:48 jer Exp $
+
+*chrony-1.26_pre1 (05 Jul 2011)
+
+  05 Jul 2011; Jeroen Roovers <jer@g.o> +chrony-1.26_pre1.ebuild:
+  Version bump.
 
   25 Jun 2011; Raúl Porcel <armin76@g.o> chrony-1.25.ebuild:
   sparc stable wrt #370485



1.1                  net-misc/chrony/chrony-1.26_pre1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/chrony-1.26_pre1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/chrony/chrony-1.26_pre1.ebuild?rev=1.1&content-type=text/plain

Index: chrony-1.26_pre1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/chrony-1.26_pre1.ebuild,v 1.1 2011/07/05 15:40:48 jer Exp $

EAPI=2

inherit eutils toolchain-funcs

MY_P=${P/_/-}

DESCRIPTION="NTP client and server programs"
HOMEPAGE="http://chrony.tuxfamily.org/"
SRC_URI="http://download.tuxfamily.org/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~mips ~ppc ~sparc ~x86"
IUSE="caps readline"

RDEPEND="
	readline? ( >=sys-libs/readline-4.1-r4 )
	caps? ( sys-libs/libcap )
"
DEPEND="${RDEPEND}"

S="${WORKDIR}"/${MY_P}

src_prepare() {
	sed -i "s:/etc/chrony\.:/etc/chrony/chrony.:g" \
		examples/* chrony*.{1,5,8} faq.txt chrony.texi || die "sed failed"
}

src_configure() {
	tc-export CC
	local myconf
	use readline || myconf+=" --disable-readline"
	#use ipv6     || myconf+=" --disable-ipv6"
	use caps     || myconf+=" --disable-linuxcaps"
	# selfwritten configure
	./configure \
		--prefix=/usr \
		--sysconfdir=/etc/chrony \
		--infodir=/usr/share/info \
		--mandir=/usr/share/man \
		--docdir=/usr/share/doc/${PF} \
		${myconf} ${EXTRA_ECONF} || die "configure failed"
}

src_compile() {
	emake all || die "make failed"
	emake docs || die "make docs failed"
}

src_install() {
	emake DESTDIR="${D}" install || die
	rm "${D}"/usr/share/doc/${PF}/COPYING || die
	dodoc examples/chrony.{conf,keys}.example || die
	doinfo chrony.info* || die

	newinitd "${FILESDIR}"/chronyd.rc chronyd || die
	newconfd "${FILESDIR}"/chronyd.conf chronyd || die

	keepdir /var/{lib,log}/chrony /etc/chrony

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/chrony.logrotate chrony
}