[gentoo-commits] repo/gentoo:master commit in: dev-python/pygal/

[Michał Górny]

commit:     0e09231c468f2e0252dcfe3ee7bd0607c15a9ced
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 26 08:22:03 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Feb 26 08:34:43 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0e09231c

dev-python/pygal: Migrate to PEP517 build

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pygal/pygal-3.0.0-r2.ebuild | 44 ++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

diff --git a/dev-python/pygal/pygal-3.0.0-r2.ebuild b/dev-python/pygal/pygal-3.0.0-r2.ebuild
new file mode 100644
index 000000000000..59615d98fba6
--- /dev/null
+++ b/dev-python/pygal/pygal-3.0.0-r2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="A python SVG charts generator"
+HOMEPAGE="https://github.com/Kozea/pygal/"
+SRC_URI="https://github.com/Kozea/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/pyquery[${PYTHON_USEDEP}]
+		media-gfx/cairosvg[${PYTHON_USEDEP}]
+	)
+"
+
+# CHANGELOG is a symlink to docs/changelog.rst
+DOCS=( docs/changelog.rst README.md )
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Not actually required unless we want to do setup.py test
+	# https://github.com/Kozea/pygal/issues/430
+	sed -i -e "/setup_requires/d" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+pkg_postinst() {
+	optfeature "improving rendering speed" "dev-python/lxml"
+	optfeature "png rendering" "dev-python/cairosvg"
+}