[gentoo-commits] gentoo-x86 commit in net-dns/unbound: metadata.xml ChangeLog unbound-1.5.0.ebuild

[Tim Harder (radhermit)]

radhermit    14/11/27 18:36:35

  Modified:             metadata.xml ChangeLog
  Added:                unbound-1.5.0.ebuild
  Log:
  Version bump, add dnstap use flag.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.11                 net-dns/unbound/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/metadata.xml?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/metadata.xml?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/metadata.xml?r1=1.10&r2=1.11

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/unbound/metadata.xml,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- metadata.xml	19 Nov 2013 21:31:15 -0000	1.10
+++ metadata.xml	27 Nov 2014 18:36:35 -0000	1.11
@@ -23,6 +23,7 @@
   as a server, but are linked into an application) are easily possible.
   </longdescription>
   <use>
+    <flag name='dnstap'>Enable dnstap support</flag>
     <flag name='gost'>Enable GOST support</flag>
   </use>
 </pkgmetadata>



1.77                 net-dns/unbound/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/ChangeLog?rev=1.77&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/ChangeLog?rev=1.77&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/ChangeLog?r1=1.76&r2=1.77

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v
retrieving revision 1.76
retrieving revision 1.77
diff -u -r1.76 -r1.77
--- ChangeLog	2 Nov 2014 08:49:46 -0000	1.76
+++ ChangeLog	27 Nov 2014 18:36:35 -0000	1.77
@@ -1,6 +1,12 @@
 # ChangeLog for net-dns/unbound
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v 1.76 2014/11/02 08:49:46 swift Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/ChangeLog,v 1.77 2014/11/27 18:36:35 radhermit Exp $
+
+*unbound-1.5.0 (27 Nov 2014)
+
+  27 Nov 2014; Tim Harder <radhermit@g.o> +unbound-1.5.0.ebuild,
+  metadata.xml:
+  Version bump, add dnstap use flag.
 
   02 Nov 2014; Sven Vermeulen <swift@g.o> unbound-1.4.22-r1.ebuild:
   Remove sec-policy/selinux-* dependency from DEPEND but keep in RDEPEND (bug



1.1                  net-dns/unbound/unbound-1.5.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/unbound-1.5.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dns/unbound/unbound-1.5.0.ebuild?rev=1.1&content-type=text/plain

Index: unbound-1.5.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dns/unbound/unbound-1.5.0.ebuild,v 1.1 2014/11/27 18:36:35 radhermit Exp $

EAPI=5
PYTHON_COMPAT=( python2_7 )

inherit eutils flag-o-matic multilib-minimal python-single-r1 systemd user

DESCRIPTION="A validating, recursive and caching DNS resolver"
HOMEPAGE="http://unbound.net/"
SRC_URI="http://unbound.net/downloads/${P}.tar.gz"

LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug dnstap gost python selinux static-libs test threads"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

# Note: expat is needed by executable only but the Makefile is custom
# and doesn't make it possible to easily install the library without
# the executables. MULTILIB_USEDEP may be dropped once build system
# is fixed.

CDEPEND=">=dev-libs/expat-2.1.0-r3[${MULTILIB_USEDEP}]
	>=dev-libs/libevent-2.0.21[${MULTILIB_USEDEP}]
	>=dev-libs/openssl-1.0.1h-r2[${MULTILIB_USEDEP}]
	dnstap? (
		dev-libs/fstrm[${MULTILIB_USEDEP}]
		>=dev-libs/protobuf-c-1.0.2-r1[${MULTILIB_USEDEP}]
	)
	python? ( ${PYTHON_DEPS} )"

DEPEND="${CDEPEND}
	python? ( dev-lang/swig )
	test? (
		net-dns/ldns-utils[examples]
		dev-util/splint
		app-text/wdiff
	)"

RDEPEND="${CDEPEND}
	selinux? ( sec-policy/selinux-bind )"

# bug #347415
RDEPEND="${RDEPEND}
	net-dns/dnssec-root"

pkg_setup() {
	enewgroup unbound
	enewuser unbound -1 -1 /etc/unbound unbound

	use python && python-single-r1_pkg_setup
}

src_prepare() {
	# To avoid below error messages, set 'trust-anchor-file' to same value in
	# 'auto-trust-anchor-file'.
	# [23109:0] error: Could not open autotrust file for writing,
	# /etc/dnssec/root-anchors.txt: Permission denied
	epatch "${FILESDIR}"/${PN}-1.4.12-gentoo.patch

	# required for the python part
	multilib_copy_sources
}

src_configure() {
	[[ ${CHOST} == *-darwin* ]] || append-ldflags -Wl,-z,noexecstack
	multilib-minimal_src_configure
}

multilib_src_configure() {
	econf \
		$(use_enable debug) \
		$(use_enable gost) \
		$(use_enable dnstap) \
		$(use_enable static-libs static) \
		$(multilib_native_use_with python pythonmodule) \
		$(multilib_native_use_with python pyunbound) \
		$(use_with threads pthreads) \
		--disable-rpath \
		--enable-ecdsa \
		--with-libevent="${EPREFIX}"/usr \
		--with-pidfile="${EPREFIX}"/var/run/unbound.pid \
		--with-rootkey-file="${EPREFIX}"/etc/dnssec/root-anchors.txt \
		--with-ssl="${EPREFIX}"/usr \
		--with-libexpat="${EPREFIX}"/usr

		# http://unbound.nlnetlabs.nl/pipermail/unbound-users/2011-April/001801.html
		# $(use_enable debug lock-checks) \
		# $(use_enable debug alloc-checks) \
		# $(use_enable debug alloc-lite) \
		# $(use_enable debug alloc-nonregional) \
}

multilib_src_install_all() {
	prune_libtool_files --modules
	use python && python_optimize

	newinitd "${FILESDIR}"/unbound.initd unbound
	newconfd "${FILESDIR}"/unbound.confd unbound

	systemd_dounit "${FILESDIR}"/unbound.service
	systemd_newunit "${FILESDIR}"/unbound_at.service "unbound@.service"
	systemd_dounit "${FILESDIR}"/unbound-anchor.service

	dodoc doc/{README,CREDITS,TODO,Changelog,FEATURES}

	# bug #315519
	dodoc contrib/unbound_munin_

	docinto selinux
	dodoc contrib/selinux/*

	exeinto /usr/share/${PN}
	doexe contrib/update-anchor.sh
}