[gentoo-commits] gentoo-x86 commit in sys-apps/hwids: metadata.xml hwids-20140602-r1.ebuild hwids-99999999.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      14/06/06 18:20:05

  Modified:             metadata.xml hwids-99999999.ebuild ChangeLog
  Added:                hwids-20140602-r1.ebuild
  Log:
  Add USE flags to control the install of the net/pci/usb databases. Unify the live & release ebuilds.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.2                  sys-apps/hwids/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/hwids/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	1 Apr 2012 01:46:52 -0000	1.1
+++ metadata.xml	6 Jun 2014 18:20:05 -0000	1.2
@@ -8,4 +8,10 @@
 <maintainer>
   <email>gregkh@g.o</email>
 </maintainer>
+<use>
+ <flag name='net'>Install the oui.txt and iab.txt databases</flag>
+ <flag name='pci'>Install the pci.ids database</flag>
+ <flag name='usb'>Install the usb.ids database</flag>
+ <flag name='udev'>Install hwdb.d rules for udev</flag>
+</use>
 </pkgmetadata>



1.25                 sys-apps/hwids/hwids-99999999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/hwids-99999999.ebuild?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/hwids-99999999.ebuild?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/hwids-99999999.ebuild?r1=1.24&r2=1.25

Index: hwids-99999999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/hwids/hwids-99999999.ebuild,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- hwids-99999999.ebuild	30 May 2014 14:41:46 -0000	1.24
+++ hwids-99999999.ebuild	6 Jun 2014 18:20:05 -0000	1.25
@@ -1,39 +1,55 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/hwids/hwids-99999999.ebuild,v 1.24 2014/05/30 14:41:46 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/hwids/hwids-99999999.ebuild,v 1.25 2014/06/06 18:20:05 vapier Exp $
 
 EAPI=5
-inherit udev eutils git-2
+inherit udev eutils
 
 DESCRIPTION="Hardware (PCI, USB, OUI, IAB) IDs databases"
 HOMEPAGE="https://github.com/gentoo/hwids"
-EGIT_REPO_URI="${HOMEPAGE}.git"
+if [[ ${PV} == "99999999" ]]; then
+	EGIT_REPO_URI="${HOMEPAGE}.git"
+	inherit git-2
+else
+	SRC_URI="${HOMEPAGE}/archive/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~amd64-linux ~arm-linux ~x86-linux"
+fi
 
 LICENSE="|| ( GPL-2 BSD ) public-domain"
 SLOT="0"
-KEYWORDS=""
-IUSE="+udev"
+IUSE="+net +pci +udev +usb"
 
 DEPEND="udev? (
-	net-misc/curl
 	dev-lang/perl
 	>=virtual/udev-206
 )"
+[[ ${PV} == "99999999" ]] && DEPEND+=" udev? ( net-misc/curl )"
 RDEPEND="!<sys-apps/pciutils-3.1.9-r2
 	!<sys-apps/usbutils-005-r1"
 
+S=${WORKDIR}/hwids-${P}
+
 src_prepare() {
-	emake fetch
+	[[ ${PV} == "99999999" ]] && emake fetch
 
 	sed -i -e '/udevadm hwdb/d' Makefile || die
 }
 
+_emake() {
+	emake \
+		NET=$(usex net) \
+		PCI=$(usex pci) \
+		UDEV=$(usex udev) \
+		USB=$(usex usb) \
+		"$@"
+}
+
 src_compile() {
-	emake UDEV=$(usex udev)
+	_emake
 }
 
 src_install() {
-	emake UDEV=$(usex udev) install \
+	_emake install \
 		DOCDIR="${EPREFIX}/usr/share/doc/${PF}" \
 		MISCDIR="${EPREFIX}/usr/share/misc" \
 		HWDBDIR="${EPREFIX}$(get_udevdir)/hwdb.d" \



1.144                sys-apps/hwids/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/ChangeLog?rev=1.144&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/ChangeLog?rev=1.144&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/ChangeLog?r1=1.143&r2=1.144

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/hwids/ChangeLog,v
retrieving revision 1.143
retrieving revision 1.144
diff -u -r1.143 -r1.144
--- ChangeLog	2 Jun 2014 11:58:34 -0000	1.143
+++ ChangeLog	6 Jun 2014 18:20:05 -0000	1.144
@@ -1,6 +1,13 @@
 # ChangeLog for sys-apps/hwids
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/hwids/ChangeLog,v 1.143 2014/06/02 11:58:34 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/hwids/ChangeLog,v 1.144 2014/06/06 18:20:05 vapier Exp $
+
+*hwids-20140602-r1 (06 Jun 2014)
+
+  06 Jun 2014; Mike Frysinger <vapier@g.o> +hwids-20140602-r1.ebuild,
+  hwids-99999999.ebuild, metadata.xml:
+  Add USE flags to control the install of the net/pci/usb databases. Unify the
+  live & release ebuilds.
 
 *hwids-20140602 (02 Jun 2014)
 



1.1                  sys-apps/hwids/hwids-20140602-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/hwids-20140602-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/hwids/hwids-20140602-r1.ebuild?rev=1.1&content-type=text/plain

Index: hwids-20140602-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/hwids/hwids-20140602-r1.ebuild,v 1.1 2014/06/06 18:20:05 vapier Exp $

EAPI=5
inherit udev eutils

DESCRIPTION="Hardware (PCI, USB, OUI, IAB) IDs databases"
HOMEPAGE="https://github.com/gentoo/hwids"
if [[ ${PV} == "99999999" ]]; then
	EGIT_REPO_URI="${HOMEPAGE}.git"
	inherit git-2
else
	SRC_URI="${HOMEPAGE}/archive/${P}.tar.gz"
	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~amd64-linux ~arm-linux ~x86-linux"
fi

LICENSE="|| ( GPL-2 BSD ) public-domain"
SLOT="0"
IUSE="+net +pci +udev +usb"

DEPEND="udev? (
	dev-lang/perl
	>=virtual/udev-206
)"
[[ ${PV} == "99999999" ]] && DEPEND+=" udev? ( net-misc/curl )"
RDEPEND="!<sys-apps/pciutils-3.1.9-r2
	!<sys-apps/usbutils-005-r1"

S=${WORKDIR}/hwids-${P}

src_prepare() {
	[[ ${PV} == "99999999" ]] && emake fetch

	sed -i -e '/udevadm hwdb/d' Makefile || die
}

_emake() {
	emake \
		NET=$(usex net) \
		PCI=$(usex pci) \
		UDEV=$(usex udev) \
		USB=$(usex usb) \
		"$@"
}

src_compile() {
	_emake
}

src_install() {
	_emake install \
		DOCDIR="${EPREFIX}/usr/share/doc/${PF}" \
		MISCDIR="${EPREFIX}/usr/share/misc" \
		HWDBDIR="${EPREFIX}$(get_udevdir)/hwdb.d" \
		DESTDIR="${D}"
}

pkg_postinst() {
	if use udev; then
		udevadm hwdb --update --root="${ROOT%/}"
		# http://cgit.freedesktop.org/systemd/systemd/commit/?id=1fab57c209035f7e66198343074e9cee06718bda
		[ "${ROOT:-/}" = "/" ] && udevadm control --reload
	fi
}