[gentoo-commits] gentoo-x86 commit in dev-util/buildbot: ChangeLog buildbot-0.7.11_p3.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    09/08/24 21:27:25

  Modified:             ChangeLog
  Added:                buildbot-0.7.11_p3.ebuild
  Log:
  Version bump.
  (Portage version: 14153-svn/cvs/Linux x86_64)

Revision  Changes    Path
1.43                 dev-util/buildbot/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/buildbot/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/buildbot/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/buildbot/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/buildbot/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	17 Jun 2009 20:10:33 -0000	1.42
+++ ChangeLog	24 Aug 2009 21:27:25 -0000	1.43
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/buildbot
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/ChangeLog,v 1.42 2009/06/17 20:10:33 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/ChangeLog,v 1.43 2009/08/24 21:27:25 arfrever Exp $
+
+*buildbot-0.7.11_p3 (24 Aug 2009)
+
+  24 Aug 2009; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  +buildbot-0.7.11_p3.ebuild:
+  Version bump.
 
   17 Jun 2009; Jeroen Roovers <jer@g.o> buildbot-0.7.10_p1.ebuild:
   Stable for HPPA (bug #270122).



1.1                  dev-util/buildbot/buildbot-0.7.11_p3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/buildbot/buildbot-0.7.11_p3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/buildbot/buildbot-0.7.11_p3.ebuild?rev=1.1&content-type=text/plain

Index: buildbot-0.7.11_p3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/buildbot-0.7.11_p3.ebuild,v 1.1 2009/08/24 21:27:25 arfrever Exp $

EAPI=1
NEED_PYTHON="2.4"

MY_PV="${PV/_p/p}"
MY_P="${PN}-${MY_PV}"

inherit distutils

DESCRIPTION="A Python system to automate the compile/test cycle to validate code changes"
HOMEPAGE="http://buildbot.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="doc irc mail manhole test"

CDEPEND=">=dev-python/twisted-2.0.1"
RDEPEND="${CDEPEND}
	mail? ( dev-python/twisted-mail )
	manhole? ( dev-python/twisted-conch )
	irc? ( dev-python/twisted-words )
	dev-python/twisted-web
	dev-python/twisted-mail"
DEPEND="${CDEPEND}
	test? ( dev-python/twisted-mail
			dev-python/twisted-web
			dev-python/twisted-words )
	doc? ( =dev-python/epydoc-2* )"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	enewuser buildbot
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${PN}-0.7.5-root-skip-tests.patch"
}

src_compile() {
	distutils_src_compile
	if use doc; then
		PYTHONPATH=. "${python}" docs/epyrun -o docs/reference || \
			die "epyrun failed"
	fi
}

src_test() {
	local trialopts
	if ! has_version ">=dev-python/twisted-2.2"; then
		trialopts=-R
	fi
	PYTHONPATH=. trial ${trialopts} buildbot || die "tests failed!"
}

src_install() {
	distutils_src_install
	doinfo docs/buildbot.info
	dohtml -r docs/images

	insinto /usr/share/doc/${PF}
	doins -r contrib
	doins -r docs/examples

	use doc && doins -r docs/reference

	newconfd "${FILESDIR}/buildslave.confd" buildslave
	newinitd "${FILESDIR}/buildbot.initd-r1" buildslave
	newconfd "${FILESDIR}/buildmaster.confd" buildmaster
	newinitd "${FILESDIR}/buildbot.initd-r1" buildmaster

	# Make it print the right names when you start/stop the script.
	sed -i -e 's/@buildbot@/buildslave/' \
		"${D}/etc/init.d/buildslave" || die "buildslave sed failed"
	sed -i -e 's/@buildbot@/buildmaster/' \
		"${D}/etc/init.d/buildmaster" || die "buildmaster sed failed"
}

pkg_postinst() {
	elog 'The "buildbot" user and the "buildmaster" and "buildslave" init'
	elog "scripts were added to support starting buildbot through gentoo's"
	elog "init system.  To use this set up your build master or build slave"
	elog "following the buildbot documentation, make sure the resulting"
	elog 'directories are owned by the "buildbot" user and point'
	elog "${ROOT}etc/conf.d/buildmaster or ${ROOT}etc/conf.d/buildslave"
	elog "at the right location.  The scripts can run as a different user"
	elog "if desired.  If you need to run more than one master or slave"
	elog "just copy the scripts."
	elog ""
	elog "Upstream recommends the following when upgrading:"
	elog "Each time you install a new version of Buildbot, you should run the new"
	elog "'buildbot upgrade-master' command on each of your pre-existing buildmasters."
	elog "This will add files and fix (or at least detect) incompatibilities between"
	elog "your old config and the new code."
}