[gentoo-commits] gentoo-x86 commit in sys-fs/cryptsetup: cryptsetup-1.1.1_rc1.ebuild ChangeLog

[Robin H. Johnson (robbat2)]

robbat2     10/05/01 21:40:39

  Modified:             ChangeLog
  Added:                cryptsetup-1.1.1_rc1.ebuild
  Log:
  Bug #318039: version bump.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.81                 sys-fs/cryptsetup/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/cryptsetup/ChangeLog?rev=1.81&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/cryptsetup/ChangeLog?rev=1.81&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/cryptsetup/ChangeLog?r1=1.80&r2=1.81

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/cryptsetup/ChangeLog,v
retrieving revision 1.80
retrieving revision 1.81
diff -p -w -b -B -u -u -r1.80 -r1.81
--- ChangeLog	23 Apr 2010 19:35:04 -0000	1.80
+++ ChangeLog	1 May 2010 21:40:39 -0000	1.81
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/cryptsetup
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/cryptsetup/ChangeLog,v 1.80 2010/04/23 19:35:04 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/cryptsetup/ChangeLog,v 1.81 2010/05/01 21:40:39 robbat2 Exp $
+
+*cryptsetup-1.1.1_rc1 (01 May 2010)
+
+  01 May 2010; Robin H. Johnson <robbat2@g.o>
+  +cryptsetup-1.1.1_rc1.ebuild:
+  Bug #318039: version bump.
 
   23 Apr 2010; Robin H. Johnson <robbat2@g.o>
   +files/1.1.0-libudev.patch, cryptsetup-1.1.0.ebuild:



1.1                  sys-fs/cryptsetup/cryptsetup-1.1.1_rc1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/cryptsetup/cryptsetup-1.1.1_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/cryptsetup/cryptsetup-1.1.1_rc1.ebuild?rev=1.1&content-type=text/plain

Index: cryptsetup-1.1.1_rc1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/cryptsetup/cryptsetup-1.1.1_rc1.ebuild,v 1.1 2010/05/01 21:40:39 robbat2 Exp $

EAPI=2

inherit linux-info eutils flag-o-matic multilib autotools

MY_P=${P/_rc/-rc}
DESCRIPTION="Tool to setup encrypted devices with dm-crypt"
HOMEPAGE="http://code.google.com/p/cryptsetup/"
SRC_URI="http://cryptsetup.googlecode.com/files/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="dynamic nls selinux"

S=${WORKDIR}/${MY_P}

DEPEND=">=sys-fs/lvm2-2.02.64
	>=dev-libs/libgcrypt-1.1.42
	>=dev-libs/libgpg-error-1.0-r1
	>=dev-libs/popt-1.7
	>=sys-fs/udev-124
	|| ( >=sys-libs/e2fsprogs-libs-1.41 <sys-fs/e2fsprogs-1.41 )
	selinux? ( sys-libs/libselinux )
	!sys-fs/cryptsetup-luks"

pkg_setup() {
	local CONFIG_CHECK="~DM_CRYPT ~CRYPTO ~CRYPTO_CBC"
	local WARNING_DM_CRYPT="CONFIG_DM_CRYPT:\tis not set (required for cryptsetup)\n"
	local WARNING_CRYPTO_CBC="CONFIG_CRYPTO_CBC:\tis not set (required for kernel 2.6.19)\n"
	local WARNING_CRYPTO="CONFIG_CRYPTO:\tis not set (required for cryptsetup)\n"
	check_extra_config

	if use dynamic ; then
		ewarn "If you need cryptsetup for an initrd or initramfs then you"
		ewarn "should NOT use the dynamic USE flag"
		epause 5
	fi
}

src_prepare() {
	# Merged upstream
	#epatch "${FILESDIR}"/1.1.0_rc3-static-no-selinux.patch
	epatch "${FILESDIR}"/1.1.0-libudev.patch
	eautoreconf
	:
}

src_configure() {
	econf \
		--sbindir=/sbin \
		--enable-shared \
		$(use_enable !dynamic static) \
		--libdir=/usr/$(get_libdir) \
		$(use_enable nls) \
		$(use_enable selinux) \
		|| die
}

src_compile() {
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"
	rmdir "${D}"/usr/$(get_libdir)/cryptsetup
	insinto /$(get_libdir)/rcscripts/addons
	newins "${FILESDIR}"/1.0.6-r2-dm-crypt-start.sh dm-crypt-start.sh || die
	newins "${FILESDIR}"/1.0.5-dm-crypt-stop.sh dm-crypt-stop.sh || die
	newconfd "${FILESDIR}"/1.0.6-dmcrypt.confd dmcrypt || die
	newinitd "${FILESDIR}"/1.0.5-dmcrypt.rc dmcrypt || die
}

pkg_postinst() {
	ewarn "This ebuild introduces a new set of scripts and configuration"
	ewarn "than the last version. If you are currently using /etc/conf.d/cryptfs"
	ewarn "then you *MUST* copy your old file to:"
	ewarn "/etc/conf.d/dmcrypt"
	ewarn "Or your encrypted partitions will *NOT* work."
	elog "Please see the example for configuring a LUKS mountpoint"
	elog "in /etc/conf.d/dmcrypt"
	elog
	elog "If you are using baselayout-2 then please do:"
	elog "rc-update add dmcrypt boot"
	elog "This version introduces a command line arguement 'key_timeout'."
	elog "If you want the search for the removable key device to timeout"
	elog "after 10 seconds add the following to your bootloader config:"
	elog "key_timeout=10"
	elog "A timeout of 0 will mean it will wait indefinitely."
}