[gentoo-commits] gentoo-x86 commit in dev-python/cython: cython-0.19.2.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     13/11/22 07:50:32

  Modified:             ChangeLog
  Added:                cython-0.19.2.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.7/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.104                dev-python/cython/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cython/ChangeLog?rev=1.104&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cython/ChangeLog?rev=1.104&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cython/ChangeLog?r1=1.103&r2=1.104

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/cython/ChangeLog,v
retrieving revision 1.103
retrieving revision 1.104
diff -u -r1.103 -r1.104
--- ChangeLog	14 Nov 2013 05:54:56 -0000	1.103
+++ ChangeLog	22 Nov 2013 07:50:32 -0000	1.104
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/cython
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/cython/ChangeLog,v 1.103 2013/11/14 05:54:56 prometheanfire Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cython/ChangeLog,v 1.104 2013/11/22 07:50:32 patrick Exp $
+
+*cython-0.19.2 (22 Nov 2013)
+
+  22 Nov 2013; Patrick Lauer <patrick@g.o> +cython-0.19.2.ebuild:
+  Bump
 
 *cython-0.19.1-r1 (14 Nov 2013)
 



1.1                  dev-python/cython/cython-0.19.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cython/cython-0.19.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/cython/cython-0.19.2.ebuild?rev=1.1&content-type=text/plain

Index: cython-0.19.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/cython/cython-0.19.2.ebuild,v 1.1 2013/11/22 07:50:32 patrick Exp $

EAPI=5
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )

inherit distutils-r1 flag-o-matic

MY_PN="Cython"
MY_P="${MY_PN}-${PV/_/}"

DESCRIPTION="A Python to C compiler"
HOMEPAGE="http://www.cython.org/ http://pypi.python.org/pypi/Cython"
SRC_URI="http://www.cython.org/release/${MY_P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris ~x64-solaris"
IUSE="doc test"

# Note: update numpy dep when it is fixed for py3.3.
RDEPEND=""
DEPEND="${RDEPEND}
	doc? ( dev-python/sphinx )
	test? (
		>=dev-python/numpy-1.6.1-r1[$(python_gen_usedep 'python2*' 'python3_[12]' )]
	)"

S="${WORKDIR}/${MY_PN}-${PV%_*}"

python_compile() {
	if [[ ${EPYTHON} == python2* ]]; then
		local CFLAGS CXXFLAGS
		append-flags -fno-strict-aliasing
	fi

	# Python gets confused when it is in sys.path before build.
	local PYTHONPATH
	export PYTHONPATH

	distutils-r1_python_compile
}

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	"${PYTHON}" runtests.py -vv --work-dir "${BUILD_DIR}"/tests \
		|| die "Tests fail with ${EPYTHON}"
}

python_install_all() {
	local DOCS=( CHANGES.rst README.txt ToDo.txt USAGE.txt )
	use doc && local HTML_DOCS=( docs/build/html/. )

	distutils-r1_python_install_all
}