[gentoo-commits] gentoo-x86 commit in sci-misc/mendeleydesktop: mendeleydesktop-1.11.ebuild ChangeLog mendeleydesktop-1.10.1.ebuild

[Vikraman Choudhury (vikraman)]

vikraman    14/04/29 11:46:28

  Modified:             ChangeLog
  Added:                mendeleydesktop-1.11.ebuild
  Removed:              mendeleydesktop-1.10.1.ebuild
  Log:
  Bump to version 1.11, bug #504578.
  
  (Portage version: 2.2.10_p22/cvs/Linux i686, signed Manifest commit with key B0A72FD2)

Revision  Changes    Path
1.16                 sci-misc/mendeleydesktop/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/mendeleydesktop/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/mendeleydesktop/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/mendeleydesktop/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-misc/mendeleydesktop/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	9 Oct 2013 18:36:43 -0000	1.15
+++ ChangeLog	29 Apr 2014 11:46:28 -0000	1.16
@@ -1,6 +1,12 @@
 # ChangeLog for sci-misc/mendeleydesktop
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-misc/mendeleydesktop/ChangeLog,v 1.15 2013/10/09 18:36:43 miknix Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-misc/mendeleydesktop/ChangeLog,v 1.16 2014/04/29 11:46:28 vikraman Exp $
+
+*mendeleydesktop-1.11 (29 Apr 2014)
+
+  29 Apr 2014; Vikraman Choudhury (vikraman) <vikraman@g.o>
+  +mendeleydesktop-1.11.ebuild, -mendeleydesktop-1.10.1.ebuild:
+  Bump to version 1.11, bug #504578.
 
 *mendeleydesktop-1.10.1 (09 Oct 2013)
 



1.1                  sci-misc/mendeleydesktop/mendeleydesktop-1.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/mendeleydesktop/mendeleydesktop-1.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-misc/mendeleydesktop/mendeleydesktop-1.11.ebuild?rev=1.1&content-type=text/plain

Index: mendeleydesktop-1.11.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-misc/mendeleydesktop/mendeleydesktop-1.11.ebuild,v 1.1 2014/04/29 11:46:28 vikraman Exp $

EAPI="4"

inherit eutils multilib

MY_P_AMD64="${P}-linux-x86_64"
MY_P_X86="${P}-linux-i486"

DESCRIPTION="A free research management tool for desktop and web"
HOMEPAGE="http://www.mendeley.com/"
SRC_URI="amd64? ( ${MY_P_AMD64}.tar.bz2 )
	x86? ( ${MY_P_X86}.tar.bz2 )
	amd64-linux? ( ${MY_P_AMD64}.tar.bz2 )
	x86-linux? ( ${MY_P_X86}.tar.bz2 )"

LICENSE="Mendeley-EULA"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RESTRICT="fetch"

DEPEND=""
RDEPEND=">=dev-qt/qtcore-4.6:4
	>=dev-qt/qtgui-4.6:4
	>=dev-qt/qtsvg-4.6:4
	>=dev-qt/qtwebkit-4.6:4
	>=dev-qt/qtxmlpatterns-4.6:4"

QA_PRESTRIPPED="
	/opt/mendeleydesktop/$(get_libdir)/mendeleydesktop/libexec/.*
	/opt/mendeleydesktop/$(get_libdir)/lib.*so.*"

pkg_nofetch() {
	elog "Please download ${A} from:"
	elog "http://www.mendeley.com/download-mendeley-desktop/"
	elog "and move it to ${DISTDIR}"
}

src_unpack() {
	unpack ${A}

	cd "${WORKDIR}"

	if use amd64 || use amd64-linux ; then
		mv -f "${MY_P_AMD64}" "${P}"
	else
		mv -f "${MY_P_X86}" "${P}"
	fi
}

src_prepare() {
	# remove bundled Qt libraries
	rm -rf lib/mendeleydesktop/plugins \
		|| die "failed to remove plugin directory"
	rm -rf lib/qt || die "failed to remove qt libraries"

	# force use of system Qt libraries
	sed -i "s:sys\.argv\.count(\"--force-system-qt\") > 0:True:" \
		bin/mendeleydesktop || die "failed to patch startup script"

	# fix library paths
	sed -i \
		-e "s:lib/mendeleydesktop:$(get_libdir)/mendeleydesktop:g" \
		-e "s:MENDELEY_BASE_PATH + \"/lib/\":MENDELEY_BASE_PATH + \"/$(get_libdir)/\":g" \
		bin/mendeleydesktop || die "failed to patch library path"
}

src_install() {
	# install menu
	domenu share/applications/${PN}.desktop

	# install application icons
	insinto /usr/share/icons
	doins -r share/icons/hicolor

	# install default icon
	insinto /usr/share/pixmaps
	doins share/icons/hicolor/48x48/apps/${PN}.png

	# install documentation, but no license file
	dodoc share/doc/${PN}/Readme.txt

	# install binary
	into /opt/${PN}
	dobin bin/*

	# install libraries
	dolib.so lib/lib*.so*

	# install programs
	exeinto /opt/mendeleydesktop/$(get_libdir)/mendeleydesktop/libexec
	doexe lib/mendeleydesktop/libexec/*

	# install shared files
	insinto /opt/${PN}/share
	doins -r share/mendeleydesktop

	# install launch script
	exeinto /opt/bin
	doexe "${FILESDIR}"/${PN}
}