[gentoo-commits] gentoo-x86 commit in media-sound/jack-rack: ChangeLog jack-rack-1.4.8_rc1.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    11/07/30 10:41:59

  Modified:             ChangeLog
  Added:                jack-rack-1.4.8_rc1.ebuild
  Log:
  Version bump to Debian version and patchset. This is more recent snapshot from upstream git.
  
  (Portage version: 2.2.0_alpha47/cvs/Linux x86_64)

Revision  Changes    Path
1.39                 media-sound/jack-rack/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/jack-rack/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/jack-rack/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/jack-rack/ChangeLog?r1=1.38&r2=1.39

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/jack-rack/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog	29 Jul 2011 12:05:32 -0000	1.38
+++ ChangeLog	30 Jul 2011 10:41:59 -0000	1.39
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/jack-rack
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/jack-rack/ChangeLog,v 1.38 2011/07/29 12:05:32 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/jack-rack/ChangeLog,v 1.39 2011/07/30 10:41:59 ssuominen Exp $
+
+*jack-rack-1.4.8_rc1 (30 Jul 2011)
+
+  30 Jul 2011; Samuli Suominen <ssuominen@g.o>
+  +jack-rack-1.4.8_rc1.ebuild:
+  Version bump to Debian version and patchset. This is more recent snapshot
+  from upstream git.
 
   29 Jul 2011; Samuli Suominen <ssuominen@g.o>
   jack-rack-1.4.7-r1.ebuild, +files/jack-rack-1.4.7-disable_deprecated.patch:



1.1                  media-sound/jack-rack/jack-rack-1.4.8_rc1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/jack-rack/jack-rack-1.4.8_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/jack-rack/jack-rack-1.4.8_rc1.ebuild?rev=1.1&content-type=text/plain

Index: jack-rack-1.4.8_rc1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/jack-rack/jack-rack-1.4.8_rc1.ebuild,v 1.1 2011/07/30 10:41:59 ssuominen Exp $

EAPI=4
inherit autotools eutils flag-o-matic toolchain-funcs

MY_P=${PN}_${PV/_/\~}
DEB_URI="mirror://debian/pool/main/j/${PN}"

DESCRIPTION="JACK Rack is an effects rack for the JACK low latency audio API."
HOMEPAGE="http://jack-rack.sourceforge.net/"
SRC_URI="${DEB_URI}/${MY_P}.orig.tar.gz ${DEB_URI}/${MY_P}-1.debian.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="alsa gnome lash xml"

RDEPEND=">=x11-libs/gtk+-2.12:2
	>=media-libs/ladspa-sdk-1.12
	media-sound/jack-audio-connection-kit
	alsa? ( media-libs/alsa-lib )
	lash? ( >=media-sound/lash-0.5 )
	gnome? ( >=gnome-base/libgnomeui-2 )
	virtual/libintl
	xml? ( dev-libs/libxml2
		media-libs/liblrdf )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/gettext"

DOCS=( AUTHORS BUGS ChangeLog NEWS README THANKS TODO WISHLIST )

src_unpack() {
	unpack ${A}
	mv ${PN}-* "${S}"
}

src_prepare() {
	EPATCH_FORCE=yes EPATCH_SUFFIX=patch epatch "${WORKDIR}"/debian/patches

	epatch \
		"${FILESDIR}"/${PN}-1.4.6-noalsa.patch \
		"${FILESDIR}"/${PN}-1.4.7-disable_deprecated.patch

	sed -i \
		-e '/Categories/s:Application:GTK:' \
		-e '/Icon/s:.png::' \
		${PN}.desktop || die

	eautopoint
	eautoreconf
}

src_configure() {
	# Use lrdf.pc to get -I/usr/include/raptor2 (lrdf.h -> raptor.h)
	use xml && append-cppflags $($(tc-getPKG_CONFIG) --cflags lrdf)

	econf \
		$(use_enable alsa aseq) \
		$(use_enable gnome) \
		$(use_enable lash) \
		$(use_enable xml) \
		$(use_enable xml lrdf)
}