[gentoo-commits] repo/gentoo:master commit in: www-client/opera-developer/

[Sam James]

commit:     54ffaf7971d18f27a8929d0a43030833da8d0bb5
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Aug 15 23:39:32 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Aug 15 23:39:32 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=54ffaf79

www-client/opera-developer: automated bump (91.0.4505.0)

Signed-off-by: Sam James <sam <AT> gentoo.org>

 www-client/opera-developer/Manifest                |   1 +
 .../opera-developer-91.0.4505.0.ebuild             | 158 +++++++++++++++++++++
 2 files changed, 159 insertions(+)

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index 5b67f9edd2f1..d3bd74948897 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,4 +1,5 @@
 DIST opera-developer_91.0.4484.0_amd64.deb 87605720 BLAKE2B 4b7b8f17a0bba21667f1bfe64c05bcf15c0fe20b1bdf928ad806f71f9ce6c8a7d3a8b2318b8b8cc2801a76c7d83172ce20c46514ba26ddd5a401915122dd4e79 SHA512 4056ea6b064867b558e132e70e8ee7c151424a7e8129e2996d8abed12806ee97a56bde613db8c8eff80331e7565bc4b0db10d7e758d24180eda9075d59260fcc
 DIST opera-developer_91.0.4491.0_amd64.deb 87721736 BLAKE2B 602d9525b1e69bb6ece6a1f9336964bdd62d0785bca4f2180628e53dd3356056d1066ddfb7b308b1bdae05512d99319da5f9b68c4735c0aff5e285e1c7d9d7ec SHA512 6853ae5d703ff9e0af5d9b0d15d45da1288b584d63aed94b761fd4926de169bcece2dda73dd0311aaaa823b2ae0892e2c852c24efa2fe1734d5faca5c31ad9a4
 DIST opera-developer_91.0.4498.0_amd64.deb 87205640 BLAKE2B 97d3516f597468930d8d523a0a90fa008d518fe6285cf786fe339c16e267d3a4cac1045fa1e50044ff099c37f14b2475e6fdc8ad2f8c7a4ea158092df61aefcf SHA512 d0841e500e05d5575719be4e4f5027f1bd9709734ca49f25cffaf6ba3cbe5508f333ca2594a621d5f338f389e1442c62aef3433f3e7fb5398c1801ebd1ba6c65
+DIST opera-developer_91.0.4505.0_amd64.deb 87300708 BLAKE2B 00ca118ef1e8ab405d0f03b8769055c2df14bba533fce2bced1c595ac57f905501e59a991175ece01ff136c668efc83b65d26c3b94293ce24bec3516573ca743 SHA512 2275bd6539588e30b50228e0184c8b948fc36bbb69b91fb5f61b47e1b9171720509668af3f7e28bfc5ba40fa54bf0744d6925ffd3a6c50f6b29fd8abdd19a8a2
 DIST opera-ffmpeg-codecs-104.0.5083.0.tar.xz 1431840 BLAKE2B 172ba55d6f390eaea644803ddae8c3cee4ee2d585de873db438d43b9e7f6d07f5b0e9b659f06c126f65148148d889948cc3287ee21da00eec08f2e665be47dbc SHA512 9ca7fe8a244b634d65a28602f9e1173694faaab6de95cd0a44aeedc29dffb75b14adf842c69d5ba5631fb40e51f021fce190dc8307148d8e9218230b7cde29b8

diff --git a/www-client/opera-developer/opera-developer-91.0.4505.0.ebuild b/www-client/opera-developer/opera-developer-91.0.4505.0.ebuild
new file mode 100644
index 000000000000..bf2f16f337f7
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-91.0.4505.0.ebuild
@@ -0,0 +1,158 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="104.0.5083.0"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}