[gentoo-commits] repo/gentoo:master commit in: media-video/yle-dl/

[Joonas Niilola]

commit:     b87677cc1725a9fa1bda9d4dbfa7c20a88b4b0fe
Author:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
AuthorDate: Wed Jan  1 16:13:49 2020 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Wed Jan  1 16:14:59 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b87677cc

media-video/yle-dl: bump to 20191231

Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 media-video/yle-dl/Manifest               |  1 +
 media-video/yle-dl/yle-dl-20191231.ebuild | 67 +++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/media-video/yle-dl/Manifest b/media-video/yle-dl/Manifest
index 142434db78c..6a59018abbb 100644
--- a/media-video/yle-dl/Manifest
+++ b/media-video/yle-dl/Manifest
@@ -1 +1,2 @@
 DIST yle-dl-20191022.tar.gz 84694 BLAKE2B bfeab9c5220931b8af5eae94b0f5377d21f6b6fb7b21c5f7bc5360a69e7185b8f1e052a584460187cfdd04d68295a20cb895e749af43c1de4ffd7fcd7bfc3875 SHA512 2d7c6d7f8e60cb8fd54fc04dcf73caf5022e3c65ab78f002c280950184fb2458f88f6934b62c0afaeaf30864b5cc47b1ef9c2a58d2855c5111a563cd195095be
+DIST yle-dl-20191231.tar.gz 86479 BLAKE2B 5b39a3e68478fe71ec604f3217a4115ad1ff09fc8913c81acc7108e433349a0c524eebadeb892e01d3ed43ab163421ea59bc4ec486af710f0680107d15d13f35 SHA512 60d7aeab72e3a6c9346a9e569c9de6af154a65b326c7528ceebe3ee33dc1df62764d6f768da160524bf74ab6ad7c238658a58184726cec6b6b46e70b5701437c

diff --git a/media-video/yle-dl/yle-dl-20191231.ebuild b/media-video/yle-dl/yle-dl-20191231.ebuild
new file mode 100644
index 00000000000..eb48b56557d
--- /dev/null
+++ b/media-video/yle-dl/yle-dl-20191231.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5..7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Download media files from Yle Areena"
+HOMEPAGE="http://aajanki.github.io/yle-dl/"
+SRC_URI="https://github.com/aajanki/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="libav php test +youtube-dl"
+
+# Requires an active internet connection during tests
+RESTRICT="test"
+
+RDEPEND="
+	!libav? ( media-video/ffmpeg )
+	>=dev-python/attrs-18.1.0[${PYTHON_USEDEP}]
+	>=dev-python/configargparse-0.13.0[${PYTHON_USEDEP}]
+	dev-python/future[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/mini-amf[${PYTHON_USEDEP}]
+	dev-python/progress[${PYTHON_USEDEP}]
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	net-misc/wget
+	php? (
+		dev-lang/php:*[bcmath,cli,curl,simplexml]
+		>=dev-libs/openssl-1.0.2:0=
+		media-video/rtmpdump
+	)
+	youtube-dl? ( net-misc/youtube-dl[${PYTHON_USEDEP}] )
+"
+DEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( COPYING ChangeLog README.fi README.md yledl.conf.sample )
+
+src_prepare() {
+	default
+
+	# Gentoo doesn't ship pycryptodomex with pycryptodome
+	sed -i 's/pycryptodomex/pycryptodome/g' setup.py || die
+}
+
+python_test() {
+	# For tests to run succesfully, you need to disable network stricting
+	# feature first.
+	#  FEATURES="-network-sandbox test" emerge -a yle-dl
+	esetup.py test
+}
+
+pkg_postinst() {
+	einfo "Sample configuration file has been installed in "
+	einfo " /usr/share/doc/yle-dl-${PV}/yledl.conf.sample.bz2"
+}