[gentoo-commits] repo/gentoo:master commit in: dev-python/pyopengl/

[James Le Cuirot]

commit:     1eedd403f0770aed89b199ad13811b5474ff63f9
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 23 21:20:44 2020 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Thu Apr 23 21:24:09 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1eedd403

dev-python/pyopengl: Bump to 3.1.5, EAPI 7, add src_test

The tests pass on amd64 and ppc64le. 3 of the OpenGL-related tests
fail on ppc64be but OpenGL is known to be problematic on this
platform.

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>

 dev-python/pyopengl/Manifest              |  1 +
 dev-python/pyopengl/pyopengl-3.1.5.ebuild | 53 +++++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/dev-python/pyopengl/Manifest b/dev-python/pyopengl/Manifest
index a8086067009..1f5c1661877 100644
--- a/dev-python/pyopengl/Manifest
+++ b/dev-python/pyopengl/Manifest
@@ -1 +1,2 @@
 DIST PyOpenGL-3.1.0.tar.gz 1172688 BLAKE2B 9865a10e8b5d2756192077b4b079658c680b9f47bdaccb33285fb1942bc678b29f6a69359a1486ec023b1a73d714a7e0209b2f57776fe8b5e4a5e2d0803dba4f SHA512 f748017ab3734c7672c3fdbedcea80df297a91a78b111533e260feb0868ebb02935666c041f77db03841ee8f90057d9c53c53b00b097aae4cf67a52c7fc9c2eb
+DIST PyOpenGL-3.1.5.tar.gz 1835295 BLAKE2B fd3b3e9970b3e704b09128402b401e23c584ba20de23082d019f5ab9e1e222efdfbd2e11ecff6ee748f41bad3a5ff089c57a5c354092e2f717b13e18108de2af SHA512 5d90fc68040b4886e46ff69a59be9e3a8e31e3e1295283756db86d50a1efe681986928e18eb55d20fd2660f863653301ea483425bbe24046f55085b44f4906eb

diff --git a/dev-python/pyopengl/pyopengl-3.1.5.ebuild b/dev-python/pyopengl/pyopengl-3.1.5.ebuild
new file mode 100644
index 00000000000..74b0b47b95c
--- /dev/null
+++ b/dev-python/pyopengl/pyopengl-3.1.5.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_REQ_USE="tk?"
+PYTHON_COMPAT=( python3_{7,8} )
+
+inherit distutils-r1 virtualx
+
+MY_PN="PyOpenGL"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python OpenGL bindings"
+HOMEPAGE="http://pyopengl.sourceforge.net/ https://pypi.org/project/PyOpenGL/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+#	mirror://sourceforge/pyopengl/${MY_P}.tar.gz" # broken mirror for this release
+LICENSE="BSD"
+
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="test tk"
+
+RDEPEND="
+	media-libs/freeglut
+	virtual/opengl
+	x11-libs/libXi
+	x11-libs/libXmu
+	tk? ( dev-tcltk/togl )
+"
+DEPEND="
+	${RDEPEND}
+"
+
+# The tests need an X server with the GLX extension. Software rendering
+# under Xvfb works but only with llvmpipe, not softpipe or swr.
+BDEPEND="
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pygame[${PYTHON_USEDEP},opengl,X]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		!prefix? (
+			media-libs/mesa[llvm]
+			x11-base/xorg-server[-minimal,xorg]
+		)
+	)
+"
+
+S="${WORKDIR}/${MY_P}"
+
+python_test() {
+	run_in_build_dir virtx pytest -v "${S}"/tests
+}