[gentoo-commits] repo/gentoo:master commit in: x11-plugins/e16-epplets/

[Andrew Savchenko]

commit:     943c7aaeedd86d3d0fc9ebd877c2625f571969d0
Author:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 31 14:54:11 2022 +0000
Commit:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
CommitDate: Sun Jul 31 14:54:11 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=943c7aae

x11-plugins/e16-epplets: add 0.17

Signed-off-by: Andrew Savchenko <bircoph <AT> gentoo.org>

 x11-plugins/e16-epplets/Manifest                |  1 +
 x11-plugins/e16-epplets/e16-epplets-0.17.ebuild | 49 +++++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/x11-plugins/e16-epplets/Manifest b/x11-plugins/e16-epplets/Manifest
index 5fbf1f3995b3..d97bb22a35c4 100644
--- a/x11-plugins/e16-epplets/Manifest
+++ b/x11-plugins/e16-epplets/Manifest
@@ -1 +1,2 @@
 DIST e16-epplets-0.16.tar.xz 800796 BLAKE2B 70785fce2949bb5e3b0f950436e63246b576dc2dc13ac392e2d884f913e0f22e68b428b416e20807adfb47ca7a148bb3242efff6dbeac8c734ed645ff3f1c705 SHA512 2cc90dee741a50f54665078db6197d7736d5423419439e640d5170057b80111458dbf4b7c9a92898e96654b1af4a986e5cedb88a565616e70ed0fba6ec82cd9b
+DIST e16-epplets-0.17.tar.xz 797728 BLAKE2B 17d1bcd885c2da1192e1ac249cc57b2b0316f10f163b4dbefd4bf10315142ec89c64e8ff0e6b8a6e86a2f393720b41324978117026150a05fd349783f3eecdff SHA512 26731b5da902f2afb7aaaa80513c2eef5a476c4156396390e08f406746e20e5cfa4ac3309b97f1104f7f53bd824be333b7a791e34480c3aaaa64856eeecf0f2a

diff --git a/x11-plugins/e16-epplets/e16-epplets-0.17.ebuild b/x11-plugins/e16-epplets/e16-epplets-0.17.ebuild
new file mode 100644
index 000000000000..a9d646dbd7f3
--- /dev/null
+++ b/x11-plugins/e16-epplets/e16-epplets-0.17.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Enlightenment DR16 epplets"
+HOMEPAGE="https://www.enlightenment.org https://sourceforge.net/projects/enlightenment/"
+SRC_URI="mirror://sourceforge/enlightenment/${P}.tar.xz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="GPL-2+ BSD public-domain"
+SLOT="0"
+IUSE="cdaudio libgtop opengl"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+CDEPEND="
+	cdaudio? ( media-libs/libcdaudio )
+	libgtop? ( gnome-base/libgtop )
+	opengl? ( media-libs/glu media-libs/mesa[X(+)] )
+	>=media-libs/imlib2-1.2.0
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-wm/e16
+"
+RDEPEND="${CDEPEND}
+	!x11-plugins/epplets
+"
+DEPEND="${CDEPEND}
+	x11-base/xorg-proto
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable cdaudio)
+		$(use_enable opengl glx)
+		$(use_with libgtop)
+		--disable-esd
+		--disable-static
+		--disable-werror
+	)
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}"/usr -name '*.la' -delete || die
+}