[gentoo-commits] gentoo-x86 commit in dev-util/dialog: dialog-1.2.20130928.ebuild ChangeLog

[Jeroen Roovers (jer)]

jer         13/09/29 15:38:18

  Modified:             ChangeLog
  Added:                dialog-1.2.20130928.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.186                dev-util/dialog/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/ChangeLog?rev=1.186&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/ChangeLog?rev=1.186&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/ChangeLog?r1=1.185&r2=1.186

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/dialog/ChangeLog,v
retrieving revision 1.185
retrieving revision 1.186
diff -u -r1.185 -r1.186
--- ChangeLog	29 Sep 2013 15:25:58 -0000	1.185
+++ ChangeLog	29 Sep 2013 15:38:18 -0000	1.186
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/dialog
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/ChangeLog,v 1.185 2013/09/29 15:25:58 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/ChangeLog,v 1.186 2013/09/29 15:38:18 jer Exp $
+
+*dialog-1.2.20130928 (29 Sep 2013)
+
+  29 Sep 2013; Jeroen Roovers <jer@g.o> +dialog-1.2.20130928.ebuild:
+  Version bump.
 
   29 Sep 2013; Jeroen Roovers <jer@g.o> -dialog-1.1.20120706.ebuild:
   Old.



1.1                  dev-util/dialog/dialog-1.2.20130928.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/dialog-1.2.20130928.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/dialog-1.2.20130928.ebuild?rev=1.1&content-type=text/plain

Index: dialog-1.2.20130928.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/dialog-1.2.20130928.ebuild,v 1.1 2013/09/29 15:38:18 jer Exp $

EAPI="4"

inherit eutils multilib versionator

MY_PV="$(get_version_component_range 1-2)-$(get_version_component_range 3)"
S=${WORKDIR}/${PN}-${MY_PV}
DESCRIPTION="tool to display dialog boxes from a shell"
HOMEPAGE="http://invisible-island.net/dialog/dialog.html"
SRC_URI="ftp://invisible-island.net/${PN}/${PN}-${MY_PV}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
IUSE="examples minimal nls static-libs unicode"

RDEPEND="
	>=sys-libs/ncurses-5.2-r5
	unicode? ( sys-libs/ncurses[unicode] )
"
DEPEND="
	${RDEPEND}
	nls? ( sys-devel/gettext )
	!minimal? ( sys-devel/libtool )
	!<=sys-freebsd/freebsd-contrib-8.9999
"

src_prepare() {
	sed -i configure -e '/LIB_CREATE=/s:${CC}:& ${LDFLAGS}:g' || die
	sed -i '/$(LIBTOOL_COMPILE)/s:$: $(LIBTOOL_OPTS):' makefile.in || die
}

src_configure() {
	econf \
		--disable-rpath-hack \
		$(use_enable nls) \
		$(use_with !minimal libtool) \
		--with-libtool-opts=$(usex static-libs '' '-shared') \
		--with-ncurses$(usex unicode w '')
}

src_install() {
	if use minimal; then
		default
	else
		emake DESTDIR="${D}" install-full
	fi

	dodoc CHANGES README

	use examples && dodoc -r samples

	use static-libs || prune_libtool_files
}