[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-shell: gnome-shell-3.6.2-r1.ebuild gnome-shell-3.4.2.ebuild ChangeLog metadata.xml gnome-shell-3.4.1.ebuild gnome-shell-3.2.2.1.ebuild

[Gilles Dartiguelongue (eva)]

eva         12/12/26 22:47:32

  Modified:             gnome-shell-3.4.2.ebuild ChangeLog metadata.xml
  Added:                gnome-shell-3.6.2-r1.ebuild
  Removed:              gnome-shell-3.4.1.ebuild gnome-shell-3.2.2.1.ebuild
  Log:
  Version bump for Gnome 3.6. Switch to EAPI=5 and python-r1.eclass. Clean up old revisions.
  
  (Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.4                  gnome-base/gnome-shell/gnome-shell-3.4.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-shell/gnome-shell-3.4.2.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-shell/gnome-shell-3.4.2.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-shell/gnome-shell-3.4.2.ebuild?r1=1.3&r2=1.4

Index: gnome-shell-3.4.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-shell/gnome-shell-3.4.2.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- gnome-shell-3.4.2.ebuild	7 Nov 2012 21:48:09 -0000	1.3
+++ gnome-shell-3.4.2.ebuild	26 Dec 2012 22:47:32 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-shell/gnome-shell-3.4.2.ebuild,v 1.3 2012/11/07 21:48:09 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-shell/gnome-shell-3.4.2.ebuild,v 1.4 2012/12/26 22:47:32 eva Exp $
 
 EAPI="4"
 GCONF_DEBUG="no"
@@ -151,7 +151,7 @@
 		pax-mark mr "${ED}usr/bin/gnome-shell"
 	elif has_version '>=dev-lang/spidermonkey-1.8.7[jit]'; then
 		pax-mark m "${ED}usr/bin/gnome-shell"
-    fi
+	fi
 }
 
 pkg_postinst() {



1.19                 gnome-base/gnome-shell/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-shell/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-shell/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-shell/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-shell/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	7 Nov 2012 21:48:09 -0000	1.18
+++ ChangeLog	26 Dec 2012 22:47:32 -0000	1.19
@@ -1,6 +1,20 @@
 # ChangeLog for gnome-base/gnome-shell
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-shell/ChangeLog,v 1.18 2012/11/07 21:48:09 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-shell/ChangeLog,v 1.19 2012/12/26 22:47:32 eva Exp $
+
+*gnome-shell-3.6.2-r1 (26 Dec 2012)
+
+  26 Dec 2012; Gilles Dartiguelongue <eva@g.o>
+  -files/gnome-shell-3.2.1-optional-networkmanager.patch,
+  -gnome-shell-3.2.2.1.ebuild,
+  -files/gnome-shell-3.4.0-libgnome-shell-js.so-link-1.patch,
+  -files/gnome-shell-3.4.0-libgnome-shell-js.so-link-2.patch,
+  -gnome-shell-3.4.1.ebuild, gnome-shell-3.4.2.ebuild,
+  +files/gnome-shell-3.5.x-bluetooth-flag.patch,
+  +files/gnome-shell-3.6.0-networkmanager-flag.patch,
+  +gnome-shell-3.6.2-r1.ebuild, metadata.xml:
+  Version bump for Gnome 3.6. Switch to EAPI=5 and python-r1.eclass. Clean up
+  old revisions.
 
   07 Nov 2012; Alexandre Rostovtsev <tetromino@g.o>
   gnome-shell-3.2.2.1.ebuild, gnome-shell-3.4.1.ebuild,



1.4                  gnome-base/gnome-shell/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-shell/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-shell/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-shell/metadata.xml?r1=1.3&r2=1.4

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-shell/metadata.xml,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- metadata.xml	14 May 2012 00:04:36 -0000	1.3
+++ metadata.xml	26 Dec 2012 22:47:32 -0000	1.4
@@ -3,6 +3,8 @@
 <pkgmetadata>
 <herd>gnome</herd>
 <use>
+	<flag name="i18n">Enable support for enhanced input methods through
+		<pkg>app-i18n/ibus</pkg></flag>
 	<flag name="systemd">Use <pkg>sys-apps/systemd</pkg> instead of
 		<pkg>sys-auth/consolekit</pkg> for session tracking</flag>
 </use>



1.1                  gnome-base/gnome-shell/gnome-shell-3.6.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-shell/gnome-shell-3.6.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/gnome-shell/gnome-shell-3.6.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: gnome-shell-3.6.2-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-shell/gnome-shell-3.6.2-r1.ebuild,v 1.1 2012/12/26 22:47:32 eva Exp $

EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python2_{6,7} )

inherit autotools eutils gnome2 multilib pax-utils python-r1

DESCRIPTION="Provides core UI functions for the GNOME 3 desktop"
HOMEPAGE="http://live.gnome.org/GnomeShell"

LICENSE="GPL-2+ LGPL-2+"
SLOT="0"
IUSE="+bluetooth +i18n +networkmanager systemd"
KEYWORDS="~amd64 ~x86"

# libXfixes-5.0 needed for pointer barriers
# TODO: gstreamer support is currently automagical:
# gstreamer? ( >=media-libs/gstreamer-0.11.92 )
COMMON_DEPEND="
	>=app-accessibility/at-spi2-atk-2.5.3
	>=dev-libs/atk-2[introspection]
	>=app-crypt/gcr-3.3.90[introspection]
	>=dev-libs/glib-2.31.6:2
	>=dev-libs/gjs-1.33.2
	>=dev-libs/gobject-introspection-0.10.1
	>=x11-libs/gtk+-3.3.9:3[introspection]
	>=media-libs/clutter-1.11.11:1.0[introspection]
	>=dev-libs/json-glib-0.13.2
	>=dev-libs/libcroco-0.6.2:0.6
	>=gnome-base/gnome-desktop-3.5.1:3=[introspection]
	>=gnome-base/gsettings-desktop-schemas-3.5.4
	>=gnome-base/gnome-keyring-3.3.90
	>=gnome-base/gnome-menus-3.5.3:3[introspection]
	gnome-base/libgnome-keyring
	>=gnome-extra/evolution-data-server-3.5.3:=
	>=media-libs/gstreamer-0.11.92:1.0
	>=net-im/telepathy-logger-0.2.4[introspection]
	>=net-libs/telepathy-glib-0.19[introspection]
	>=sys-auth/polkit-0.100[introspection]
	>=x11-libs/libXfixes-5.0
	>=x11-wm/mutter-${PV}[introspection]
	>=x11-libs/startup-notification-0.11

	${PYTHON_DEPS}
	dev-python/pygobject:3[${PYTHON_USEDEP}]

	dev-libs/dbus-glib
	dev-libs/libxml2:2
	gnome-base/librsvg
	media-libs/libcanberra
	media-libs/mesa
	media-sound/pulseaudio
	net-libs/libsoup:2.4[introspection]
	x11-libs/libX11
	x11-libs/gdk-pixbuf:2[introspection]
	x11-libs/pango[introspection]
	x11-apps/mesa-progs

	bluetooth? ( >=net-wireless/gnome-bluetooth-3.5[introspection] )
	networkmanager? ( >=net-misc/networkmanager-0.8.999[introspection] )
	systemd? ( >=sys-apps/systemd-31 )
"
# Runtime-only deps are probably incomplete and approximate.
# Introspection deps generated using:
#  grep -roe "imports.gi.*" gnome-shell-* | cut -f2 -d: | sort | uniq
# Each block:
# 1. Pull in polkit-0.101 for pretty authorization dialogs
# 2. Introspection stuff needed via imports.gi.*
# 3. gnome-session is needed for gnome-session-quit
# 4. Control shell settings
# 5. xdg-utils needed for xdg-open, used by extension tool
# 6. gnome-icon-theme-symbolic and dejavu font neeed for various icons & arrows
# 7. IBus is needed for i18n integration
# 8. mobile-broadband-provider-info, timezone-data for shell-mobile-providers.c
RDEPEND="${COMMON_DEPEND}
	>=sys-auth/polkit-0.101[introspection]

	>=app-accessibility/caribou-0.3
	>=gnome-base/gdm-3.5[introspection]
	>=gnome-base/libgnomekbd-2.91.4[introspection]
	media-libs/cogl[introspection]
	>=sys-apps/accountsservice-0.6.14[introspection]
	sys-power/upower[introspection]

	>=gnome-base/gnome-session-2.91.91
	>=gnome-base/gnome-settings-daemon-2.91
	>=gnome-base/gnome-control-center-2.91.92-r1[bluetooth(+)?]

	x11-misc/xdg-utils

	media-fonts/dejavu
	x11-themes/gnome-icon-theme-symbolic

	i18n? ( >=app-i18n/ibus-1.4.99[dconf,gtk3,introspection] )
	networkmanager? (
		net-misc/mobile-broadband-provider-info
		sys-libs/timezone-data )

	!systemd? ( sys-auth/consolekit )
"
DEPEND="${COMMON_DEPEND}
	dev-libs/libxslt
	>=dev-util/gtk-doc-am-1.17
	>=dev-util/intltool-0.40
	gnome-base/gnome-common
	>=sys-devel/gettext-0.17
	virtual/pkgconfig
	!!=dev-lang/spidermonkey-1.8.2*"
# libmozjs.so is picked up from /usr/lib while compiling, so block at build-time
# https://bugs.gentoo.org/show_bug.cgi?id=360413

src_prepare() {
	# Fix automagic gnome-bluetooth dep, bug #398145
	epatch "${FILESDIR}/${PN}-3.5.x-bluetooth-flag.patch"

	# Make networkmanager optional, bug #398593
	epatch "${FILESDIR}/${PN}-3.6.0-networkmanager-flag.patch"

	eautoreconf
	gnome2_src_prepare
}

src_configure() {
	# Do not error out on warnings
	G2CONF="${G2CONF}
		--enable-man
		--enable-compile-warnings=maximum
		--disable-jhbuild-wrapper-script
		$(use_with bluetooth)
		$(use_enable networkmanager)
		$(use_with systemd)
		BROWSER_PLUGIN_DIR=${EPREFIX}/usr/$(get_libdir)/nsbrowser/plugins"
	gnome2_src_configure
}

src_install() {
	gnome2_src_install
	python_replicate_script "${ED}/usr/bin/gnome-shell-extension-tool"
	python_replicate_script "${ED}/usr/bin/gnome-shell-perf-tool"

	# Required for gnome-shell on hardened/PaX, bug #398941
	# Future-proof for >=spidermonkey-1.8.7 following polkit's example
	if has_version '<dev-lang/spidermonkey-1.8.7'; then
		pax-mark mr "${ED}usr/bin/gnome-shell"
	elif has_version '>=dev-lang/spidermonkey-1.8.7[jit]'; then
		pax-mark m "${ED}usr/bin/gnome-shell"
	fi
}

pkg_postinst() {
	gnome2_pkg_postinst

	if ! has_version 'media-libs/gst-plugins-good:1.0' || \
	   ! has_version 'media-plugins/gst-plugins-vpx:1.0'; then
		ewarn "To make use of GNOME Shell's built-in screen recording utility,"
		ewarn "you need to either install media-libs/gst-plugins-good:1.0"
		ewarn "and media-plugins/gst-plugins-vpx:1.0, or use dconf-editor to change"
		ewarn "apps.gnome-shell.recorder/pipeline to what you want to use."
	fi

	if ! has_version ">=x11-base/xorg-server-1.11"; then
		ewarn "If you use multiple screens, it is highly recommended that you"
		ewarn "upgrade to >=x11-base/xorg-server-1.11 to be able to make use of"
		ewarn "pointer barriers which will make it easier to use hot corners."
	fi

	if has_version "<x11-drivers/ati-drivers-12"; then
		ewarn "GNOME Shell has been reported to show graphical corruption under"
		ewarn "x11-drivers/ati-drivers-11.*; you may want to use GNOME in"
		ewarn "fallback mode, or switch to open-source drivers."
	fi

	if has_version "media-libs/mesa[video_cards_radeon]" ||
	   has_version "media-libs/mesa[video_cards_r300]" ||
	   has_version "media-libs/mesa[video_cards_r600]"; then
		elog "GNOME Shell is unstable under classic-mode r300/r600 mesa drivers."
		elog "Make sure that gallium architecture for r300 and r600 drivers is"
		elog "selected using 'eselect mesa'."
		if ! has_version "media-libs/mesa[gallium]"; then
			ewarn "You will need to emerge media-libs/mesa with USE=gallium."
		fi
	fi

	if has_version "media-libs/mesa[video_cards_intel]" ||
	   has_version "media-libs/mesa[video_cards_i915]" ||
	   has_version "media-libs/mesa[video_cards_i965]"; then
		elog "GNOME Shell is unstable under gallium-mode i915/i965 mesa drivers."
		elog "Make sure that classic architecture for i915 and i965 drivers is"
		elog "selected using 'eselect mesa'."
		if ! has_version "media-libs/mesa[classic]"; then
			ewarn "You will need to emerge media-libs/mesa with USE=classic."
		fi
	fi
}