[gentoo-commits] gentoo-x86 commit in app-emacs/org-mode: ChangeLog org-mode-8.2.1.ebuild

[Ulrich Mueller (ulm)]

ulm         13/11/02 10:26:02

  Modified:             ChangeLog
  Added:                org-mode-8.2.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)

Revision  Changes    Path
1.160                app-emacs/org-mode/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/ChangeLog?rev=1.160&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/ChangeLog?rev=1.160&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/ChangeLog?r1=1.159&r2=1.160

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emacs/org-mode/ChangeLog,v
retrieving revision 1.159
retrieving revision 1.160
diff -u -r1.159 -r1.160
--- ChangeLog	23 Sep 2013 17:53:53 -0000	1.159
+++ ChangeLog	2 Nov 2013 10:26:02 -0000	1.160
@@ -1,6 +1,11 @@
 # ChangeLog for app-emacs/org-mode
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emacs/org-mode/ChangeLog,v 1.159 2013/09/23 17:53:53 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/org-mode/ChangeLog,v 1.160 2013/11/02 10:26:02 ulm Exp $
+
+*org-mode-8.2.1 (02 Nov 2013)
+
+  02 Nov 2013; Ulrich Müller <ulm@g.o> +org-mode-8.2.1.ebuild:
+  Version bump.
 
 *org-mode-8.2 (23 Sep 2013)
 



1.1                  app-emacs/org-mode/org-mode-8.2.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/org-mode-8.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emacs/org-mode/org-mode-8.2.1.ebuild?rev=1.1&content-type=text/plain

Index: org-mode-8.2.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emacs/org-mode/org-mode-8.2.1.ebuild,v 1.1 2013/11/02 10:26:02 ulm Exp $

EAPI=5
NEED_EMACS=23

inherit elisp

DESCRIPTION="An Emacs mode for notes and project planning"
HOMEPAGE="http://www.orgmode.org/"
SRC_URI="http://orgmode.org/org-${PV}.tar.gz"

LICENSE="GPL-3+ FDL-1.3+ contrib? ( GPL-2+ MIT ) odt-schema? ( OASIS-Open )"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd ~x86-macos"
IUSE="contrib doc odt-schema"
RESTRICT="test"

DEPEND="doc? ( virtual/texi2dvi )"

S="${WORKDIR}/org-${PV}"
SITEFILE="50${PN}-gentoo-8.el"

src_compile() {
	emake datadir="${EPREFIX}${SITEETC}/${PN}"
	use doc && emake pdf card
}

src_install() {
	emake \
		DESTDIR="${D}" \
		ETCDIRS="styles $(use odt-schema && echo schema)" \
		lispdir="${EPREFIX}${SITELISP}/${PN}" \
		datadir="${EPREFIX}${SITEETC}/${PN}" \
		infodir="${EPREFIX}/usr/share/info" \
		install

	cp "${FILESDIR}/${SITEFILE}" "${T}/${SITEFILE}"

	if use contrib; then
		elisp-install ${PN}/contrib contrib/lisp/{org,ob,ox}*.el
		insinto /usr/share/doc/${PF}/contrib
		doins -r contrib/README contrib/scripts
		find "${ED}/usr/share/doc/${PF}/contrib" -type f -name '.*' \
			-exec rm -f '{}' '+'
		# add the contrib subdirectory to load-path
		sed -i -e 's:\(.*@SITELISP@\)\(.*\):&\n\1/contrib\2:' \
			"${T}/${SITEFILE}" || die
	fi

	elisp-site-file-install "${T}/${SITEFILE}"
	dodoc README doc/library-of-babel.org doc/orgcard.txt etc/ORG-NEWS
	use doc && dodoc doc/org.pdf doc/orgcard.pdf doc/orgguide.pdf
}