[gentoo-commits] gentoo-x86 commit in app-emacs/cedet: ChangeLog cedet-1.0_pre4-r2.ebuild

[Ulrich Mueller (ulm)]

ulm         07/09/12 15:24:15

  Modified:             ChangeLog
  Added:                cedet-1.0_pre4-r2.ebuild
  Log:
  Don't require ede while building semantic, fixes bug #191341.
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.31                 app-emacs/cedet/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emacs/cedet/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emacs/cedet/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emacs/cedet/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emacs/cedet/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	2 Sep 2007 20:11:16 -0000	1.30
+++ ChangeLog	12 Sep 2007 15:24:14 -0000	1.31
@@ -1,6 +1,12 @@
 # ChangeLog for app-emacs/cedet
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emacs/cedet/ChangeLog,v 1.30 2007/09/02 20:11:16 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/cedet/ChangeLog,v 1.31 2007/09/12 15:24:14 ulm Exp $
+
+*cedet-1.0_pre4-r2 (12 Sep 2007)
+
+  12 Sep 2007; Ulrich Mueller <ulm@g.o>
+  +files/1.0_pre4-semantic-build.patch, +cedet-1.0_pre4-r2.ebuild:
+  Don't require ede while building semantic, fixes bug #191341.
 
   02 Sep 2007; Ulrich Mueller <ulm@g.o> files/60cedet-gentoo.el:
   Suppress startup message.



1.1                  app-emacs/cedet/cedet-1.0_pre4-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emacs/cedet/cedet-1.0_pre4-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emacs/cedet/cedet-1.0_pre4-r2.ebuild?rev=1.1&content-type=text/plain

Index: cedet-1.0_pre4-r2.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emacs/cedet/cedet-1.0_pre4-r2.ebuild,v 1.1 2007/09/12 15:24:14 ulm Exp $

inherit elisp eutils versionator

MY_PV=$(delete_version_separator 2)
DESCRIPTION="CEDET: Collection of Emacs Development Tools"
HOMEPAGE="http://cedet.sourceforge.net/"
SRC_URI="mirror://sourceforge/cedet/${PN}-${MY_PV}.tar.gz"

LICENSE="GPL-2 FDL-1.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

DEPEND="!app-emacs/semantic
	!app-emacs/eieio
	!app-emacs/speedbar"

S="${WORKDIR}/${PN}-${MY_PV}"

SITEFILE=60${PN}-gentoo.el

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/1.0_pre3-eieio-tests-gentoo.patch" # bug 124598
	epatch "${FILESDIR}/1.0_pre4-semantic-build.patch" # bugs 183205/191341
}

src_compile() {
	emake EMACS=/usr/bin/emacs || die "emake failed"
}

src_install() {
	find "${S}" -type f -print | while read target; do
		local directory=$(dirname ${target}) file=$(basename ${target})
		local sub_directory=$(echo ${directory} | sed "s%^${S}/*%%;s/^$/./")
		case $file in
			*~ | Makefile | *.texi | *-script | PRERELEASE_CHECKLIST \
				| Project.ede | IMPLICIT_TARGETS)
				;;
			ChangeLog | README | AUTHORS | *NEWS | INSTALL)
				docinto ${sub_directory}
				dodoc ${target}
				;;
			*.png)
				insinto /usr/share/doc/${PF}/${sub_directory}
				doins ${target}
				;;
			*.el | *.elc)
				insinto ${SITELISP}/${PN}/${sub_directory}
				doins ${target}
				;;
			*.info*)
				doinfo ${target}
				;;
			*)
				insinto ${SITELISP}/${PN}/${sub_directory}
				doins ${target}
				echo ${target} >>"${S}/IMPLICIT_TARGETS"
				;;
		esac
	done

	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
}



-- 
gentoo-commits@g.o mailing list