[gentoo-commits] gentoo-x86 commit in app-arch/rar: rar-5.0.0.ebuild ChangeLog rar-5.0.0_beta8.ebuild

[Jeff Horelick (jdhore)]

jdhore      13/10/31 01:11:20

  Modified:             ChangeLog
  Added:                rar-5.0.0.ebuild
  Removed:              rar-5.0.0_beta8.ebuild
  Log:
  Version bump to 5.0.0 and remove beta release
  
  (Portage version: 2.2.7/cvs/Linux i686, signed Manifest commit with key 23E9E900)

Revision  Changes    Path
1.89                 app-arch/rar/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/ChangeLog?rev=1.89&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/ChangeLog?rev=1.89&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/ChangeLog?r1=1.88&r2=1.89

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/rar/ChangeLog,v
retrieving revision 1.88
retrieving revision 1.89
diff -u -r1.88 -r1.89
--- ChangeLog	1 Sep 2013 22:26:30 -0000	1.88
+++ ChangeLog	31 Oct 2013 01:11:20 -0000	1.89
@@ -1,6 +1,12 @@
 # ChangeLog for app-arch/rar
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/rar/ChangeLog,v 1.88 2013/09/01 22:26:30 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/rar/ChangeLog,v 1.89 2013/10/31 01:11:20 jdhore Exp $
+
+*rar-5.0.0 (31 Oct 2013)
+
+  31 Oct 2013; Jeff Horelick <jdhore@g.o> +rar-5.0.0.ebuild,
+  -rar-5.0.0_beta8.ebuild:
+  Version bump to 5.0.0 and remove beta release
 
 *rar-5.0.0_beta8 (01 Sep 2013)
 



1.1                  app-arch/rar/rar-5.0.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/rar-5.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/rar/rar-5.0.0.ebuild?rev=1.1&content-type=text/plain

Index: rar-5.0.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/rar/rar-5.0.0.ebuild,v 1.1 2013/10/31 01:11:20 jdhore Exp $
EAPI=4
MY_PV="${PV/0_beta/b}"
DESCRIPTION="RAR compressor/uncompressor"
HOMEPAGE="http://www.rarsoft.com/"
URI_x86="http://www.rarlab.com/rar/rarlinux-${MY_PV}.tar.gz"
URI_amd64="http://www.rarlab.com/rar/rarlinux-x64-${MY_PV}.tar.gz"
URI_w64="http://www.rarlab.com/rar/winrar-x64-${MY_PV//.}.exe"
SRC_URI="x86? ( ${URI_x86} )
	amd64? ( ${URI_amd64} )
	all_sfx? (
		${URI_x86}
		${URI_amd64}
		${URI_w64}
	)"

LICENSE="RAR"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="all_sfx static"

DEPEND="all_sfx? ( app-arch/unrar )"
RDEPEND="sys-libs/glibc"

S=${WORKDIR}/${PN}

QA_FLAGS_IGNORED="opt/rar/default.sfx
	opt/rar/default-elf32.sfx
	opt/rar/default-elf64.sfx
	opt/rar/default-win32.sfx
	opt/rar/default-win64.sfx
	opt/rar/WinCon.SFX
	opt/rar/WinCon64.SFX
	opt/rar/Zip.SFX
	opt/rar/Zip64.SFX
	opt/rar/unrar
	opt/rar/rar"
QA_PRESTRIPPED=${QA_FLAGS_IGNORED}

src_unpack() {
	use x86 && unpack ${URI_x86##*/}
	use amd64 && unpack ${URI_amd64##*/}
	rm -f "${S}"/license.txt
	if use all_sfx ; then
		mkdir sfx
		cd sfx
		unpack ${URI_x86##*/}
		mv rar/default.sfx default-elf32.sfx || die
		unpack ${URI_amd64##*/}
		mv rar/default.sfx default-elf64.sfx || die
		ln -s "${DISTDIR}"/${URI_w64##*/} w64.rar
		unpack ./w64.rar
		mv Default.SFX default-win32.sfx || die
		mv Default64.SFX default-win64.sfx || die
	fi
}

src_compile() { :; }

src_install() {
	exeinto /opt/rar
	doexe rar unrar || die
	use static && { newexe rar_static rar || die ; }

	dodir /opt/bin
	dosym ../rar/rar /opt/bin/rar || die
	dosym ../rar/unrar /opt/bin/unrar || die

	insinto /opt/rar
	if use all_sfx ; then
		doins "${WORKDIR}"/sfx/*.{sfx,SFX} || die
	else
		doins default.sfx || die
	fi
	doins rarfiles.lst || die
	dodoc *.txt
}