[gentoo-commits] gentoo-x86 commit in dev-python/logilab-common: logilab-common-0.60.1-r1.ebuild ChangeLog logilab-common-0.60.1.ebuild logilab-common-0.60.0.ebuild logilab-common-0.59.1.ebuild

[Ian Delaney (idella4)]

idella4     14/03/27 12:53:28

  Modified:             ChangeLog
  Added:                logilab-common-0.60.1-r1.ebuild
  Removed:              logilab-common-0.60.1.ebuild
                        logilab-common-0.60.0.ebuild
                        logilab-common-0.59.1.ebuild
  Log:
  revbump; sec fix wrt sec Bug #499872, rm old unstable versions
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.135                dev-python/logilab-common/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/logilab-common/ChangeLog?rev=1.135&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/logilab-common/ChangeLog?rev=1.135&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/logilab-common/ChangeLog?r1=1.134&r2=1.135

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/logilab-common/ChangeLog,v
retrieving revision 1.134
retrieving revision 1.135
diff -u -r1.134 -r1.135
--- ChangeLog	12 Feb 2014 04:49:32 -0000	1.134
+++ ChangeLog	27 Mar 2014 12:53:28 -0000	1.135
@@ -1,6 +1,15 @@
 # ChangeLog for dev-python/logilab-common
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/logilab-common/ChangeLog,v 1.134 2014/02/12 04:49:32 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/logilab-common/ChangeLog,v 1.135 2014/03/27 12:53:28 idella4 Exp $
+
+*logilab-common-0.60.1-r1 (27 Mar 2014)
+
+  27 Mar 2014; Ian Delaney <idella4@g.o>
+  +files/logilab-common-sec-CVE-2014-1838-9.patch,
+  +logilab-common-0.60.1-r1.ebuild, -logilab-common-0.59.1.ebuild,
+  -logilab-common-0.60.0.ebuild, -logilab-common-0.60.1.ebuild,
+  logilab-common-0.61.0.ebuild:
+  revbump; sec fix wrt sec Bug #499872, rm old unstable versions
 
 *logilab-common-0.61.0 (12 Feb 2014)
 



1.1                  dev-python/logilab-common/logilab-common-0.60.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/logilab-common/logilab-common-0.60.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/logilab-common/logilab-common-0.60.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: logilab-common-0.60.1-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/logilab-common/logilab-common-0.60.1-r1.ebuild,v 1.1 2014/03/27 12:53:28 idella4 Exp $

EAPI=5

# 0.60.0 fails unittest_umessage with python3.3
# http://www.logilab.org/ticket/149345
PYTHON_COMPAT=( python{2_6,2_7,3_2} pypy2_0 )

inherit distutils-r1 eutils

DESCRIPTION="Useful miscellaneous modules used by Logilab projects"
HOMEPAGE="http://www.logilab.org/project/logilab-common http://pypi.python.org/pypi/logilab-common"
SRC_URI="ftp://ftp.logilab.org/pub/common/${P}.tar.gz mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="test doc"

RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
	virtual/python-unittest2[${PYTHON_USEDEP}]"

# Tests using dev-python/psycopg are skipped when dev-python/psycopg
# isn't installed.
# egenix-mx-base tests are optional, and egenix-mx-base does support
# Python2 only.
DEPEND="${RDEPEND}
	test? (
		$(python_gen_cond_dep dev-python/egenix-mx-base[$(python_gen_usedep 'python2*')] 'python2*')
		!dev-python/psycopg[-mxdatetime]
	)
	doc? ( dev-python/epydoc )"

PATCHES=(
	# Make sure setuptools does not create a zip file in python_test;
	# this is buggy and causes tests to fail.
	"${FILESDIR}"/${PN}-0.59.1-zipsafe.patch
	# Depends on order of dictionary keys
	"${FILESDIR}"/logilab-common-0.60.0-skip-doctest.patch
	"${FILESDIR}"/${PN}-sec-CVE-2014-1838-9.patch
)

python_prepare_all() {
	# CVE-2014-1838
	rm -f pdf_ext.py || die
	sed -e 's:(CURDIR):{S}/${P}:' -i doc/makefile || die
	distutils-r1_python_prepare_all
}

python_compile_all() {
	if use doc; then
		# Simplest way to make makefile point to the right place.
		ln -s "${BUILD_DIR}" build || die
		emake -C doc epydoc
		rm build || die
	fi
}

python_test() {
	distutils_install_for_testing

	# Prevent timezone related failure.
	export TZ=UTC

	# Make sure that the tests use correct modules.
	pushd "${TEST_DIR}"/lib > /dev/null || die
	"${TEST_DIR}"/scripts/pytest || die "Tests fail with ${EPYTHON}"
	popd > /dev/null || die
}

python_install_all() {
	distutils-r1_python_install_all

	doman doc/pytest.1
	use doc && dohtml -r doc/apidoc/.
}