[gentoo-commits] gentoo-x86 commit in dev-python/lxml: ChangeLog lxml-2.1.5.ebuild

[Jesus Rivero (neurogeek)]

neurogeek    09/01/20 13:37:39

  Modified:             ChangeLog
  Added:                lxml-2.1.5.ebuild
  Log:
  Version bump. Closes bug #255545
  (Portage version: 2.2_rc16/cvs/Linux 2.6.18-gentoo-r3 i686)

Revision  Changes    Path
1.47                 dev-python/lxml/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/ChangeLog?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/ChangeLog?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/ChangeLog?r1=1.46&r2=1.47

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/lxml/ChangeLog,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- ChangeLog	19 Aug 2008 10:07:42 -0000	1.46
+++ ChangeLog	20 Jan 2009 13:37:39 -0000	1.47
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/lxml
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/lxml/ChangeLog,v 1.46 2008/08/19 10:07:42 hawking Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/lxml/ChangeLog,v 1.47 2009/01/20 13:37:39 neurogeek Exp $
+
+*lxml-2.1.5 (20 Jan 2009)
+
+  20 Jan 2009; Jesus Rivero <neurogeek@g.o>
+  +files/lxml-2.1.5_unicode_test.patch, +lxml-2.1.5.ebuild:
+  Version bump. Closes bug #255545
 
 *lxml-2.1.1 (19 Aug 2008)
 



1.1                  dev-python/lxml/lxml-2.1.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/lxml-2.1.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/lxml/lxml-2.1.5.ebuild?rev=1.1&content-type=text/plain

Index: lxml-2.1.5.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/lxml/lxml-2.1.5.ebuild,v 1.1 2009/01/20 13:37:39 neurogeek Exp $

NEED_PYTHON="2.3"

inherit distutils

DESCRIPTION="A Pythonic binding for the libxml2 and libxslt libraries"
HOMEPAGE="http://codespeak.net/lxml/"
SRC_URI="http://codespeak.net/lxml/${P}.tgz"
LICENSE="BSD ElementTree GPL-2 PSF-2.4"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="doc examples"

RDEPEND=">=dev-libs/libxml2-2.6.21
		>=dev-libs/libxslt-1.1.15"
DEPEND="${RDEPEND}
	>=dev-python/cython-0.9.8
	>=dev-python/setuptools-0.6_rc5"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Use cython instead of own bundled version of pyrex
	epatch "${FILESDIR}/${PN}-2.0.3-no-fake-pyrex.patch"
	# Patch for xpath/unicode test. This test fails 
	epatch "${FILESDIR}/${P}_unicode_test.patch"
}

src_install() {
	distutils_src_install

	if use doc; then
		dohtml doc/html/*
		dodoc *.txt
		docinto doc
		dodoc doc/*.txt
	fi

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins -r samples/*
	fi
}

src_test() {
	distutils_python_version
	python setup.py build_ext -i || die "building extensions for test use failed"
	einfo "Running test"
	"${python}" test.py || die "tests failed"
	export PYTHONPATH="${PYTHONPATH}:${S}/src"
	einfo "Running selftest"
	"${python}" selftest.py || die "selftest failed"
	einfo "Running selftest2"
	"${python}" selftest2.py || die "selftest2 failed"
}