[gentoo-commits] repo/gentoo:master commit in: dev-vcs/gitg/

[Mart Raudsepp]

commit:     e55d9d07cf0b0b66254df9982a9e983f764e56fb
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 18 10:42:20 2017 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Tue Apr 18 10:53:41 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e55d9d07

dev-vcs/gitg: bump to 3.23.90

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 dev-vcs/gitg/Manifest            |  1 +
 dev-vcs/gitg/gitg-3.23.90.ebuild | 84 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 85 insertions(+)

diff --git a/dev-vcs/gitg/Manifest b/dev-vcs/gitg/Manifest
index 93647cf603d..7368a751250 100644
--- a/dev-vcs/gitg/Manifest
+++ b/dev-vcs/gitg/Manifest
@@ -1 +1,2 @@
 DIST gitg-3.22.0.tar.xz 1507056 SHA256 ba6895f85c18748294075980a5e03e0936ad4e84534dbb0d8f9e29aa874ddeaf SHA512 2d59af3bb725c111966544ed6977002a901a862f0280c9acf117b2b613b00d889039ea780cad83bd624de5099256e48b99cdf0421362f154a8380e98f5f977da WHIRLPOOL 088819c4580c14268f420a6f745cc68f5ec0e22c88ce318792071773dc8ecf0a1e99d78639ec0dc561ba22366d8f9a1673be4c939cd5074c6c335fc03f86a819
+DIST gitg-3.23.90.tar.xz 1688752 SHA256 afb9903e33796ca5149651569280ce15dd53e7d38722146a91db408b9e426f54 SHA512 97af27fd699bffb0268f01287a2a2e015211f4f09cf92687e8a944cad21b60fb2b8b0dbb6fce4167b283dd241e8f946e4cd8e0dcc47007193f1969a1d375e0e6 WHIRLPOOL 3201e107767dd01152ca44ed639f124aaab3e78a373e949c68c83bbcb5c2c7624b720c259ebd57be62474613e82d96109a306ae57c5b5e4264d929e2f0c44f57

diff --git a/dev-vcs/gitg/gitg-3.23.90.ebuild b/dev-vcs/gitg/gitg-3.23.90.ebuild
new file mode 100644
index 00000000000..b8f4bb95294
--- /dev/null
+++ b/dev-vcs/gitg/gitg-3.23.90.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{3_4,3_5} )
+VALA_MIN_API_VERSION="0.32" # Needed when gtk+-3.20 is found
+
+inherit gnome2 pax-utils python-r1 vala
+
+DESCRIPTION="git repository viewer for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gitg"
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="glade +python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# test if unbundling of libgd is possible
+# Currently it seems not to be (unstable API/ABI)
+RDEPEND="
+	app-crypt/libsecret
+	dev-libs/libgee:0.8[introspection]
+	>=app-text/gtkspell-3.0.3:3
+	>=dev-libs/glib-2.38:2[dbus]
+	>=dev-libs/gobject-introspection-0.10.1:=
+	dev-libs/libgit2:=[threads]
+
+	>=dev-libs/libgit2-glib-0.25.0[ssh]
+	<dev-libs/libgit2-glib-0.26.0
+
+	>=dev-libs/libpeas-1.5.0[gtk]
+	>=dev-libs/libxml2-2.9.0:2
+	net-libs/libsoup:2.4
+	>=gnome-base/gsettings-desktop-schemas-0.1.1
+	>=x11-libs/gtk+-3.20.0:3
+	>=x11-libs/gtksourceview-3.10:3.0
+	x11-themes/adwaita-icon-theme
+	glade? ( >=dev-util/glade-3.2:3.10 )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	>=dev-libs/libgit2-glib-0.24.4[vala]
+	>=dev-util/intltool-0.40
+	gnome-base/gnome-common
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use python && [[ ${MERGE_TYPE} != binary ]] && python_setup
+}
+
+src_prepare() {
+	gnome2_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		--disable-deprecations \
+		$(use_enable glade glade-catalog) \
+		$(use_enable python)
+}
+
+src_install() {
+	# -j1: bug #???
+	gnome2_src_install -j1
+
+	if use python ; then
+		install_gi_override() {
+			python_moduleinto "$(python_get_sitedir)/gi/overrides"
+			python_domodule "${S}"/libgitg-ext/GitgExt.py
+		}
+		python_foreach_impl install_gi_override
+	fi
+}