[gentoo-commits] repo/gentoo:master commit in: dev-python/fs/

[Michał Górny]

commit:     af3508cff7a9eb86764d75b9c698ece7c9792ce5
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Feb  7 19:45:57 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Feb  7 20:30:04 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=af3508cf

dev-python/fs: Bump to 2.4.15

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/fs/Manifest         |  1 +
 dev-python/fs/fs-2.4.15.ebuild | 60 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/dev-python/fs/Manifest b/dev-python/fs/Manifest
index 4b77af288471..38c0239dda81 100644
--- a/dev-python/fs/Manifest
+++ b/dev-python/fs/Manifest
@@ -1 +1,2 @@
 DIST pyfilesystem2-2.4.14.tar.gz 181196 BLAKE2B 23442e551684fab1493762182944769789ac45e363556705a911b2b3df456da7edfebb58a0d49317f9e9d46316494577be0ec449c86365a510d493d57e1636b0 SHA512 7bc69e23e6477a68fdf87d18403ba0bff2ff4eb2d0cf3cd9c7b0078885ed9d718e3f4f5f22bd77c6bcca6ebfa990045104a2d5abcf473a9d77a28aa94884650b
+DIST pyfilesystem2-2.4.15.tar.gz 181799 BLAKE2B 522d118dcee6aafe754d8eb571aa88f26cbbbafd7fedabbf7f4470e098dde01db42cb26b20ed28305daf8f32a22250da81c8a932d420ef4bdf825deb363a26a1 SHA512 7bb153dad5ea03eec7cb1af8d1b5a851845984e194f288687b0e737e1f32c74bf4c1a8d62a9105c8637cd5a29ab82810df9fc11055b894ab0df899cb20a4e1c1

diff --git a/dev-python/fs/fs-2.4.15.ebuild b/dev-python/fs/fs-2.4.15.ebuild
new file mode 100644
index 000000000000..25c6dbf504e8
--- /dev/null
+++ b/dev-python/fs/fs-2.4.15.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 optfeature
+
+MY_P=pyfilesystem2-${PV}
+DESCRIPTION="Filesystem abstraction layer"
+HOMEPAGE="
+	https://pypi.org/project/fs/
+	https://docs.pyfilesystem.org
+	https://www.willmcgugan.com/tag/fs/
+"
+# Tests from the PyPI tarball are broken
+# https://github.com/PyFilesystem/pyfilesystem2/issues/364
+SRC_URI="
+	https://github.com/PyFilesystem/pyfilesystem2/archive/v${PV}.tar.gz
+		-> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/appdirs-1.4.3[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10[${PYTHON_USEDEP}]
+"
+# NB: we skip tests requiring pyftpdlib
+BDEPEND="
+	test? (
+		dev-python/parameterized[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source dev-python/sphinx_rtd_theme
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# TODO: fails at teardown due to unfreed resources
+		tests/test_ftpfs.py
+	)
+
+	# pytest-xvfb causes test failures due to a zombie Xvfb process
+	epytest -p no:xvfb
+}
+
+pkg_postinst() {
+	optfeature "S3 support" dev-python/boto
+	optfeature "SFTP support" dev-python/paramiko
+	optfeature "Browser support" dev-python/wxpython
+}