[gentoo-commits] gentoo-x86 commit in dev-qt/qt-creator: qt-creator-3.0.0_rc1.ebuild ChangeLog qt-creator-3.0.0_beta.ebuild

[Davide Pesavento (pesa)]

pesa        13/11/29 18:25:49

  Modified:             ChangeLog
  Added:                qt-creator-3.0.0_rc1.ebuild
  Removed:              qt-creator-3.0.0_beta.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 17A85C72)

Revision  Changes    Path
1.25                 dev-qt/qt-creator/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qt-creator/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qt-creator/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qt-creator/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	23 Oct 2013 13:08:04 -0000	1.24
+++ ChangeLog	29 Nov 2013 18:25:49 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for dev-qt/qt-creator
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/ChangeLog,v 1.24 2013/10/23 13:08:04 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/ChangeLog,v 1.25 2013/11/29 18:25:49 pesa Exp $
+
+*qt-creator-3.0.0_rc1 (29 Nov 2013)
+
+  29 Nov 2013; Davide Pesavento <pesa@g.o> +qt-creator-3.0.0_rc1.ebuild,
+  -qt-creator-3.0.0_beta.ebuild:
+  Version bump.
 
 *qt-creator-3.0.0_beta (23 Oct 2013)
 



1.1                  dev-qt/qt-creator/qt-creator-3.0.0_rc1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qt-creator/qt-creator-3.0.0_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qt-creator/qt-creator-3.0.0_rc1.ebuild?rev=1.1&content-type=text/plain

Index: qt-creator-3.0.0_rc1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-qt/qt-creator/qt-creator-3.0.0_rc1.ebuild,v 1.1 2013/11/29 18:25:49 pesa Exp $

EAPI=5

PLOCALES="cs de fr ja pl ru sl zh_CN zh_TW"

inherit eutils l10n multilib qt4-r2

DESCRIPTION="Lightweight IDE for C++/QML development centering around Qt"
HOMEPAGE="http://qt-project.org/wiki/Category:Tools::QtCreator"
LICENSE="LGPL-2.1"

if [[ ${PV} == *9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI=(
		"git://gitorious.org/${PN}/${PN}.git"
		"https://git.gitorious.org/${PN}/${PN}.git"
	)
else
	MY_PV=${PV/_/-}
	MY_P=${PN}-opensource-src-${MY_PV}
	[[ ${MY_PV} == ${PV} ]] && MY_REL=official || MY_REL=development
	SRC_URI="http://download.qt-project.org/${MY_REL}_releases/${PN/-}/${PV%.*}/${MY_PV}/${MY_P}.tar.gz"
	S=${WORKDIR}/${MY_P}
fi

SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86"

QTC_PLUGINS=(android autotools:autotoolsprojectmanager baremetal bazaar
	clearcase cmake:cmakeprojectmanager cvs fakevim git ios mercurial
	perforce python:pythoneditor qnx subversion valgrind)
IUSE="debug doc examples test ${QTC_PLUGINS[@]%:*}"

# minimum Qt version required
QT_PV="4.8.0:4"

CDEPEND="
	=dev-libs/botan-1.10*[threads]
	>=dev-qt/qtcore-${QT_PV}[ssl]
	>=dev-qt/qtdeclarative-${QT_PV}
	|| (
		( >=dev-qt/qtgui-4.8.5:4 dev-qt/designer:4 )
		( >=dev-qt/qtgui-${QT_PV} <dev-qt/qtgui-4.8.5:4 )
	)
	>=dev-qt/qthelp-${QT_PV}[doc?]
	>=dev-qt/qtscript-${QT_PV}
	>=dev-qt/qtsql-${QT_PV}
	>=dev-qt/qtsvg-${QT_PV}
"
DEPEND="${CDEPEND}
	virtual/pkgconfig
	test? ( >=dev-qt/qttest-${QT_PV} )
"
RDEPEND="${CDEPEND}
	>=sys-devel/gdb-7.2[client(+),python]
	examples? ( >=dev-qt/qtdemo-${QT_PV} )
"
PDEPEND="
	autotools? ( sys-devel/autoconf )
	bazaar? ( dev-vcs/bzr )
	cmake? ( dev-util/cmake )
	cvs? ( dev-vcs/cvs )
	git? ( dev-vcs/git )
	mercurial? ( dev-vcs/mercurial )
	subversion? ( dev-vcs/subversion )
	valgrind? ( dev-util/valgrind )
"

src_prepare() {
	qt4-r2_src_prepare

	# disable unwanted plugins
	for plugin in "${QTC_PLUGINS[@]#[+-]}"; do
		if ! use ${plugin%:*}; then
			einfo "Disabling ${plugin%:*} plugin"
			sed -i -re "/^\s+${plugin#*:}\>/d" src/plugins/plugins.pro \
				|| die "failed to disable ${plugin%:*} plugin"
		fi
	done

	# fix translations
	sed -i -e "/^LANGUAGES =/ s:=.*:= $(l10n_get_locales):" \
		share/qtcreator/translations/translations.pro || die

	# remove bundled qbs for now
	# TODO: package it and re-enable the plugin
	rm -rf src/shared/qbs || die
}

src_configure() {
	EQMAKE4_EXCLUDE="share/qtcreator/templates/*
			tests/*"
	eqmake4 IDE_LIBRARY_BASENAME="$(get_libdir)" \
		IDE_PACKAGE_MODE=1 \
		TEST=$(use test && echo 1 || echo 0) \
		USE_SYSTEM_BOTAN=1
}

src_test() {
	echo ">>> Test phase [QTest]: ${CATEGORY}/${PF}"
	cd tests/auto || die

	EQMAKE4_EXCLUDE="valgrind/*"
	eqmake4 IDE_LIBRARY_BASENAME="$(get_libdir)"

	emake check
}

src_install() {
	emake INSTALL_ROOT="${ED}usr" install

	dodoc dist/{changes-*,known-issues}

	# install documentation
	if use doc; then
		emake docs
		insinto /usr/share/doc/${PF}
		doins share/doc/qtcreator/qtcreator{,-dev}.qch
		docompress -x /usr/share/doc/${PF}/qtcreator{,-dev}.qch
	fi

	# install desktop file
	make_desktop_entry qtcreator 'Qt Creator' QtProject-qtcreator 'Qt;Development;IDE'
}