[gentoo-commits] gentoo-x86 commit in net-voip/yate: yate-2.0.0.ebuild ChangeLog metadata.xml

[Mounir Lamouri (volkmar)]

volkmar     09/07/30 14:38:04

  Modified:             ChangeLog metadata.xml
  Added:                yate-2.0.0.ebuild
  Log:
  Version bump to 2.0.0.
  Bug 272280.
  (Portage version: 13845-svn/cvs/Linux i686)

Revision  Changes    Path
1.9                  net-voip/yate/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/yate/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/yate/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/yate/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-voip/yate/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	16 May 2009 14:39:57 -0000	1.8
+++ ChangeLog	30 Jul 2009 14:38:04 -0000	1.9
@@ -1,6 +1,15 @@
 # ChangeLog for net-voip/yate
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-voip/yate/ChangeLog,v 1.8 2009/05/16 14:39:57 volkmar Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-voip/yate/ChangeLog,v 1.9 2009/07/30 14:38:04 volkmar Exp $
+
+*yate-2.0.0 (30 Jul 2009)
+
+  30 Jul 2009; Mounir Lamouri <volkmar@g.o>
+  +files/yate-2.0.0-as-needed.patch, +files/yate-2.0.0-cxxflags.patch,
+  +files/yate-2.0.0-ilbc-alsa-oss.patch, +files/yate-2.0.0-spandsp.patch,
+  files/yate.confd, +files/yate.initd, files/yate.rc6, metadata.xml,
+  +yate-2.0.0.ebuild:
+  Version bump to 2.0.0. Fixing bug 272280.
 
   16 May 2009; Mounir Lamouri <volkmar@g.o> metadata.xml:
   Use global gsm USE flag instead of local one.



1.4                  net-voip/yate/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/yate/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/yate/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/yate/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-voip/yate/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	16 May 2009 14:39:57 -0000	1.3
+++ metadata.xml	30 Jul 2009 14:38:04 -0000	1.4
@@ -1,10 +1,21 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>voip</herd>
-<use>
-	<flag name='h323'>Build H.323 Channel plugin</flag>
-	<flag name='ilbc'>Build ILBC codec plugin</flag>
-	<flag name='zaptel'>Build zaptel Channel plugin</flag>
-</use>
+	<herd>voip</herd>
+	<maintainer>
+		<email>volkmar@g.o</email>
+		<name>Mounir Lamouri</name>
+	</maintainer>
+	<use>
+		<flag name='amrnb'>
+			Enables Adaptive Multi-Rate Audio support (Narrow Band)
+		</flag>
+		<flag name='h323'>Build H.323 Channel plugin</flag>
+		<flag name='ilbc'>Build ILBC codec plugin</flag>
+		<flag name='sctp'>
+			Support for Stream Control Transmission Protocol
+		</flag>
+		<flag name='spandsp'>Enable support for the spandsp codec</flag>
+		<flag name='zaptel'>Build zaptel Channel plugin</flag>
+	</use>
 </pkgmetadata>



1.1                  net-voip/yate/yate-2.0.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/yate/yate-2.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-voip/yate/yate-2.0.0.ebuild?rev=1.1&content-type=text/plain

Index: yate-2.0.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-voip/yate/yate-2.0.0.ebuild,v 1.1 2009/07/30 14:38:04 volkmar Exp $

EAPI="2"

inherit autotools eutils multilib

DESCRIPTION="Yet Another Telephony Engine"
HOMEPAGE="http://yate.null.ro/"
SRC_URI="http://yate.null.ro/tarballs/yate2/${P}-1.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa amrnb debug doc gsm h323 ilbc mysql oss postgres qt4 sctp spandsp
speex ssl zaptel"

RDEPEND="
	sys-libs/glibc
	alsa? ( media-libs/alsa-lib )
	amrnb? ( media-libs/amrnb )
	gsm? ( media-sound/gsm )
	h323? ( dev-libs/pwlib
		net-libs/openh323 )
	ilbc? ( dev-libs/ilbc-rfc3951 )
	mysql? ( virtual/mysql )
	oss? ( sys-kernel/linux-headers )
	postgres? ( virtual/postgresql-base )
	qt4? ( x11-libs/qt-core:4
		x11-libs/qt-gui:4 )
	spandsp? ( >=media-libs/spandsp-0.0.3 )
	speex? ( media-libs/speex )
	ssl? ( dev-libs/openssl )
	zaptel? ( net-misc/zaptel )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/${PN}

# NOTES:
# doc is already built

# TODO:
# coredumper can't be used because not in the tree, bug 118716
# wanpipe can't be used because not in the tree (but voip overlay), bug 188939
# spandsp >= 0.0.6 fails in configure and >=0.0.5 fails in build
# fix bug 199222 for this version

src_prepare() {
	# add Icon in yate-qt4 desktop file
	sed -i -e '/^Exec=yate-qt4$/a Icon=null_team-32.png' \
		clients/yate-qt4.desktop || die "sed failed"

	epatch "${FILESDIR}"/${P}-ilbc-alsa-oss.patch
	epatch "${FILESDIR}"/${P}-cxxflags.patch
	epatch "${FILESDIR}"/${P}-spandsp.patch
	epatch "${FILESDIR}"/${P}-as-needed.patch

	eautoreconf
}

src_configure() {
	# fdsize, inline, rtti: keep default values
	# internalregex: use system
	# coredumper: not in the tree, bug 118716
	# wanpipe, wphwec: not in the tree, bug 188939
	# doxygen, kdoc: no need to rebuild already built doc
	econf \
		--disable-internalregex \
		--without-coredumper \
		--disable-wanpipe \
		--without-wphwec \
		--without-doxygen \
		--without-kdoc \
		--with-archlib=$(get_libdir) \
		$(use_with amrnb amrnb /usr) \
		$(use_enable alsa) \
		$(use_with gsm libgsm) \
		$(use_with h323 openh323 /usr) \
		$(use_with h323 pwlib /usr) \
		$(use_enable ilbc) \
		$(use_with mysql mysql /usr) \
		$(use_enable oss) \
		$(use_with postgres libpq /usr) \
		$(use_with qt4 libqt4) \
		$(use_enable sctp) \
		$(use_with spandsp) \
		$(use_with speex libspeex) \
		$(use_with ssl openssl) \
		$(use_enable zaptel)
}

src_compile() {
	if use debug; then
		emake ddebug || die "emake ddebug failed"
	else
		default_src_compile
	fi
}

src_test() {
	# there is no real test suite
	# 'make test' tries to execute non-existing ./test
	# do not add RESTRICT="test" because it's not a failing test suite
	:
}

src_install() {
	emake DESTDIR="${D}" install-noapi || die "emake install-noapi failed"

	dodoc ChangeLog README || die "dodoc failed"

	insinto /etc/logrotate.d
	newins packing/${PN}.logrotate ${PN} || die "newins failed"

	newinitd "${FILESDIR}"/${PN}.initd ${PN} || die "newinitd failed"
	newconfd "${FILESDIR}"/${PN}.confd ${PN} || die "newconfd failed"

	if use doc; then
		emake DESTDIR="${D}" install-api || die "emake install-api failed"
	fi
}