[gentoo-commits] gentoo-x86 commit in dev-util/monodevelop: monodevelop-2.4.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       10/07/04 20:57:55

  Modified:             ChangeLog
  Added:                monodevelop-2.4.ebuild
  Log:
  Version bump
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.80                 dev-util/monodevelop/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/monodevelop/ChangeLog?rev=1.80&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/monodevelop/ChangeLog?rev=1.80&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/monodevelop/ChangeLog?r1=1.79&r2=1.80

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/monodevelop/ChangeLog,v
retrieving revision 1.79
retrieving revision 1.80
diff -u -r1.79 -r1.80
--- ChangeLog	22 Jun 2010 18:41:01 -0000	1.79
+++ ChangeLog	4 Jul 2010 20:57:55 -0000	1.80
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/monodevelop
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/monodevelop/ChangeLog,v 1.79 2010/06/22 18:41:01 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/monodevelop/ChangeLog,v 1.80 2010/07/04 20:57:55 pacho Exp $
+
+*monodevelop-2.4 (04 Jul 2010)
+
+  04 Jul 2010; Pacho Ramos <pacho@g.o> +monodevelop-2.4.ebuild:
+  Version bump with lots of fixes and new features.
 
   22 Jun 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
   monodevelop-2.0.ebuild, monodevelop-2.1.1.ebuild,



1.1                  dev-util/monodevelop/monodevelop-2.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/monodevelop/monodevelop-2.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/monodevelop/monodevelop-2.4.ebuild?rev=1.1&content-type=text/plain

Index: monodevelop-2.4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/monodevelop/monodevelop-2.4.ebuild,v 1.1 2010/07/04 20:57:55 pacho Exp $

EAPI=2

inherit fdo-mime mono multilib gnome2-utils versionator

DESCRIPTION="Integrated Development Environment for .NET"
HOMEPAGE="http://www.monodevelop.com/"
SRC_URI="http://ftp.novell.com/pub/mono/sources/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+subversion"

RDEPEND="sys-apps/dbus[X]
	>=dev-lang/mono-2.6.1
	>=virtual/monodoc-2.0
	>=dev-dotnet/mono-addins-0.5[gtk]
	>=dev-dotnet/gtk-sharp-2.12.9
	>=dev-dotnet/glade-sharp-2.12.9
	>=dev-dotnet/gnome-sharp-2.24.0
	>=dev-dotnet/gnomevfs-sharp-2.24.0
	>=dev-dotnet/gconf-sharp-2.24.0
	||	(
		net-libs/xulrunner
		www-client/mozilla-firefox
		www-client/firefox-bin
		www-client/seamonkey
	)
	>=dev-dotnet/xsp-2
	subversion? ( dev-vcs/subversion )
	dev-util/ctags
	!<dev-util/monodevelop-boo-$(get_version_component_range 1-2)
	!<dev-util/monodevelop-java-$(get_version_component_range 1-2)
	!<dev-util/monodevelop-database-$(get_version_component_range 1-2)
	!<dev-util/monodevelop-debugger-gdb-$(get_version_component_range 1-2)
	!<dev-util/monodevelop-debugger-mdb-$(get_version_component_range 1-2)
	!<dev-util/monodevelop-vala-$(get_version_component_range 1-2)"

DEPEND="${RDEPEND}
	sys-devel/gettext
	x11-misc/shared-mime-info
	>=dev-util/intltool-0.35
	>=dev-util/pkgconfig-0.19"

MAKEOPTS="${MAKEOPTS} -j1"

src_configure() {
	econf	--disable-update-mimedb				\
		--disable-update-desktopdb			\
		--enable-monoextensions				\
		--enable-gnomeplatform				\
		$(use_enable subversion)			\
		|| die "configure failed"
}

src_compile() {
	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"
	dodoc ChangeLog README || die "dodoc failed"
}

pkg_postinst() {
	gnome2_icon_cache_update
	fdo-mime_mime_database_update
	fdo-mime_desktop_database_update
	elog "These optional plugins currently exist:"
	elog " - dev-util/monodevelop-boo"
	elog " - dev-util/monodevelop-java"
	elog " - dev-util/monodevelop-database"
	elog " - dev-util/monodevelop-debugger-gdb"
	elog " - dev-util/monodevelop-debugger-mdb"
	elog " - dev-util/monodevelop-vala"
	elog "To enable their (self-explanatory) functionality, just emerge them."
	elog "Read more here:"
	elog "http://monodevelop.com/"
}