[gentoo-commits] gentoo-x86 commit in app-emulation/xen: xen-4.2.0-r2.ebuild xen-4.2.1-r1.ebuild xen-4.2.0-r1.ebuild xen-4.2.1-r2.ebuild ChangeLog

[Ian Delaney (idella4)]

idella4     13/02/24 08:23:59

  Modified:             xen-4.2.1-r1.ebuild xen-4.2.0-r1.ebuild ChangeLog
  Added:                xen-4.2.0-r2.ebuild xen-4.2.1-r2.ebuild
  Log:
  After further review, reverted both -r1 ebuilds, revbumped both to -r2, fixed deps and install, reduced efi.patch accordingly and re-named to xen-4.2-efi.patch, all wrt Bug #458160
  
  (Portage version: 2.1.11.40/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.4                  app-emulation/xen/xen-4.2.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xen/xen-4.2.1-r1.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xen/xen-4.2.1-r1.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xen/xen-4.2.1-r1.ebuild?r1=1.3&r2=1.4

Index: xen-4.2.1-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/xen/xen-4.2.1-r1.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- xen-4.2.1-r1.ebuild	23 Feb 2013 16:34:06 -0000	1.3
+++ xen-4.2.1-r1.ebuild	24 Feb 2013 08:23:59 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/xen/xen-4.2.1-r1.ebuild,v 1.3 2013/02/23 16:34:06 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/xen/xen-4.2.1-r1.ebuild,v 1.4 2013/02/24 08:23:59 idella4 Exp $
 
 EAPI=5
 
@@ -24,10 +24,9 @@
 
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="custom-cflags debug efi flask pae xsm"
+IUSE="custom-cflags debug flask pae xsm"
 
-RDEPEND="efi? ( >=sys-devel/binutils-2.22[multitarget] )
-		>=sys-devel/binutils-2.22[-multitarget]"
+RDEPEND=""
 PDEPEND="~app-emulation/xen-tools-${PV}"
 
 RESTRICT="test"
@@ -65,8 +64,6 @@
 	# Drop .config and fix gcc-4.6
 	epatch  "${FILESDIR}"/${PN/-pvgrub/}-4-fix_dotconfig-gcc.patch
 
-	use efi && epatch "${FILESDIR}"/${PN}-4-efi.patch
-
 	# if the user *really* wants to use their own custom-cflags, let them
 	if use custom-cflags; then
 		einfo "User wants their own CFLAGS - removing defaults"
@@ -110,7 +107,6 @@
 	local myopt
 	use debug && myopt="${myopt} debug=y"
 	use pae && myopt="${myopt} pae=y"
-	use efi && mkdir -p "${D}"/boot/efi
 
 	emake LDFLAGS="$(raw-ldflags)" DESTDIR="${D}" -C xen ${myopt} install
 }
@@ -121,5 +117,4 @@
 	elog " http://en.gentoo-wiki.com/wiki/Xen/"
 
 	use pae && ewarn "This is a PAE build of Xen. It will *only* boot PAE kernels!"
-	use efi && einfo "The efi executable is installed in boot/efi"
 }



1.8                  app-emulation/xen/xen-4.2.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xen/xen-4.2.0-r1.ebuild?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xen/xen-4.2.0-r1.ebuild?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xen/xen-4.2.0-r1.ebuild?r1=1.7&r2=1.8

Index: xen-4.2.0-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/xen/xen-4.2.0-r1.ebuild,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- xen-4.2.0-r1.ebuild	23 Feb 2013 16:34:06 -0000	1.7
+++ xen-4.2.0-r1.ebuild	24 Feb 2013 08:23:59 -0000	1.8
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/xen/xen-4.2.0-r1.ebuild,v 1.7 2013/02/23 16:34:06 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/xen/xen-4.2.0-r1.ebuild,v 1.8 2013/02/24 08:23:59 idella4 Exp $
 
 EAPI=5
 
@@ -24,10 +24,9 @@
 
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="custom-cflags debug efi flask pae xsm"
+IUSE="custom-cflags debug flask pae xsm"
 
-RDEPEND="efi? ( >=sys-devel/binutils-2.22[multitarget] )
-		 >=sys-devel/binutils-2.22[-multitarget]"
+RDEPEND=""
 PDEPEND="~app-emulation/xen-tools-${PV}[${PYTHON_USEDEP}]"
 
 RESTRICT="test"
@@ -65,8 +64,6 @@
 	# Drop .config, fix gcc-4.6
 	epatch "${FILESDIR}"/${PN}-4-fix_dotconfig-gcc.patch
 
