[gentoo-commits] gentoo-x86 commit in sys-devel/automake: ChangeLog automake-1.10.2.ebuild

[Mike Frysinger (vapier)]

vapier      08/11/23 14:52:20

  Modified:             ChangeLog
  Added:                automake-1.10.2.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc14/cvs/Linux 2.6.27.4 x86_64)

Revision  Changes    Path
1.123                sys-devel/automake/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/ChangeLog?rev=1.123&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/ChangeLog?rev=1.123&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/ChangeLog?r1=1.122&r2=1.123

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/automake/ChangeLog,v
retrieving revision 1.122
retrieving revision 1.123
diff -u -r1.122 -r1.123
--- ChangeLog	22 Sep 2008 04:16:29 -0000	1.122
+++ ChangeLog	23 Nov 2008 14:52:20 -0000	1.123
@@ -1,6 +1,11 @@
 # ChangeLog for sys-devel/automake
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/automake/ChangeLog,v 1.122 2008/09/22 04:16:29 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/automake/ChangeLog,v 1.123 2008/11/23 14:52:20 vapier Exp $
+
+*automake-1.10.2 (23 Nov 2008)
+
+  23 Nov 2008; Mike Frysinger <vapier@g.o> +automake-1.10.2.ebuild:
+  Version bump.
 
   22 Sep 2008; Jeroen Roovers <jer@g.o> automake-1.10.1-r1.ebuild:
   Stable for HPPA (bug #238268).



1.1                  sys-devel/automake/automake-1.10.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/automake-1.10.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/automake/automake-1.10.2.ebuild?rev=1.1&content-type=text/plain

Index: automake-1.10.2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/automake/automake-1.10.2.ebuild,v 1.1 2008/11/23 14:52:20 vapier Exp $

inherit eutils

DESCRIPTION="Used to generate Makefile.in from Makefile.am"
HOMEPAGE="http://sources.redhat.com/automake/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="${PV:0:4}"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE=""

RDEPEND="dev-lang/perl
	>=sys-devel/automake-wrapper-2
	>=sys-devel/autoconf-2.60
	>=sys-apps/texinfo-4.7
	sys-devel/gnuconfig"
DEPEND="${RDEPEND}
	sys-apps/help2man"

src_unpack() {
	unpack ${A}
	cd "${S}"
	chmod a+rx tests/*.test
	sed -i \
		-e "s|: (automake)| v${SLOT}: (automake${SLOT})|" \
		doc/automake.texi || die "sed failed"
	mv doc/automake{,${SLOT}}.texi
	sed -i \
		-e "s:automake.info:automake${SLOT}.info:" \
		-e "s:automake.texi:automake${SLOT}.texi:" \
		doc/Makefile.in || die "sed on Makefile.in failed"
	export WANT_AUTOCONF=2.5
}

src_compile() {
	econf --docdir=/usr/share/doc/${PF} || die
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc NEWS README THANKS TODO AUTHORS ChangeLog

	# SLOT the docs and junk
	local x
	for x in aclocal automake ; do
		help2man ./${x} > ${x}-${SLOT}.1
		doman ${x}-${SLOT}.1
		rm -f "${D}"/usr/bin/${x}
	done

	# remove all config.guess and config.sub files replacing them
	# w/a symlink to a specific gnuconfig version
	for x in guess sub ; do
		dosym ../gnuconfig/config.${x} /usr/share/${PN}-${SLOT}/config.${x}
	done
}