[gentoo-commits] gentoo-x86 commit in sys-apps/pcsc-lite: ChangeLog pcsc-lite-1.6.4.ebuild

[Diego Petteno (flameeyes)]

flameeyes    10/09/28 23:37:16

  Modified:             ChangeLog
  Added:                pcsc-lite-1.6.4.ebuild
  Log:
  Version bump; the new version has an improved init script that takes less time to start (no process creation for depend calculation), and properly uses s-s-d to respect system limits; also upstream moved to libusb-1 rather than the previous libusb-0.
  
  (Portage version: 2.2_rc88/cvs/Linux x86_64)

Revision  Changes    Path
1.87                 sys-apps/pcsc-lite/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/ChangeLog?rev=1.87&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/ChangeLog?rev=1.87&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/ChangeLog?r1=1.86&r2=1.87

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/ChangeLog,v
retrieving revision 1.86
retrieving revision 1.87
diff -u -r1.86 -r1.87
--- ChangeLog	5 Sep 2010 15:54:53 -0000	1.86
+++ ChangeLog	28 Sep 2010 23:37:15 -0000	1.87
@@ -1,6 +1,15 @@
 # ChangeLog for sys-apps/pcsc-lite
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/ChangeLog,v 1.86 2010/09/05 15:54:53 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/ChangeLog,v 1.87 2010/09/28 23:37:15 flameeyes Exp $
+
+*pcsc-lite-1.6.4 (28 Sep 2010)
+
+  28 Sep 2010; Diego E. Pettenò <flameeyes@g.o>
+  +pcsc-lite-1.6.4.ebuild, +files/pcscd-init.2:
+  Version bump; the new version has an improved init script that takes less
+  time to start (no process creation for depend calculation), and properly
+  uses s-s-d to respect system limits; also upstream moved to libusb-1
+  rather than the previous libusb-0.
 
   05 Sep 2010; Raúl Porcel <armin76@g.o> pcsc-lite-1.6.1.ebuild:
   ia64/m68k/s390/sh/sparc stable wrt #330601



1.1                  sys-apps/pcsc-lite/pcsc-lite-1.6.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/pcsc-lite-1.6.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/pcsc-lite-1.6.4.ebuild?rev=1.1&content-type=text/plain

Index: pcsc-lite-1.6.4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/pcsc-lite-1.6.4.ebuild,v 1.1 2010/09/28 23:37:15 flameeyes Exp $

EAPI="3"

inherit multilib

DESCRIPTION="PC/SC Architecture smartcard middleware library"
HOMEPAGE="http://pcsclite.alioth.debian.org/"

if [[ "${PV}" = "9999" ]]; then
	inherit autotools subversion
	ESVN_REPO_URI="svn://svn.debian.org/pcsclite/trunk"
	S="${WORKDIR}/trunk"
else
	STUPID_NUM="3337"
	MY_P="${PN}-${PV/_/-}"
	SRC_URI="http://alioth.debian.org/download.php/${STUPID_NUM}/${MY_P}.tar.bz2"
	S="${WORKDIR}/${MY_P}"
fi

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="hal static usb"

RDEPEND="usb? ( virtual/libusb:1 )
	hal? ( sys-apps/hal )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

pkg_setup() {
	if use hal && use usb; then
		ewarn "The usb and hal USE flags cannot be enabled at the same time"
		ewarn "Disabling the effect of USE=usb"
	fi
}

if [[ "${PV}" == "9999" ]]; then
	src_prepare() {
		S="${WORKDIR}/trunk/PCSC"
		cd "${S}"
		AT_M4DIR="m4" eautoreconf
	}
fi

src_configure() {
	local myconf
	if use hal; then
		myconf="--enable-libhal --disable-libusb"
	else
		myconf="--disable-libhal $(use_enable usb libusb)"
	fi

	econf \
		--docdir="/usr/share/doc/${PF}" \
		--enable-usbdropdir="/usr/$(get_libdir)/readers/usb" \
		${myconf} \
		$(use_enable static)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS DRIVERS HELP README SECURITY ChangeLog || die

	newinitd "${FILESDIR}/pcscd-init.2" pcscd || die
	newconfd "${FILESDIR}/pcscd-confd" pcscd || die

	if ! use hal; then
		sed -i -e '/need hald/d' "${D}"/etc/init.d/pcscd || die
	fi
}