[gentoo-commits] gentoo-x86 commit in net-libs/rb_libtorrent: rb_libtorrent-0.15.8.ebuild ChangeLog

[Markos Chandras (hwoarang)]

hwoarang    11/09/30 12:27:07

  Modified:             ChangeLog
  Added:                rb_libtorrent-0.15.8.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha55/cvs/Linux x86_64)

Revision  Changes    Path
1.115                net-libs/rb_libtorrent/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/ChangeLog?rev=1.115&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/ChangeLog?rev=1.115&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/ChangeLog?r1=1.114&r2=1.115

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/ChangeLog,v
retrieving revision 1.114
retrieving revision 1.115
diff -u -r1.114 -r1.115
--- ChangeLog	25 Sep 2011 17:58:30 -0000	1.114
+++ ChangeLog	30 Sep 2011 12:27:07 -0000	1.115
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/rb_libtorrent
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/ChangeLog,v 1.114 2011/09/25 17:58:30 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/ChangeLog,v 1.115 2011/09/30 12:27:07 hwoarang Exp $
+
+*rb_libtorrent-0.15.8 (30 Sep 2011)
+
+  30 Sep 2011; Markos Chandras <hwoarang@g.o>
+  +rb_libtorrent-0.15.8.ebuild:
+  Version bump
 
 *rb_libtorrent-0.15.7-r1 (25 Sep 2011)
 



1.1                  net-libs/rb_libtorrent/rb_libtorrent-0.15.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/rb_libtorrent-0.15.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/rb_libtorrent-0.15.8.ebuild?rev=1.1&content-type=text/plain

Index: rb_libtorrent-0.15.8.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/rb_libtorrent-0.15.8.ebuild,v 1.1 2011/09/30 12:27:07 hwoarang Exp $

EAPI="2"
PYTHON_DEPEND="python? 2:2.6"
PYTHON_USE_WITH="threads"

inherit eutils versionator python

MY_P=${P/rb_/}
MY_P=${MY_P/torrent/torrent-rasterbar}
S=${WORKDIR}/${MY_P}

DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
HOMEPAGE="http://www.rasterbar.com/products/libtorrent/"
SRC_URI="http://libtorrent.googlecode.com/files/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="debug doc examples python ssl static-libs"
RESTRICT="test"

DEPEND=">=dev-libs/boost-1.36[python?]
	>=sys-devel/libtool-2.2
	sys-libs/zlib
	examples? ( !net-p2p/mldonkey )
	ssl? ( dev-libs/openssl )"

RDEPEND="${DEPEND}"

pkg_setup() {
	use python && python_set_active_version 2
}

src_prepare() {
	use python && python_convert_shebangs -r 2 .
}

src_configure() {
	# use multi-threading versions of boost libs
	local BOOST_LIBS="--with-boost-system=boost_system-mt \
		--with-boost-filesystem=boost_filesystem-mt \
		--with-boost-thread=boost_thread-mt \
		--with-boost-python=boost_python-mt"
	# detect boost version and location, bug 295474
	BOOST_PKG="$(best_version ">=dev-libs/boost-1.34.1")"
	BOOST_VER="$(get_version_component_range 1-2 "${BOOST_PKG/*boost-/}")"
	BOOST_VER="$(replace_all_version_separators _ "${BOOST_VER}")"
	BOOST_INC="/usr/include/boost-${BOOST_VER}"
	BOOST_LIB="/usr/$(get_libdir)/boost-${BOOST_VER}"

	local LOGGING
	use debug && LOGGING="--enable-logging=verbose"

	econf $(use_enable debug) \
		$(use_enable test tests) \
		$(use_enable examples) \
		$(use_enable python python-binding) \
		$(use_enable ssl encryption) \
		$(use_enable static-libs static) \
		--with-zlib=system \
		${LOGGING} \
		--with-boost=${BOOST_INC} \
		--with-boost-libdir=${BOOST_LIB} \
		${BOOST_LIBS}
}

src_install() {
	emake DESTDIR="${D}" install || die 'emake install failed'
	use static-libs || find "${D}" -name '*.la' -exec rm -f {} +
	dodoc ChangeLog AUTHORS NEWS README || die 'dodoc failed'
	if use doc ; then
		dohtml docs/* || die "Could not install HTML documentation"
	fi
}