[gentoo-commits] gentoo-x86 commit in app-admin/ansible: ansible-1.9.2.ebuild ChangeLog

[Justin Lecher (jlec)]

jlec        15/06/26 12:31:49

  Modified:             ChangeLog
  Added:                ansible-1.9.2.ebuild
  Log:
  Version Bump
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key E9402A79B03529A2!)

Revision  Changes    Path
1.72                 app-admin/ansible/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ChangeLog?rev=1.72&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ChangeLog?rev=1.72&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ChangeLog?r1=1.71&r2=1.72

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/ansible/ChangeLog,v
retrieving revision 1.71
retrieving revision 1.72
diff -u -r1.71 -r1.72
--- ChangeLog	6 Jun 2015 09:50:13 -0000	1.71
+++ ChangeLog	26 Jun 2015 12:31:49 -0000	1.72
@@ -1,6 +1,11 @@
 # ChangeLog for app-admin/ansible
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/ansible/ChangeLog,v 1.71 2015/06/06 09:50:13 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/ansible/ChangeLog,v 1.72 2015/06/26 12:31:49 jlec Exp $
+
+*ansible-1.9.2 (26 Jun 2015)
+
+  26 Jun 2015; Justin Lecher <jlec@g.o> +ansible-1.9.2.ebuild:
+  Version Bump
 
   06 Jun 2015; Justin Lecher <jlec@g.o> ansible-1.9.0.1.ebuild,
   ansible-1.9.1.ebuild, ansible-9999.ebuild:



1.1                  app-admin/ansible/ansible-1.9.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ansible-1.9.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/ansible/ansible-1.9.2.ebuild?rev=1.1&content-type=text/plain

Index: ansible-1.9.2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/ansible/ansible-1.9.2.ebuild,v 1.1 2015/06/26 12:31:49 jlec Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 )

inherit distutils-r1 eutils readme.gentoo

DESCRIPTION="Radically simple deployment, model-driven configuration management, and command execution framework"
HOMEPAGE="http://ansible.com/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x64-macos"
IUSE="test"

RDEPEND="
	dev-python/httplib2[${PYTHON_USEDEP}]
	dev-python/jinja[${PYTHON_USEDEP}]
	dev-python/keyczar[${PYTHON_USEDEP}]
	>=dev-python/pycrypto-2.6[${PYTHON_USEDEP}]
	dev-python/pyyaml[${PYTHON_USEDEP}]
	dev-python/setuptools[${PYTHON_USEDEP}]
	net-misc/sshpass
	virtual/ssh
"
DEPEND="
	dev-python/setuptools[${PYTHON_USEDEP}]
	test? (
		${RDEPEND}
		dev-python/mock[${PYTHON_USEDEP}]
		dev-python/nose[${PYTHON_USEDEP}]
		dev-python/passlib[${PYTHON_USEDEP}]
		dev-vcs/git
	)"

# not included in release tarball
RESTRICT="test"

python_test() {
	nosetests -d -w test/units -v --with-coverage --cover-package=ansible --cover-branches || die
}

python_install_all() {
	EXAMPLES=( examples )
	distutils-r1_python_install_all

	doman docs/man/man1/*.1

	newenvd "${FILESDIR}"/${PN}.env 95ansible
}

src_install() {
	distutils-r1_src_install
	readme.gentoo_create_doc
}

pkg_postinst() {
	optfeature "Alternative ssh transport" dev-python/paramiko
}