[gentoo-commits] gentoo-x86 commit in app-admin/tenshi: tenshi-0.14.ebuild ChangeLog

[Michael Weber (xmw)]

xmw         12/06/07 21:01:36

  Modified:             ChangeLog
  Added:                tenshi-0.14.ebuild
  Log:
  Version bump (bug 420003 by Brian De Wolf)
  
  (Portage version: 2.1.10.63/cvs/Linux x86_64)

Revision  Changes    Path
1.71                 app-admin/tenshi/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/tenshi/ChangeLog?rev=1.71&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/tenshi/ChangeLog?rev=1.71&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/tenshi/ChangeLog?r1=1.70&r2=1.71

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/tenshi/ChangeLog,v
retrieving revision 1.70
retrieving revision 1.71
diff -u -r1.70 -r1.71
--- ChangeLog	31 May 2012 02:59:03 -0000	1.70
+++ ChangeLog	7 Jun 2012 21:01:36 -0000	1.71
@@ -1,6 +1,11 @@
 # ChangeLog for app-admin/tenshi
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/tenshi/ChangeLog,v 1.70 2012/05/31 02:59:03 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/tenshi/ChangeLog,v 1.71 2012/06/07 21:01:36 xmw Exp $
+
+*tenshi-0.14 (07 Jun 2012)
+
+  07 Jun 2012; Michael Weber <xmw@g.o> +tenshi-0.14.ebuild:
+  Version bump (bug 420003 by Brian De Wolf)
 
   31 May 2012; Zac Medico <zmedico@g.o> tenshi-0.12.ebuild:
   inherit user for enewgroup and enewuser



1.1                  app-admin/tenshi/tenshi-0.14.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/tenshi/tenshi-0.14.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/tenshi/tenshi-0.14.ebuild?rev=1.1&content-type=text/plain

Index: tenshi-0.14.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/tenshi/tenshi-0.14.ebuild,v 1.1 2012/06/07 21:01:35 xmw Exp $

EAPI=4
inherit eutils user

DESCRIPTION="Log parsing and notification program"
HOMEPAGE="http://dev.inversepath.com/trac/tenshi"
SRC_URI="http://dev.inversepath.com/tenshi/${P}.tar.gz"

LICENSE="ISC"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

RDEPEND="dev-lang/perl
	dev-perl/IO-BufferedSelect
	sys-apps/coreutils"

pkg_setup() {
	enewgroup tenshi
	enewuser tenshi -1 -1 /var/lib/tenshi tenshi
}

src_prepare() {
	# Fix for bug #241254
	sed -i 's:^docdir =.*:docdir = /usr/share/doc/${PF}:' \
		Makefile || die "docdir substitution failed"
}

src_install() {
	emake DESTDIR="${D}" install
	fowners tenshi:root /etc/tenshi/tenshi.conf
	dodir /var/lib/tenshi
	fowners tenshi:root /var/lib/tenshi
	doman tenshi.8
	newinitd tenshi.gentoo-init tenshi
	keepdir /var/lib/tenshi
}

pkg_postinst() {
	ewarn "The sample config installed to ${ROOT}etc/tenshi/tenshi.conf"
	ewarn "monitors /var/log/messages which, by default, can not be read"
	ewarn "by the tenshi user.  Make sure that the tenshi user has read"
	ewarn "permission on all the files that you want tenshi to monitor."
}