[gentoo-commits] repo/gentoo:master commit in: media-gfx/feh/

[Tim Harder]

commit:     930eebecfe2cbb1e0f989f439207d2d61fe52aaa
Author:     Tim Harder <radhermit <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 27 19:06:23 2019 +0000
Commit:     Tim Harder <radhermit <AT> gentoo <DOT> org>
CommitDate: Fri Dec 27 19:10:33 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=930eebec

media-gfx/feh: version bump to 3.3

Signed-off-by: Tim Harder <radhermit <AT> gentoo.org>

 media-gfx/feh/Manifest       |  1 +
 media-gfx/feh/feh-3.3.ebuild | 74 ++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/media-gfx/feh/Manifest b/media-gfx/feh/Manifest
index 8ff5bfc8122..0c77094a8f9 100644
--- a/media-gfx/feh/Manifest
+++ b/media-gfx/feh/Manifest
@@ -1 +1,2 @@
 DIST feh-3.2.1.tar.bz2 2112281 BLAKE2B 2918d2714f0557e1b67284709bce22c5e14d8f7f545ca33c16ec7928273edf18c9be48a685c3e9a032170bf2b7e572a4b78664f37b2a16c5ae5829b3cc55ca76 SHA512 11a136990f7d02409501f10553659c64ad5d18d4bfaa4e5cfdeb7a2f53ffdb8bd9b8347796c65e75c49615ac4c12bc81bf3a58325f778cb5e0c1608181d7b53a
+DIST feh-3.3.tar.bz2 2112880 BLAKE2B 56042367c0acce966e115e77f3afa1acd3f942a956bc453de364bcd17d90393ad2868039a5793af64826cd50322e4ef5f9f2b9678f982c7c85b025ed208f8bb8 SHA512 0372115a8f2df77cdfc0fc1b24479e72d9be1f24127c787909ef671075b199b8d5f873200ce202f51705991cf3c5f5cc71ef8f47294fe520e3a9acc5cb7582a9

diff --git a/media-gfx/feh/feh-3.3.ebuild b/media-gfx/feh/feh-3.3.ebuild
new file mode 100644
index 00000000000..ad37f294e68
--- /dev/null
+++ b/media-gfx/feh/feh-3.3.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit toolchain-funcs gnome2-utils xdg-utils
+
+DESCRIPTION="A fast, lightweight imageviewer using imlib2"
+HOMEPAGE="https://feh.finalrewind.org/"
+SRC_URI="https://feh.finalrewind.org/${P}.tar.bz2"
+
+LICENSE="feh"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~x86"
+IUSE="debug curl exif test xinerama"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="media-libs/imlib2[X]
+	>=media-libs/libpng-1.2:0=
+	x11-libs/libX11
+	curl? ( net-misc/curl )
+	exif? ( media-libs/libexif )
+	xinerama? ( x11-libs/libXinerama )"
+RDEPEND="${COMMON_DEPEND}
+	virtual/jpeg:0"
+DEPEND="${COMMON_DEPEND}
+	x11-base/xorg-proto
+	x11-libs/libXt
+	test? (
+		>=dev-lang/perl-5.10
+		dev-perl/Test-Command
+		media-libs/imlib2[gif,jpeg,png]
+	)"
+
+PATCHES=( "${FILESDIR}"/${PN}-3.2-debug-cflags.patch )
+
+pkg_setup() {
+	use_feh() { usex $1 1 0; }
+
+	fehopts=(
+		DESTDIR="${D}"
+		PREFIX="${EPREFIX}"/usr
+		doc_dir='${main_dir}'/share/doc/${PF}
+		example_dir='${main_dir}'/share/doc/${PF}/examples
+		curl=$(use_feh curl)
+		debug=$(use_feh debug)
+		xinerama=$(use_feh xinerama)
+		exif=$(use_feh exif)
+	)
+}
+
+src_compile() {
+	tc-export CC
+	emake "${fehopts[@]}"
+}
+
+src_install() {
+	emake "${fehopts[@]}" install
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}