[gentoo-commits] gentoo-x86 commit in app-misc/ddccontrol: ddccontrol-0.4.2_p20140105.ebuild ChangeLog

[Manuel Rueger (mrueg)]

mrueg       14/01/30 18:49:55

  Modified:             ChangeLog
  Added:                ddccontrol-0.4.2_p20140105.ebuild
  Log:
  Add new snapshot.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key )

Revision  Changes    Path
1.36                 app-misc/ddccontrol/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/ddccontrol/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/ddccontrol/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/ddccontrol/ChangeLog?r1=1.35&r2=1.36

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/ddccontrol/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog	4 Jan 2014 04:46:54 -0000	1.35
+++ ChangeLog	30 Jan 2014 18:49:55 -0000	1.36
@@ -1,6 +1,12 @@
 # ChangeLog for app-misc/ddccontrol
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/ddccontrol/ChangeLog,v 1.35 2014/01/04 04:46:54 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/ddccontrol/ChangeLog,v 1.36 2014/01/30 18:49:55 mrueg Exp $
+
+*ddccontrol-0.4.2_p20140105 (30 Jan 2014)
+
+  30 Jan 2014; Manuel Rüger <mrueg@g.o>
+  +ddccontrol-0.4.2_p20140105.ebuild:
+  Add new snapshot.
 
 *ddccontrol-0.4.2_p20130703 (04 Jan 2014)
 



1.1                  app-misc/ddccontrol/ddccontrol-0.4.2_p20140105.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/ddccontrol/ddccontrol-0.4.2_p20140105.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/ddccontrol/ddccontrol-0.4.2_p20140105.ebuild?rev=1.1&content-type=text/plain

Index: ddccontrol-0.4.2_p20140105.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/ddccontrol/ddccontrol-0.4.2_p20140105.ebuild,v 1.1 2014/01/30 18:49:55 mrueg Exp $

EAPI=5

inherit eutils autotools

DESCRIPTION="DDCControl allows control of monitor parameters via DDC"
HOMEPAGE="http://ddccontrol.sourceforge.net/"
COMMIT_ID="9d89d8c0b959a4da62ecc50fb2aeb23142d4bfb4"
SRC_URI="https://github.com/ddccontrol/ddccontrol/archive/${COMMIT_ID}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="+ddcpci doc gnome gtk nls static-libs video_cards_fglrx"
S=${WORKDIR}/${PN}-${COMMIT_ID}

RDEPEND="app-misc/ddccontrol-db
	dev-libs/libxml2:2
	sys-apps/pciutils
	gtk? ( x11-libs/gtk+:2 )
	gnome? ( >=gnome-base/gnome-panel-2.10 )
	nls? ( sys-devel/gettext )
	video_cards_fglrx? ( x11-libs/amd-adl-sdk )"
DEPEND="${RDEPEND}
	dev-perl/XML-Parser
	dev-util/intltool
	sys-kernel/linux-headers
	doc? ( >=app-text/docbook-xsl-stylesheets-1.65.1
		   >=dev-libs/libxslt-1.1.6
	       app-text/htmltidy )"

src_prepare() {
	sed -i 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' configure.ac || die #467574
	sed -i '/;Application/d' src/gddccontrol/gddccontrol.desktop.in || die

	# ppc/ppc64 do not have inb/outb/ioperm
	# they also do not have (sys|asm)/io.h
	if ! use amd64 && ! use x86 ; then
		local card
		for card in sis intel810 ; do
			sed -r -i \
				-e "/${card}.Po/d" \
				-e "s~${card}[^[:space:]]*~ ~g" \
				src/ddcpci/Makefile.{am,ini} || die
		done
		sed -i \
			-e '/sis_/d' \
			-e '/i810_/d' \
			src/ddcpci/main.c || die
	fi

	## Save for a rainy day or future patching
	touch config.rpath ABOUT-NLS
	eautoreconf
	intltoolize --force || die "intltoolize failed"
}

src_configure() {
	econf \
		--htmldir='$(datarootdir)'/doc/${PF}/html \
		$(use_enable ddcpci) \
		$(use_enable doc) \
		$(use_enable gnome gnome-applet) \
		$(use_enable gtk gnome) \
		$(use_enable nls) \
		$(use_enable static-libs static) \
		$(use_enable video_cards_fglrx amdadl)
}

src_install() {
	default
	use static-libs || find "${ED}" -name '*.la' -delete
}