[gentoo-commits] gentoo-x86 commit in media-plugins/audacious-plugins: ChangeLog audacious-plugins-1.5.1-r2.ebuild

[Peter Alfredsen (loki_val)]

loki_val    08/09/03 12:28:04

  Modified:             ChangeLog
  Added:                audacious-plugins-1.5.1-r2.ebuild
  Log:
  Add libmtp-0.3.0 API support, patch from upstream bugzilla rebased. Fix configure being invoked with wrong options (flac->flacng, cdaudio-ng->cdaudio).
  (Portage version: 2.2_rc8/cvs/Linux 2.6.25.8 i686)

Revision  Changes    Path
1.96                 media-plugins/audacious-plugins/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/audacious-plugins/ChangeLog?rev=1.96&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/audacious-plugins/ChangeLog?rev=1.96&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/audacious-plugins/ChangeLog?r1=1.95&r2=1.96

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/ChangeLog,v
retrieving revision 1.95
retrieving revision 1.96
diff -u -r1.95 -r1.96
--- ChangeLog	1 Aug 2008 16:56:15 -0000	1.95
+++ ChangeLog	3 Sep 2008 12:28:03 -0000	1.96
@@ -1,6 +1,14 @@
 # ChangeLog for media-plugins/audacious-plugins
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/ChangeLog,v 1.95 2008/08/01 16:56:15 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/ChangeLog,v 1.96 2008/09/03 12:28:03 loki_val Exp $
+
+*audacious-plugins-1.5.1-r2 (03 Sep 2008)
+
+  03 Sep 2008; Peter Alfredsen <loki_val@g.o>
+  +files/1.5.1-libmtp-0.3.0-API.patch, +audacious-plugins-1.5.1-r2.ebuild:
+  Add libmtp-0.3.0 API support, patch from upstream bugzilla rebased. Fix
+  configure being invoked with wrong options (flac->flacng,
+  cdaudio-ng->cdaudio).
 
   01 Aug 2008; Doug Goldstein <cardoe@g.o> metadata.xml:
   add GLEP 56 USE flag desc from use.local.desc



1.1                  media-plugins/audacious-plugins/audacious-plugins-1.5.1-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/audacious-plugins/audacious-plugins-1.5.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/audacious-plugins/audacious-plugins-1.5.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: audacious-plugins-1.5.1-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/audacious-plugins-1.5.1-r2.ebuild,v 1.1 2008/09/03 12:28:03 loki_val Exp $

inherit eutils flag-o-matic autotools

MY_P="${P/_/-}"
S="${WORKDIR}/${MY_P}"
DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
HOMEPAGE="http://audacious-media-player.org/"
SRC_URI="http://distfiles.atheme.org/${MY_P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="aac adplug alsa arts chardet esd flac gnome jack lirc modplug mp3 mtp musepack nls oss pulseaudio scrobbler sdl sid sndfile sse2 timidity tta vorbis wavpack wma"

RDEPEND="app-arch/unzip
	>=dev-libs/libcdio-0.79-r1
	>=dev-libs/dbus-glib-0.60
	dev-libs/libxml2
	>=gnome-base/libglade-2.3.1
	>=media-libs/libcddb-1.2.1
	>=media-sound/audacious-1.5.1-r1
	>=net-misc/neon-0.26.4
	>=x11-libs/gtk+-2.10
	adplug? ( >=dev-cpp/libbinio-1.4 )
	alsa? ( >=media-libs/alsa-lib-1.0.16 )
	arts? ( kde-base/arts )
	esd? ( >=media-sound/esound-0.2.38-r1 )
	flac? ( >=media-libs/libvorbis-1.0
		>=media-libs/flac-1.2.1-r1 )
	jack? ( >=media-libs/bio2jack-0.4
		media-sound/jack-audio-connection-kit )
	lirc? ( app-misc/lirc )
	mp3? ( media-libs/libmad )
	mtp? ( media-libs/libmtp )
	musepack? ( media-libs/libmpcdec media-libs/taglib )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
	scrobbler? ( net-misc/curl
		     media-libs/musicbrainz )
	sdl? (	>=media-libs/libsdl-1.2.5 )
	sid? ( media-libs/libsidplay )
	sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
	timidity? ( media-sound/timidity++ )
	tta? ( media-libs/libid3tag )
	vorbis? ( >=media-libs/libvorbis-1.2.0
		  >=media-libs/libogg-1.1.3 )
	wavpack? ( >=media-sound/wavpack-4.41.0 )
	wma? ( >=media-libs/libmms-0.3 )"

DEPEND="${RDEPEND}
	nls? ( dev-util/intltool )
	>=dev-util/pkgconfig-0.9.0"

mp3_warning() {
	if ! useq mp3 ; then
		ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	# Bug 232418; patch by Ivan Iraci <ivanhoe@×××××××.net>
	epatch "${FILESDIR}/${PV}-missing-include.patch"
	# Bug 230995; patch by Linus Walleij
	# http://bugzilla.atheme.org/show_bug.cgi?id=35
	# Rebased from hg head to 1.5.1
	epatch "${FILESDIR}/${PV}-libmtp-0.3.0-API.patch"
	AT_M4DIR="m4" eautoreconf
}

src_compile() {
	mp3_warning

	econf \
		--enable-cdaudio \
		--enable-dbus \
		--enable-neon \
		--disable-projectm \
		--disable-projectm-1.0 \
		$(use_enable aac) \
		$(use_enable adplug) \
		$(use_enable alsa) \
		$(use_enable arts) \
		$(use_enable chardet) \
		$(use_enable esd) \
		$(use_enable flac flacng) \
		$(use_enable jack) \
		$(use_enable gnome gnomeshortcuts) \
		$(use_enable lirc) \
		$(use_enable mp3) \
		$(use_enable modplug) \
		$(use_enable musepack) \
		$(use_enable mtp mtp_up) \
		$(use_enable nls) \
		$(use_enable oss) \
		$(use_enable pulseaudio pulse) \
		$(use_enable sdl paranormal) \
		$(use_enable sid) \
		$(use_enable sndfile) \
		$(use_enable sse2) \
		$(use_enable timidity) \
		$(use_enable tta) \
		$(use_enable vorbis) \
		$(use_enable wavpack) \
		$(use_enable wma) \
		|| die

	emake || die "make failed"
}

src_install() {
	make DESTDIR="${D}" install || die
	dodoc AUTHORS
}

pkg_postinst() {
	mp3_warning
}