[gentoo-commits] repo/gentoo:master commit in: dev-ruby/ruby-elf/

[Hans de Graaff]

commit:     00f269768d9782aeadb918aa169947d065d8b30e
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 25 08:46:37 2021 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Thu Nov 25 09:09:53 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=00f26976

dev-ruby/ruby-elf: add ruby27, ruby30

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 dev-ruby/ruby-elf/ruby-elf-1.0.8-r1.ebuild | 53 ++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/dev-ruby/ruby-elf/ruby-elf-1.0.8-r1.ebuild b/dev-ruby/ruby-elf/ruby-elf-1.0.8-r1.ebuild
new file mode 100644
index 000000000000..1e982e1d37ee
--- /dev/null
+++ b/dev-ruby/ruby-elf/ruby-elf-1.0.8-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby26 ruby27 ruby30"
+
+GITHUB_URI="https://github.com/Flameeyes/${PN}"
+
+RUBY_FAKEGEM_RECIPE_TEST="none"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+SRC_URI="${GITHUB_URI}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+DESCRIPTION="Ruby library to access ELF files information"
+HOMEPAGE="http://www.flameeyes.eu/projects/ruby-elf"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="test"
+
+ruby_add_bdepend "
+	test? ( dev-ruby/test-unit:2 )
+	dev-ruby/rake"
+
+# for the man pages
+DEPEND+="
+	dev-libs/libxslt
+	app-text/docbook-xsl-ns-stylesheets"
+
+RDEPEND+="
+	virtual/man"
+
+all_ruby_compile() {
+	# build the man pages
+	rake manpages || die "rake manpages failed"
+}
+
+each_ruby_test() {
+	ruby-ng_testrb-2 -Ilib test/test_*.rb
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	doman manpages/*.1
+	dodoc DONATING README.md
+}