-	use efi && epatch "${FILESDIR}"/${PN}-4-efi.patch
-
 	# if the user *really* wants to use their own custom-cflags, let them
 	if use custom-cflags; then
 		einfo "User wants their own CFLAGS - removing defaults"
@@ -119,7 +116,6 @@
 	local myopt
 	use debug && myopt="${myopt} debug=y"
 	use pae && myopt="${myopt} pae=y"
-	use efi && mkdir -p "${D}"/boot/efi
 
 	emake LDFLAGS="$(raw-ldflags)" DESTDIR="${D}" -C xen ${myopt} install
 }
@@ -130,5 +126,4 @@
 	elog " http://en.gentoo-wiki.com/wiki/Xen/"
 
 	use pae && ewarn "This is a PAE build of Xen. It will *only* boot PAE kernels!"
-	use efi && einfo "The efi executable is installed in boot/efi"
 }



1.110                app-emulation/xen/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xen/ChangeLog?rev=1.110&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xen/ChangeLog?rev=1.110&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xen/ChangeLog?r1=1.109&r2=1.110

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/xen/ChangeLog,v
retrieving revision 1.109
retrieving revision 1.110
diff -u -r1.109 -r1.110
--- ChangeLog	23 Feb 2013 16:34:06 -0000	1.109
+++ ChangeLog	24 Feb 2013 08:23:59 -0000	1.110
@@ -1,6 +1,16 @@
 # ChangeLog for app-emulation/xen
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/xen/ChangeLog,v 1.109 2013/02/23 16:34:06 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/xen/ChangeLog,v 1.110 2013/02/24 08:23:59 idella4 Exp $
+
+*xen-4.2.1-r2 (24 Feb 2013)
+*xen-4.2.0-r2 (24 Feb 2013)
+
+  24 Feb 2013; Ian Delaney <idella4@g.o> +files/xen-4.2-efi.patch,
+  +xen-4.2.0-r2.ebuild, +xen-4.2.1-r2.ebuild, -files/xen-4-efi.patch,
+  xen-4.2.0-r1.ebuild, xen-4.2.1-r1.ebuild:
+  After further review, reverted both -r1 ebuilds, revbumped both to -r2, fixed
+  deps and install, reduced efi.patch accordingly and re-named to
+  xen-4.2-efi.patch, all wrt Bug #458160
 
   23 Feb 2013; Ian Delaney <idella4@g.o> +files/xen-4-efi.patch,
   metadata.xml, xen-4.2.0-r1.ebuild, xen-4.2.1-r1.ebuild:



1.1                  app-emulation/xen/xen-4.2.0-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xen/xen-4.2.0-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xen/xen-4.2.0-r2.ebuild?rev=1.1&content-type=text/plain

Index: xen-4.2.0-r2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/xen/xen-4.2.0-r2.ebuild,v 1.1 2013/02/24 08:23:59 idella4 Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )

if [[ $PV == *9999 ]]; then
	KEYWORDS=""
	REPO="xen-unstable.hg"
	EHG_REPO_URI="http://xenbits.xensource.com/${REPO}"
	S="${WORKDIR}/${REPO}"
	live_eclass="mercurial"
else
	KEYWORDS="~amd64 ~x86"
	SRC_URI="http://bits.xensource.com/oss-xen/release/${PV}/xen-${PV}.tar.gz"
fi

inherit mount-boot flag-o-matic python-single-r1 toolchain-funcs ${live_eclass}

DESCRIPTION="The Xen virtual machine monitor"
HOMEPAGE="http://xen.org/"

LICENSE="GPL-2"
SLOT="0"
IUSE="custom-cflags debug efi flask pae xsm"

RDEPEND=""
PDEPEND="~app-emulation/xen-tools-${PV}[${PYTHON_USEDEP}]"

RESTRICT="test"

# Approved by QA team in bug #144032
QA_WX_LOAD="boot/xen-syms-${PV}"

REQUIRED_USE="
	flask? ( xsm )"

pkg_setup() {
	python-single-r1_pkg_setup

	if [[ -z ${XEN_TARGET_ARCH} ]]; then
		if use x86 && use amd64; then
			die "Confusion! Both x86 and amd64 are set in your use flags!"
		elif use x86; then
			export XEN_TARGET_ARCH="x86_32"
		elif use amd64; then
			export XEN_TARGET_ARCH="x86_64"
		else
			die "Unsupported architecture!"
		fi
	fi

	if use flask ; then
		export "XSM_ENABLE=y"
		export "FLASK_ENABLE=y"
	elif use xsm ; then
		export "XSM_ENABLE=y"
	fi
}

