[gentoo-commits] repo/gentoo:master commit in: x11-misc/sddm/

[Andreas Sturmlechner]

commit:     4d554223bfaf775fb3a83b954095d197b103362e
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Sep  2 14:59:00 2017 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Sep  2 15:06:33 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4d554223

x11-misc/sddm: 0.15.0 version bump

Gentoo-bug: 629532
Package-Manager: Portage-2.3.8, Repoman-2.3.3

 x11-misc/sddm/Manifest           |  1 +
 x11-misc/sddm/sddm-0.15.0.ebuild | 62 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/x11-misc/sddm/Manifest b/x11-misc/sddm/Manifest
index 491da324496..195294a8bd0 100644
--- a/x11-misc/sddm/Manifest
+++ b/x11-misc/sddm/Manifest
@@ -1 +1,2 @@
 DIST sddm-0.14.0.tar.xz 3298360 SHA256 7e348258618b20f777767a98f9e377b48824b5cb5aad3a3f10f8482c1eb27778 SHA512 ae6f02e168dbb4ef1d5d360e6b26a2c45a9891fba9d53b73d41a5cc14906f3fcca3bde6d16d7bb109132d23e3e0e768c5976934fd2f59c23d919cc9f81fbd366 WHIRLPOOL d7d80c5d1e8eb5016fa6f5909026bb477293b4356b9caff92d741c936534504e35fdfe81feea8cb2312cdb53ed0e7cc5bda3af5fc4226d5a797baea97e431ecb
+DIST sddm-0.15.0.tar.gz 3520188 SHA256 a4211e5b66f674415e07bc1cc39c16f60ae6025418bcbaba1118cd51e57c3174 SHA512 4440acfc6f98ab8efe8e3a441e8dc9ee98615c3544f8adc899bc4f0334e4f1b0d37c1ef823b32cc466adc8fac942cd188b33eb49795e0468a136a959c65c7566 WHIRLPOOL 48d4ab7ac8d4527719d532e13956e59bdd6b94a094fdf83cb58f1c32d946b111f5ad9f2fefabe9fd6fac8bbccd2d4f8d63ef467d840b975b54d879d5f1b711f4

diff --git a/x11-misc/sddm/sddm-0.15.0.ebuild b/x11-misc/sddm/sddm-0.15.0.ebuild
new file mode 100644
index 00000000000..0099ac086cd
--- /dev/null
+++ b/x11-misc/sddm/sddm-0.15.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils user
+
+DESCRIPTION="Simple Desktop Display Manager"
+HOMEPAGE="https://github.com/sddm/sddm"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+LICENSE="GPL-2+ MIT CC-BY-3.0 CC-BY-SA-3.0 public-domain"
+SLOT="0"
+IUSE="consolekit elogind +pam systemd"
+
+REQUIRED_USE="?? ( elogind systemd )"
+
+RDEPEND="
+	>=dev-qt/qtcore-5.6:5
+	>=dev-qt/qtdbus-5.6:5
+	>=dev-qt/qtgui-5.6:5
+	>=dev-qt/qtdeclarative-5.6:5
+	>=dev-qt/qtnetwork-5.6:5
+	>=x11-base/xorg-server-1.15.1
+	x11-libs/libxcb[xkb]
+	consolekit? ( >=sys-auth/consolekit-0.9.4 )
+	elogind? ( sys-auth/elogind )
+	pam? ( sys-libs/pam )
+	systemd? ( sys-apps/systemd:= )
+	!systemd? ( sys-power/upower )"
+
+DEPEND="${RDEPEND}
+	dev-python/docutils
+	>=dev-qt/linguist-tools-5.6:5
+	>=dev-qt/qttest-5.6:5
+	kde-frameworks/extra-cmake-modules
+	virtual/pkgconfig"
+
+# fix for flags handling and bug 563108
+PATCHES=( "${FILESDIR}/${PN}-0.12.0-respect-user-flags.patch" )
+
+src_prepare() {
+	use consolekit && eapply "${FILESDIR}/${PN}-0.14.0-consolekit.patch"
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_PAM=$(usex pam)
+		-DNO_SYSTEMD=$(usex '!systemd')
+		-DUSE_ELOGIND=$(usex 'elogind')
+		-DBUILD_MAN_PAGES=ON
+		-DDBUS_CONFIG_FILENAME="org.freedesktop.sddm.conf"
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 /var/lib/${PN} ${PN},video
+}