[gentoo-commits] gentoo-x86 commit in sys-libs/e2fsprogs-libs: e2fsprogs-libs-1.41.9.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      09/08/23 21:27:55

  Modified:             ChangeLog
  Added:                e2fsprogs-libs-1.41.9.ebuild
  Log:
  Version bump #282445 by Marcin Mirosław.
  (Portage version: 2.2_rc38/cvs/Linux x86_64)

Revision  Changes    Path
1.34                 sys-libs/e2fsprogs-libs/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	17 Aug 2009 20:24:00 -0000	1.33
+++ ChangeLog	23 Aug 2009 21:27:55 -0000	1.34
@@ -1,6 +1,12 @@
 # ChangeLog for sys-libs/e2fsprogs-libs
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.33 2009/08/17 20:24:00 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.34 2009/08/23 21:27:55 vapier Exp $
+
+*e2fsprogs-libs-1.41.9 (23 Aug 2009)
+
+  23 Aug 2009; Mike Frysinger <vapier@g.o>
+  +e2fsprogs-libs-1.41.9.ebuild:
+  Version bump #282445 by Marcin Mirosław.
 
   15 Aug 2009; Alexis Ballier <aballier@g.o>
   e2fsprogs-libs-1.41.8.ebuild:



1.1                  sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.9.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.9.ebuild?rev=1.1&content-type=text/plain

Index: e2fsprogs-libs-1.41.9.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.9.ebuild,v 1.1 2009/08/23 21:27:55 vapier Exp $

EAPI="2"

inherit toolchain-funcs

DESCRIPTION="e2fsprogs libraries (common error and subsystem)"
HOMEPAGE="http://e2fsprogs.sourceforge.net/"
SRC_URI="mirror://sourceforge/e2fsprogs/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nls"

RDEPEND="elibc_glibc? ( >=sys-libs/glibc-2.6 )
	!sys-libs/com_err
	!sys-libs/ss
	!<sys-fs/e2fsprogs-1.41.8"
DEPEND="nls? ( sys-devel/gettext )
	dev-util/pkgconfig
	sys-devel/bc"

export VARTEXFONTS=${T}/fonts #281390

src_prepare() {
	# stupid configure script clobbers CC for us
	sed -i '/if test -z "$CC" ; then CC=cc; fi/d' configure
}

src_configure() {
	# We want to use the "bsd" libraries while building on Darwin, but while
	# building on other Gentoo/*BSD we prefer elf-naming scheme.
	local libtype
	case ${CHOST} in
		*-darwin*) libtype=bsd;;
		*)         libtype=elf;;
	esac

	# we use blkid/uuid from util-linux now
	ac_cv_lib_uuid_uuid_generate=yes \
	ac_cv_lib_blkid_blkid_get_cache=yes \
	ac_cv_path_LDCONFIG=: \
	econf \
		--disable-libblkid \
		--disable-libuuid \
		--enable-${libtype}-shlibs \
		$(use_enable !elibc_uclibc tls) \
		$(use_enable nls)
}

src_install() {
	emake STRIP=: DESTDIR="${D}" install || die
	gen_usr_ldscript -a com_err ss
}