[gentoo-commits] repo/gentoo:master commit in: app-emacs/lsp-mode/

[Maciej Barć]

commit:     9b334da658e4fd22eb44371a1d7ba2f44111f7b2
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 23 15:27:05 2022 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Thu Jun 23 15:27:05 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9b334da6

app-emacs/lsp-mode: bump to 8.0.0_p20220620

2022.06.20 snapshot

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 app-emacs/lsp-mode/Manifest                        |  1 +
 app-emacs/lsp-mode/lsp-mode-8.0.0_p20220620.ebuild | 61 ++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/app-emacs/lsp-mode/Manifest b/app-emacs/lsp-mode/Manifest
index a66229b89085..8fbe910bb5d2 100644
--- a/app-emacs/lsp-mode/Manifest
+++ b/app-emacs/lsp-mode/Manifest
@@ -1 +1,2 @@
 DIST lsp-mode-8.0.0.tar.gz 14703640 BLAKE2B ab7993772cfc127ee94ba4a0af75e8d7f6789ac22c76acce8df250b5579c1dd2f41e353b26cbdcf6e1a2e6a8d1f8a179d4736b67914cdec31c23032f93dffd3c SHA512 2620288142cea7b06ad2725b63e5db945b1d62d0b4c215e8d35d79d6c3f05bcdf2736dab34bd10c2b9f8928caf36ef617182c41c309e62e2ce8ddf45df376cbc
+DIST lsp-mode-8.0.0_p20220620.tar.gz 15464614 BLAKE2B 10e50a52e2a725b1a275b81514bb268619b128370f8989970c75c87bc37516588e798c5f2531b73689d9d102fbd6b965841c6d8a0c337cb8d9052b632a01e289 SHA512 d464418df6eb99d8a1f4cad8c9e31ca057286f846afbb0078fdff21cfc685ffc158b1b37d22224372bee67eb5298f20bb4db83ed466c09e4b4b3a83db865ef09

diff --git a/app-emacs/lsp-mode/lsp-mode-8.0.0_p20220620.ebuild b/app-emacs/lsp-mode/lsp-mode-8.0.0_p20220620.ebuild
new file mode 100644
index 000000000000..b87fe3e08a74
--- /dev/null
+++ b/app-emacs/lsp-mode/lsp-mode-8.0.0_p20220620.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+H=9957623d93b13fabaca8ba35b85da8fcceaeef69
+NEED_EMACS=26.1
+
+inherit elisp
+
+DESCRIPTION="Emacs client/library for the Language Server Protocol"
+HOMEPAGE="https://emacs-lsp.github.io/lsp-mode/"
+SRC_URI="https://github.com/emacs-lsp/${PN}/archive/${H}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${PN}-${H}
+
+LICENSE="GPL-3+"
+KEYWORDS="~amd64"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=app-emacs/dash-2.18.0
+	>=app-emacs/f-0.20.0
+	app-emacs/ht
+	app-emacs/lv
+	app-emacs/markdown-mode
+	app-emacs/spinner
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		app-emacs/deferred
+		app-emacs/ecukes
+		app-emacs/el-mock
+		app-emacs/ert-runner
+		app-emacs/espuds
+		app-emacs/flycheck
+		app-emacs/undercover
+	)
+"
+
+DOCS=( AUTHORS CHANGELOG.org README.md refcard )
+BYTECOMPFLAGS="-L . -L clients"
+ELISP_REMOVE="test/lsp-clangd-test.el test/lsp-common-test.el
+	test/lsp-integration-test.el"  # Remove failing tests
+SITEFILE="50${PN}-gentoo.el"
+
+src_compile() {
+	elisp_src_compile
+	elisp-compile clients/*.el
+}
+
+src_test() {
+	ert-runner -L clients --reporter ert+duration -t "!no-win" -t "!org" || die
+}
+
+src_install() {
+	elisp_src_install
+	elisp-install ${PN}/clients clients/*
+}