[gentoo-commits] gentoo-x86 commit in net-irc/atheme-services: atheme-services-7.0.0_alpha9.ebuild atheme-services-6.0.9.ebuild ChangeLog atheme-services-6.0.9-r1.ebuild metadata.xml

[Nathan Phillip Brink (binki)]

binki       12/01/03 05:43:07

  Modified:             atheme-services-7.0.0_alpha9.ebuild
                        atheme-services-6.0.9.ebuild ChangeLog metadata.xml
  Added:                atheme-services-6.0.9-r1.ebuild
  Log:
  Add patch removing automagic dependence on sys-libs/cracklib, fixes bug #397401 reported by kensington.
  
  (Portage version: 2.2.0_alpha82-r1/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  net-irc/atheme-services/atheme-services-7.0.0_alpha9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/atheme-services-7.0.0_alpha9.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/atheme-services-7.0.0_alpha9.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/atheme-services-7.0.0_alpha9.ebuild?r1=1.2&r2=1.3

Index: atheme-services-7.0.0_alpha9.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/atheme-services/atheme-services-7.0.0_alpha9.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- atheme-services-7.0.0_alpha9.ebuild	30 Dec 2011 22:42:37 -0000	1.2
+++ atheme-services-7.0.0_alpha9.ebuild	3 Jan 2012 05:43:07 -0000	1.3
@@ -1,6 +1,6 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/atheme-services/atheme-services-7.0.0_alpha9.ebuild,v 1.2 2011/12/30 22:42:37 binki Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/atheme-services/atheme-services-7.0.0_alpha9.ebuild,v 1.3 2012/01/03 05:43:07 binki Exp $
 
 EAPI=4
 
@@ -15,9 +15,10 @@
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS="~amd64 ~sparc ~x86 ~x86-fbsd ~amd64-linux"
-IUSE="largenet ldap nls +pcre perl profile ssl"
+IUSE="cracklib largenet ldap nls +pcre perl profile ssl"
 
 RDEPEND=">=dev-libs/libmowgli-0.9.95
+	cracklib? ( sys-libs/cracklib )
 	ldap? ( net-nds/openldap )
 	nls? ( sys-devel/gettext )
 	perl? ( dev-lang/perl )
@@ -48,6 +49,7 @@
 	# The first PKG_CHECK_MODULES call is conditional, causing
 	# PKG_PROG_PKG_CONFIG expansion to fail.
 	epatch "${FILESDIR}"/${P}-pkg-config.patch
+	epatch "${FILESDIR}"/${PN}-7.0.0_alpha11-cracklib-automagic.patch
 	eautoconf
 
 	# fix docdir
@@ -73,6 +75,7 @@
 		--disable-warnings \
 		--enable-contrib \
 		$(use_enable largenet large-net) \
+		$(use_with cracklib) \
 		$(use_with ldap) \
 		$(use_with nls) \
 		$(use_enable profile) \



1.4                  net-irc/atheme-services/atheme-services-6.0.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/atheme-services-6.0.9.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/atheme-services-6.0.9.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/atheme-services-6.0.9.ebuild?r1=1.3&r2=1.4

Index: atheme-services-6.0.9.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/atheme-services/atheme-services-6.0.9.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- atheme-services-6.0.9.ebuild	26 Dec 2011 14:42:27 -0000	1.3
+++ atheme-services-6.0.9.ebuild	3 Jan 2012 05:43:07 -0000	1.4
@@ -1,6 +1,6 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/atheme-services/atheme-services-6.0.9.ebuild,v 1.3 2011/12/26 14:42:27 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/atheme-services/atheme-services-6.0.9.ebuild,v 1.4 2012/01/03 05:43:07 binki Exp $
 
 EAPI=4
 
@@ -16,6 +16,7 @@
 IUSE="largenet ldap nls +pcre perl profile ssl"
 
 RDEPEND="dev-libs/libmowgli
+	sys-libs/cracklib
 	ldap? ( net-nds/openldap )
 	nls? ( sys-devel/gettext )
 	pcre? ( dev-libs/libpcre )



1.26                 net-irc/atheme-services/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/ChangeLog?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/ChangeLog?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/ChangeLog?r1=1.25&r2=1.26

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/atheme-services/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- ChangeLog	30 Dec 2011 22:47:37 -0000	1.25
+++ ChangeLog	3 Jan 2012 05:43:07 -0000	1.26
@@ -1,6 +1,16 @@
 # ChangeLog for net-irc/atheme-services
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/atheme-services/ChangeLog,v 1.25 2011/12/30 22:47:37 binki Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-irc/atheme-services/ChangeLog,v 1.26 2012/01/03 05:43:07 binki Exp $
+
+*atheme-services-6.0.9-r1 (03 Jan 2012)
+
+  03 Jan 2012; Nathan Phillip Brink <binki@g.o>
+  atheme-services-6.0.9.ebuild, +atheme-services-6.0.9-r1.ebuild,
+  +files/atheme-services-6.0.9-cracklib-automagic.patch,
+  atheme-services-7.0.0_alpha9.ebuild,
+  +files/atheme-services-7.0.0_alpha11-cracklib-automagic.patch, metadata.xml:
+  Add patch removing automagic dependence on sys-libs/cracklib, fixes bug
+  #397401 reported by kensington.
 
   30 Dec 2011; Nathan Phillip Brink <binki@g.o>
   -atheme-services-6.0.8-r2.ebuild:



1.5                  net-irc/atheme-services/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/atheme-services/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	21 Dec 2011 01:58:13 -0000	1.4
+++ metadata.xml	3 Jan 2012 05:43:07 -0000	1.5
@@ -11,7 +11,8 @@
     <name>Jeff Horelick</name>
     <description>Co-maintainer</description>
   </maintainer>
-	<use>
+  <use>
+    <flag name='cracklib'>Enable nickserv/cracklib module for enforcing strong account passwords</flag>
 		<flag name='largenet'>Enable support/tweaks for large networks</flag>
 		<flag name='ldap'>Enable ldap-backed authentication module</flag>
 		<flag name='perl'>Install a perl module which wraps around the services' XML-RPC interface</flag>



1.1                  net-irc/atheme-services/atheme-services-6.0.9-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/atheme-services-6.0.9-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/atheme-services/atheme-services-6.0.9-r1.ebuild?rev=1.1&content-type=text/plain

Index: atheme-services-6.0.9-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/atheme-services/atheme-services-6.0.9-r1.ebuild,v 1.1 2012/01/03 05:43:07 binki Exp $

EAPI=4

inherit autotools eutils flag-o-matic perl-module prefix

DESCRIPTION="A portable and secure set of open-source and modular IRC services"
HOMEPAGE="http://atheme.net/"
SRC_URI="http://atheme.net/downloads/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~sparc ~x86 ~x86-fbsd ~amd64-linux"
IUSE="cracklib largenet ldap nls +pcre perl profile ssl"

RDEPEND="dev-libs/libmowgli
	cracklib? ( sys-libs/cracklib )
	ldap? ( net-nds/openldap )
	nls? ( sys-devel/gettext )
	pcre? ( dev-libs/libpcre )
	ssl? ( dev-libs/openssl )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

pkg_setup() {
	# the dependency calculation puts all of the .c files together and
	# overwhelms cc1 with this flag :-(
	filter-flags -combine

	if use profile; then
		# bug #371119
		ewarn "USE=\"profile\" is incompatible with the hardened profile's -pie flag."
		ewarn "Disabling PIE. Please ignore any warning messages about -nopie being invalid."
		append-flags -nopie
	fi

	enewgroup ${PN}
	enewuser ${PN} -1 -1 /var/lib/atheme ${PN}
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-6.0.8-configure-disable.patch
	epatch "${FILESDIR}"/${P}-cracklib-automagic.patch
	eautoconf

	# fix docdir
	sed -i -e 's/\(^DOCDIR.*=.\)@DOCDIR@/\1@docdir@/' extra.mk.in || die

	# basic logging config directive fix
	sed -i -e '/^logfile/s;var/\(.*\.log\);'"${EPREFIX}"'/var/log/atheme/\1;g' dist/* || die

	# QA against bundled libs
	rm -rf libmowgli || die

	# Get useful information into build.log
	sed -i -e '/^\.SILENT:$/d' buildsys.mk.in || die
}

src_configure() {
	econf \
		--sysconfdir="${EPREFIX}"/etc/${PN} \
		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
		--localstatedir="${EPREFIX}"/var \
		--enable-fhs-paths \
		--enable-contrib \
		$(use_enable largenet large-net) \
		$(use_with cracklib) \
		$(use_with ldap) \
		$(use_with nls) \
		$(use_enable profile) \
		$(use_with pcre) \
		$(use_enable ssl)
}

src_install() {
	emake DESTDIR="${D}" install

	insinto /etc/${PN}
	for conf in dist/*.example; do
		# The .cron file isn't meant to live in /etc/${PN}, so only
		# install a .example version.
		[[ ${conf} == *cron* ]] && continue

		newins ${conf} $(basename ${conf} .example)
	done

	fowners -R 0:${PN} /etc/${PN}
	keepdir /var/{lib,log}/atheme
	fowners ${PN}:${PN} /var/{lib,log,run}/atheme
	fperms -R go-w,o-rx /etc/${PN}
	fperms 750 /etc/${PN} /var/{lib,log,run}/atheme

	newinitd "${FILESDIR}"/${PN}.initd ${PN}

	# contributed scripts and such:
	insinto /usr/share/doc/${PF}/contrib
	doins contrib/*.{c,pl,php,py,rb}

	if use perl; then
		perlinfo
		insinto "${VENDOR_LIB#${EPREFIX}}"
		doins -r contrib/Atheme{,.pm}
	fi
}