Gentoo Archives: gentoo-commits

From: "Julian Ospald (hasufell)" <hasufell@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in games-strategy/hedgewars: ChangeLog hedgewars-0.9.19.ebuild
Date: Fri, 31 May 2013 18:50:41
Message-Id: 20130531185033.459112171D@flycatcher.gentoo.org
hasufell    13/05/31 18:50:33

  Modified:             ChangeLog
  Added:                hedgewars-0.9.19.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.51                 games-strategy/hedgewars/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/hedgewars/ChangeLog?rev=1.51&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/hedgewars/ChangeLog?rev=1.51&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/hedgewars/ChangeLog?r1=1.50&r2=1.51

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/hedgewars/ChangeLog,v
retrieving revision 1.50
retrieving revision 1.51
diff -u -r1.50 -r1.51
--- ChangeLog	2 Mar 2013 21:22:01 -0000	1.50
+++ ChangeLog	31 May 2013 18:50:32 -0000	1.51
@@ -1,6 +1,11 @@
 # ChangeLog for games-strategy/hedgewars
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/hedgewars/ChangeLog,v 1.50 2013/03/02 21:22:01 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/hedgewars/ChangeLog,v 1.51 2013/05/31 18:50:32 hasufell Exp $
+
+*hedgewars-0.9.19 (31 May 2013)
+
+  31 May 2013; Julian Ospald <hasufell@g.o> +hedgewars-0.9.19.ebuild:
+  version bump
 
   02 Mar 2013; Markos Chandras <hwoarang@g.o> hedgewars-0.9.18-r1.ebuild:
   Move Qt dependencies to the new category



1.1                  games-strategy/hedgewars/hedgewars-0.9.19.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/hedgewars/hedgewars-0.9.19.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/hedgewars/hedgewars-0.9.19.ebuild?rev=1.1&content-type=text/plain

Index: hedgewars-0.9.19.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/hedgewars/hedgewars-0.9.19.ebuild,v 1.1 2013/05/31 18:50:33 hasufell Exp $

# TODO: when physfs-2.1.0 hits the tree, set
# -DSYSTEM_PHYSFS=ON

EAPI=5
CMAKE_BUILD_TYPE=Release
inherit cmake-utils eutils games

MY_P=${PN}-src-${PV}
DESCRIPTION="Free Worms-like turn based strategy game"
HOMEPAGE="http://hedgewars.org/"
SRC_URI="http://download.gna.org/hedgewars/${MY_P}.tar.bz2"

LICENSE="GPL-2 Apache-2.0 FDL-1.3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""
QA_FLAGS_IGNORED=${GAMES_BINDIR}/hwengine # pascal sucks
QA_PRESTRIPPED=${GAMES_BINDIR}/hwengine # pascal sucks

RDEPEND="dev-qt/qtgui:4
	media-libs/freeglut
	virtual/ffmpeg
	media-libs/libsdl[audio,opengl,video]
	media-libs/sdl-ttf
	media-libs/sdl-mixer[vorbis]
	media-libs/sdl-image[png]
	media-libs/sdl-net
	dev-lang/lua"
DEPEND="${RDEPEND}
	>=dev-lang/fpc-2.4"
RDEPEND="${RDEPEND}
	>=media-fonts/dejavu-2.28"

S=${WORKDIR}/${PN}-src-${PV}

src_configure() {
	local mycmakeargs=(
		-DMINIMAL_FLAGS=ON
		-DCMAKE_INSTALL_PREFIX="${GAMES_PREFIX}"
		-DDATA_INSTALL_DIR="${GAMES_DATADIR}"
		-DNOSERVER=TRUE
		-DCMAKE_VERBOSE_MAKEFILE=TRUE
		-DSYSTEM_PHYSFS=OFF
	)
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
}

src_install() {
	DOCS="ChangeLog.txt README" cmake-utils_src_install
	rm -f "${D}"/usr/share/games/hedgewars/Data/Fonts/DejaVuSans-Bold.ttf
	dosym /usr/share/fonts/dejavu/DejaVuSans-Bold.ttf \
		"${GAMES_DATADIR}"/hedgewars/Data/Fonts/DejaVuSans-Bold.ttf
	newicon QTfrontend/res/hh25x25.png ${PN}.png
	make_desktop_entry ${PN} Hedgewars
	doman man/${PN}.6
	prepgamesdirs
}