[gentoo-commits] gentoo-x86 commit in app-pda/libsyncml: ChangeLog libsyncml-9999.ebuild

[Piotr Jaroszynski (peper)]

peper       07/11/26 20:10:01

  Modified:             ChangeLog
  Added:                libsyncml-9999.ebuild
  Log:
  Add live svn ebuild.
  (Portage version: 2.1.4_rc3)

Revision  Changes    Path
1.6                  app-pda/libsyncml/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-pda/libsyncml/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-pda/libsyncml/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-pda/libsyncml/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-pda/libsyncml/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	28 Mar 2007 20:13:43 -0000	1.5
+++ ChangeLog	26 Nov 2007 20:10:00 -0000	1.6
@@ -1,6 +1,11 @@
 # ChangeLog for app-pda/libsyncml
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-pda/libsyncml/ChangeLog,v 1.5 2007/03/28 20:13:43 peper Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-pda/libsyncml/ChangeLog,v 1.6 2007/11/26 20:10:00 peper Exp $
+
+*libsyncml-9999 (26 Nov 2007)
+
+  26 Nov 2007; Piotr Jaroszyński <peper@g.o> +libsyncml-9999.ebuild:
+  Add live svn ebuild.
 
 *libsyncml-0.4.4 (28 Mar 2007)
 



1.1                  app-pda/libsyncml/libsyncml-9999.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-pda/libsyncml/libsyncml-9999.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-pda/libsyncml/libsyncml-9999.ebuild?rev=1.1&content-type=text/plain

Index: libsyncml-9999.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-pda/libsyncml/libsyncml-9999.ebuild,v 1.1 2007/11/26 20:10:00 peper Exp $

inherit eutils subversion autotools

DESCRIPTION="Implementation of the SyncML protocol"
HOMEPAGE="http://libsyncml.opensync.org/"
SRC_URI=""

ESVN_REPO_URI="http://svn.opensync.org/libsyncml/trunk"

KEYWORDS="~amd64 ~x86"
SLOT="0"
LICENSE="LGPL-2.1"
IUSE="bluetooth debug doc http obex"

RDEPEND=">=dev-libs/glib-2.0
	>=dev-libs/libwbxml-0.9.2
	dev-libs/libxml2
	http? ( >=net-libs/libsoup-2.2.91 )
	obex? ( >=dev-libs/openobex-1.1 )
	bluetooth? ( net-wireless/bluez-libs )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )"

# Some of the tests are broken
RESTRICT="test"

pkg_setup() {
	if ! use obex && ! use http; then
		eerror "${CATEGORY}/${P} without support for obex nor http is unusable."
		eerror "Please enable \"obex\" or/and \"http\" USE flags."
		die "Please enable \"obex\" or/and \"http\" USE flags."
	fi

	if use bluetooth; then
		if use obex && ! built_with_use dev-libs/openobex bluetooth; then
			eerror "You are trying to build ${CATEGORY}/${P} with the \"bluetooth\""
			eerror "and \"obex\" USE flags, but dev-libs/openobex was built without"
			eerror "the \"bluetooth\" USE flag."
			eerror "Please rebuild dev-libs/openobex with \"bluetooth\" USE flag."
			die "Please rebuild dev-libs/openobex with \"bluetooth\" USE flag."
		elif ! use obex; then
			eerror "You are trying to build ${CATEGORY}/${P} with the \"bluetooth\""
			eerror "USE flag, but you didn't enable the \"obex\" flag, which is"
			eerror "needed for bluetooth support."
			eerror "Please enable \"obex\" USE flag."
			die "Please enable \"obex\" USE flag."
		fi
	fi
}

src_compile() {
	eautoreconf

	econf \
		$(use_enable bluetooth) \
		$(use_enable obex) \
		$(use_enable http) \
		$(use_enable debug) \
		$(use_enable debug tracing) \
		--disable-unit-tests \
		|| die "econf failed"
		#$(use_enable test unit-tests) \

	emake || die "emake failed"

	use doc && doxygen Doxyfile
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog README

	use doc && dohtml docs/html/*
}



-- 
gentoo-commits@g.o mailing list