src_prepare() {
	# Drop .config, fix gcc-4.6
	epatch "${FILESDIR}"/${PN}-4-fix_dotconfig-gcc.patch

	if use efi; then
		epatch "${FILESDIR}"/${PN}-4.2-efi.patch
		export EFI_VENDOR="gentoo"
		export EFI_MOUNTPOINT="boot"
	fi

	# if the user *really* wants to use their own custom-cflags, let them
	if use custom-cflags; then
		einfo "User wants their own CFLAGS - removing defaults"
		# try and remove all the default custom-cflags
		find "${S}" -name Makefile -o -name Rules.mk -o -name Config.mk -exec sed \
			-e 's/CFLAGS\(.*\)=\(.*\)-O3\(.*\)/CFLAGS\1=\2\3/' \
			-e 's/CFLAGS\(.*\)=\(.*\)-march=i686\(.*\)/CFLAGS\1=\2\3/' \
			-e 's/CFLAGS\(.*\)=\(.*\)-fomit-frame-pointer\(.*\)/CFLAGS\1=\2\3/' \
			-e 's/CFLAGS\(.*\)=\(.*\)-g3*\s\(.*\)/CFLAGS\1=\2 \3/' \
			-e 's/CFLAGS\(.*\)=\(.*\)-O2\(.*\)/CFLAGS\1=\2\3/' \
			-i {} \; || die "failed to re-set custom-cflags"
	fi

	# not strictly necessary to fix this
	sed -i 's/, "-Werror"//' "${S}/tools/python/setup.py" || die "failed to re-set setup.py"

	#Security patches
	epatch "${FILESDIR}"/${PN}-4-CVE-2012-4535-XSA-20.patch \
		"${FILESDIR}"/${PN}-4-CVE-2012-4537-XSA-22.patch \
		"${FILESDIR}"/${PN}-4-CVE-2012-4538-XSA-23.patch \
		"${FILESDIR}"/${PN}-4-CVE-2012-4539-XSA-24.patch \
		"${FILESDIR}"/${PN}-4-CVE-2012-5510-XSA-26.patch \
		"${FILESDIR}"/${PN}-4-CVE-2012-5513-XSA-29.patch \
		"${FILESDIR}"/${PN}-4-CVE-2012-5514-XSA-30.patch \
		"${FILESDIR}"/${PN}-4-CVE-2012-5515-XSA-31.patch \
		"${FILESDIR}"/${PN}-4-CVE-2012-5525-XSA-32.patch \
		"${FILESDIR}"/${PN}-4-CVE-2012-5634-XSA-33.patch \
		"${FILESDIR}"/${PN}-4-CVE-2013-0151-XSA-27_34_35.patch \
		"${FILESDIR}"/${PN}-4-CVE-2013-0154-XSA-37.patch
}

src_configure() {
	use debug && myopt="${myopt} debug=y"
	use pae && myopt="${myopt} pae=y"

	if use custom-cflags; then
		filter-flags -fPIE -fstack-protector
		replace-flags -O3 -O2
	else
		unset CFLAGS
	fi
}

src_compile() {
	# Send raw LDFLAGS so that --as-needed works
	emake CC="$(tc-getCC)" LDFLAGS="$(raw-ldflags)" LD="$(tc-getLD)" -C xen ${myopt}
}

src_install() {
	local myopt
	use debug && myopt="${myopt} debug=y"
	use pae && myopt="${myopt} pae=y"
	#The 'make install' doesn't 'mkdir -p' the subdirs
	use efi && mkdir -p "${D}"${EFI_MOUNTPOINT}/efi/${EFI_VENDOR} || die

	emake LDFLAGS="$(raw-ldflags)" DESTDIR="${D}" -C xen ${myopt} install
}

pkg_postinst() {
	elog "Official Xen Guide and the unoffical wiki page:"
	elog " http://www.gentoo.org/doc/en/xen-guide.xml"
	elog " http://en.gentoo-wiki.com/wiki/Xen/"

	use pae && ewarn "This is a PAE build of Xen. It will *only* boot PAE kernels!"
	use efi && einfo "The efi executable is installed in boot/efi/gentoo"
}



1.1                  app-emulation/xen/xen-4.2.1-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xen/xen-4.2.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xen/xen-4.2.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: xen-4.2.1-r2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/xen/xen-4.2.1-r2.ebuild,v 1.1 2013/02/24 08:23:59 idella4 Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )

if [[ $PV == *9999 ]]; then
	KEYWORDS=""
	REPO="xen-unstable.hg"
	EHG_REPO_URI="http://xenbits.xensource.com/${REPO}"
	S="${WORKDIR}/${REPO}"
	live_eclass="mercurial"
else
	KEYWORDS="~amd64 ~x86"
	SRC_URI="http://bits.xensource.com/oss-xen/release/${PV}/xen-${PV}.tar.gz"
