[gentoo-commits] repo/gentoo:master commit in: app-portage/elogv/

[Sebastian Pipping]

commit:     b08bf08f317dc8202752b259c73f32fbfc781cd9
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 30 18:05:03 2022 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Sat Apr 30 18:07:27 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b08bf08f

app-portage/elogv: Improve LINGUAS cleanup code

Closes: https://bugs.gentoo.org/839207
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
Package-Manager: Portage-3.0.30, Repoman-3.0.3

 app-portage/elogv/elogv-0.7.9-r1.ebuild | 56 +++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/app-portage/elogv/elogv-0.7.9-r1.ebuild b/app-portage/elogv/elogv-0.7.9-r1.ebuild
new file mode 100644
index 000000000000..5f0a98be9ddf
--- /dev/null
+++ b/app-portage/elogv/elogv-0.7.9-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+PYTHON_REQ_USE="ncurses"
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit distutils-r1
+
+DESCRIPTION="Curses based utility to parse the contents of elogs created by Portage"
+HOMEPAGE="https://gitweb.gentoo.org/proj/elogv.git/"
+SRC_URI="https://github.com/gentoo/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+
+RDEPEND="sys-apps/portage[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+DOCS=( README )
+
+src_install() {
+	distutils-r1_src_install
+
+	# unset LINGUAS => install all languages
+	# empty LINGUAS => install none
+	local i
+	if [[ -n "${LINGUAS+x}" ]] ; then
+		elog 'Deleting unwanted language files...'
+		for i in $(cd "${ED}"/usr/share/locale/ && ls -1) ; do
+			if ! has "${i}" "${LINGUAS}" ; then
+				rm -rf "${ED}"/usr/share/{locale,man}/"${i}"
+				elog "- Language \"${i}\" deleted"
+			fi
+		done
+	fi
+}
+
+pkg_postinst() {
+	elog "In order to use this software, you need to activate"
+	elog "Portage's elog features.  Required is"
+	elog "		 PORTAGE_ELOG_SYSTEM=\"save\" "
+	elog "and at least one out of "
+	elog "		 PORTAGE_ELOG_CLASSES=\"warn error info log qa\""
+	elog "More information on the elog system can be found"
+	elog "in ${EPREFIX}/usr/share/portage/config/make.conf.example"
+	elog
+	elog "To operate properly this software needs the directory"
+	elog "${PORT_LOGDIR:-${EPREFIX}/var/log/portage}/elog created, belonging to group portage."
+	elog "To start the software as a user, add yourself to the portage"
+	elog "group."
+	elog
+}