[gentoo-commits] gentoo-x86 commit in sci-visualization/gri: gri-2.12.23.ebuild ChangeLog

[Sebastien Fabbro (bicatali)]

bicatali    11/07/28 00:10:12

  Modified:             ChangeLog
  Added:                gri-2.12.23.ebuild
  Log:
  Version bump. Switched to EAPI4. Fixed bug #248372 and bug #314373
  
  (Portage version: 2.1.10.7/cvs/Linux x86_64)

Revision  Changes    Path
1.7                  sci-visualization/gri/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/gri/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/gri/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/gri/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-visualization/gri/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	15 Jun 2011 05:55:30 -0000	1.6
+++ ChangeLog	28 Jul 2011 00:10:12 -0000	1.7
@@ -1,6 +1,11 @@
 # ChangeLog for sci-visualization/gri
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gri/ChangeLog,v 1.6 2011/06/15 05:55:30 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gri/ChangeLog,v 1.7 2011/07/28 00:10:12 bicatali Exp $
+
+*gri-2.12.23 (28 Jul 2011)
+
+  28 Jul 2011; Sébastien Fabbro <bicatali@g.o> +gri-2.12.23.ebuild:
+  Version bump. Switched to EAPI4. Fixed bug #248372 and bug #314373
 
   15 Jun 2011; Justin Lecher <jlec@g.o> gri-2.12.19.ebuild:
   Depend on media-gfx/imagemagick[png], #371583



1.1                  sci-visualization/gri/gri-2.12.23.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/gri/gri-2.12.23.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/gri/gri-2.12.23.ebuild?rev=1.1&content-type=text/plain

Index: gri-2.12.23.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gri/gri-2.12.23.ebuild,v 1.1 2011/07/28 00:10:12 bicatali Exp $

EAPI=4

inherit eutils elisp-common

DESCRIPTION="Language for scientific graphics programming"
HOMEPAGE="http://gri.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="doc emacs examples"

DEPEND="sci-libs/netcdf
	virtual/latex-base
	|| ( media-gfx/imagemagick[png] media-gfx/graphicsmagick[png] )
	app-text/ghostscript-gpl
	emacs? ( virtual/emacs )"
RDEPEND="${DEPEND}"

SITEFILE="50gri-gentoo.el"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.12.18-postscript.patch
}

src_compile() {
	VARTEXFONTS="${T}/fonts" emake
	use emacs && elisp-compile src/*.el
}

src_install() {
	default
	# license text not necessary
	rm "${ED}"/usr/share/gri/doc/license.txt

	# install target installs it always and in the wrong location
	# remove it here and call elisp-install in case of USE=emacs below
	rm -rf "${ED}"/usr/share/emacs

	if ! use doc; then
		sed -i -e "s/Manual at.*//" "${ED}"/usr/share/gri/startup.msg
		rm "${ED}"/usr/share/gri/doc/{cmd,}refcard.ps
		rm -rf "${D}"/usr/share/gri/doc/html
	fi
	if ! use examples; then
		sed -i -e "s/Examples at.*//" "${ED}"/usr/share/gri/startup.msg
		rm -rf "${ED}"/usr/share/gri/doc/examples
	fi

	#move docs to the proper place
	mv "${ED}"/usr/share/gri/doc/* "${ED}"/usr/share/doc/${PF}
	rmdir "${ED}"/usr/share/gri/doc

	if use emacs; then
		cd src
		elisp-install ${PN} *.{el,elc}
		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}