[gentoo-commits] proj/gamerlay:master commit in: games-strategy/curseofwar/

[Azamat H. Hackimov]

commit:     e6e4b221f047b0109a6f167e718009dcbf4f2638
Author:     Azamat H. Hackimov <azamat.hackimov <AT> gmail <DOT> com>
AuthorDate: Mon Jul 12 20:37:09 2021 +0000
Commit:     Azamat H. Hackimov <winterheart <AT> gentoo <DOT> ru>
CommitDate: Mon Jul 12 20:45:59 2021 +0000
URL:        https://gitweb.gentoo.org/proj/gamerlay.git/commit/?id=e6e4b221

games-strategy/curseofwar: update to 1.3.0

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Azamat H. Hackimov <azamat.hackimov <AT> gmail.com>

 games-strategy/curseofwar/curseofwar-1.3.0.ebuild | 50 +++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/games-strategy/curseofwar/curseofwar-1.3.0.ebuild b/games-strategy/curseofwar/curseofwar-1.3.0.ebuild
new file mode 100644
index 0000000..f41e4d7
--- /dev/null
+++ b/games-strategy/curseofwar/curseofwar-1.3.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="A fast-paced action strategy game implemented using ncurses user interface."
+HOMEPAGE="https://github.com/a-nikolaev/curseofwar/wiki"
+SRC_URI="https://github.com/a-nikolaev/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ncurses sdl"
+REQUIRED_USE="|| ( ncurses sdl )"
+
+DEPEND="ncurses? ( sys-libs/ncurses:0 )
+	sdl? ( media-libs/libsdl )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	sed -i -e "s:TARGET_LINK_LIBRARIES( curseofwar \${COMMON_LIBS} ncurses ):TARGET_LINK_LIBRARIES( curseofwar \${COMMON_LIBS} ncurses tinfo ):g" CMakeLists.txt
+	sed -i -e 's:INSTALL_DATA:"/usr/share/curseofwar/":g' path.c || die "sed failed"
+	cmake_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DCW_NCURSE_FRONTEND=$(usex ncurses)
+		-DCW_SDL_FRONTEND=$(usex sdl)
+		-DCW_SDL_MULTIPLAYER=$(usex sdl)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	if use ncurses ; then
+		dobin "${BUILD_DIR}/${PN}"
+		doman ${PN}.6
+	fi
+	if use sdl ; then
+		dobin "${BUILD_DIR}/${PN}-sdl"
+		doman ${PN}-sdl.6
+		insinto "/usr/share/${PN}"
+		doins -r images
+	fi
+	dodoc CHANGELOG README
+}