fi

inherit mount-boot flag-o-matic python-single-r1 toolchain-funcs ${live_eclass}

DESCRIPTION="The Xen virtual machine monitor"
HOMEPAGE="http://xen.org/"

LICENSE="GPL-2"
SLOT="0"
IUSE="custom-cflags debug efi flask pae xsm"

RDEPEND="efi? ( >=sys-devel/binutils-2.22[multitarget] )"
PDEPEND="~app-emulation/xen-tools-${PV}"

RESTRICT="test"

# Approved by QA team in bug #144032
QA_WX_LOAD="boot/xen-syms-${PV}"

REQUIRED_USE="
	flask? ( xsm )
	"

pkg_setup() {
	python-single-r1_pkg_setup
	if [[ -z ${XEN_TARGET_ARCH} ]]; then
		if use x86 && use amd64; then
			die "Confusion! Both x86 and amd64 are set in your use flags!"
		elif use x86; then
			export XEN_TARGET_ARCH="x86_32"
		elif use amd64; then
			export XEN_TARGET_ARCH="x86_64"
		else
			die "Unsupported architecture!"
		fi
	fi

	if use flask ; then
		export "XSM_ENABLE=y"
		export "FLASK_ENABLE=y"
	elif use xsm ; then
		export "XSM_ENABLE=y"
	fi
}

src_prepare() {
	# Drop .config and fix gcc-4.6
	epatch  "${FILESDIR}"/${PN/-pvgrub/}-4-fix_dotconfig-gcc.patch

	if use efi; then
		epatch "${FILESDIR}"/${PN}-4.2-efi.patch
		export EFI_VENDOR="gentoo"
		export EFI_MOUNTPOINT="boot"
	fi

	# if the user *really* wants to use their own custom-cflags, let them
	if use custom-cflags; then
		einfo "User wants their own CFLAGS - removing defaults"
		# try and remove all the default custom-cflags
		find "${S}" -name Makefile -o -name Rules.mk -o -name Config.mk -exec sed \
			-e 's/CFLAGS\(.*\)=\(.*\)-O3\(.*\)/CFLAGS\1=\2\3/' \
			-e 's/CFLAGS\(.*\)=\(.*\)-march=i686\(.*\)/CFLAGS\1=\2\3/' \
			-e 's/CFLAGS\(.*\)=\(.*\)-fomit-frame-pointer\(.*\)/CFLAGS\1=\2\3/' \
			-e 's/CFLAGS\(.*\)=\(.*\)-g3*\s\(.*\)/CFLAGS\1=\2 \3/' \
			-e 's/CFLAGS\(.*\)=\(.*\)-O2\(.*\)/CFLAGS\1=\2\3/' \
			-i {} \; || die "failed to re-set custom-cflags"
	fi

	# not strictly necessary to fix this
	sed -i 's/, "-Werror"//' "${S}/tools/python/setup.py" || die "failed to re-set setup.py"

	#Security patches
	epatch "${FILESDIR}"/${PN}-4-CVE-2012-5634-XSA-33.patch \
                "${FILESDIR}"/${PN}-4-CVE-2013-0151-XSA-34_35.patch \
                "${FILESDIR}"/${PN}-4-CVE-2013-0154-XSA-37.patch
}

src_configure() {
	use debug && myopt="${myopt} debug=y"
	use pae && myopt="${myopt} pae=y"

	if use custom-cflags; then
		filter-flags -fPIE -fstack-protector
		replace-flags -O3 -O2
	else
		unset CFLAGS
	fi
}

src_compile() {
	# Send raw LDFLAGS so that --as-needed works
	emake CC="$(tc-getCC)" LDFLAGS="$(raw-ldflags)" LD="$(tc-getLD)" -C xen ${myopt}
}

src_install() {
	local myopt
	use debug && myopt="${myopt} debug=y"
	use pae && myopt="${myopt} pae=y"
	#The 'make install' doesn't 'mkdir -p' the subdirs
	use efi && mkdir -p "${D}"${EFI_MOUNTPOINT}/efi/${EFI_VENDOR} || die

	emake LDFLAGS="$(raw-ldflags)" DESTDIR="${D}" -C xen ${myopt} install
}

pkg_postinst() {
	elog "Official Xen Guide and the unoffical wiki page:"
	elog " http://www.gentoo.org/doc/en/xen-guide.xml"
	elog " http://en.gentoo-wiki.com/wiki/Xen/"

	use pae && ewarn "This is a PAE build of Xen. It will *only* boot PAE kernels!"
	use efi && einfo "The efi executable is installed in boot/efi/gentoo"
}